无忧启动论坛

标题: 老毛桃能否将你的winpe(0911)中的“PESETUP.EXE”，写成批处理的形式? [打印本页]

作者: earthblove 时间: 2007-11-29 14:47
标题: 老毛桃能否将你的winpe(0911)中的“PESETUP.EXE”，写成批处理的形式?
老毛桃，你好！
能否将你的winpe(0911)中的“PESETUP.EXE”，写成批处理"PESETUP.CMD"的形式，我想对这部分做点修改，非常感谢！

NTCOM.exe是作什么用的呀？非常感谢！

祝工作愉快，一切顺心如意！

[ 本帖最后由打狗协会理事于 2007-11-29 03:57 PM 编辑 ]

作者: dgxhls 时间: 2007-11-29 16:03
本来就是批处理转化而来的：

安装.rar (3.4 KB, 下载次数: 2235)

作者: dgxhls 时间: 2007-11-29 16:08
@Echo Off
COLOR 2F
Set Prog=老毛桃制作的 WinPE 专用安装工具
Set L1=　　　　　　╭══════════════════╮
Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
Set L3=　　　╭══┤　%Prog%　 ├══╮
Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
Set L5=　　　║　　╰══════════════════╯　　║
Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
Set L7=　　　╟════════════════════════╢
Set L8=　　　║　版权所有：老毛桃　　仅供网友们交流　翻版不究　║
Set L9=　　　╰────────────────────────╯
Title %Prog%

Set SetupINIFile=PESetup.INI
Set PEFile=MiniPE\WinPE.IS_
Set PEIni=MiniPE\WinPE.INI
Set LogFile=PEInstall.log
If Not Exist .\PESETUP.INI Goto Err0
For /F "tokens=2 delims=^=" %%I In ('FIND /I ^"外置程序包^" .\%SetupINIFile%') DO Set OPFile=MiniPE\%%I

Set AddATTR=ATTRIB +S +H +R
Set DelATTR=ATTRIB -S -H -R

:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║
Echo %L6%
Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
Echo 　　　║　　[4] Grub安装/启动 (U 盘、移动硬盘安装)　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：
If "%Choice%"=="" Goto Start
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Goto HD
If /I "%Choice%"=="2" Goto HD
If /I "%Choice%"=="3" Goto HD
If /I "%Choice%"=="4" Goto UD
If /I "%Choice%"=="Q" Exit
Goto Start

:HD
Set RP=
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If "%RP%"=="" Goto NoSys
Set PEDIR=%RP%\MiniPE&&Set TargetP=硬盘&&Set TxtSp=
If Exist %PEDIR% Goto Err1
FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
FIND /I "C:\MiniPE" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
If /I "%Choice%"=="1" Goto Install
If /I "%Choice%"=="2" Goto GInstall
If /I "%Choice%"=="3" Goto AInstall
Goto HD

:UD
CLS
Title %Prog%——U 盘安装
For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I
If "%Us%"=="当前可移动磁盘分区：" Goto NoUD
Echo %Us%&&Echo.
If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在或写保护或不是 U 盘分区，请按任意键重新设定。&&Echo.
Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
Echo.&&Echo.
If "%RP%"=="" Goto UD
If Not "%RP%"=="" Set RP=%RP:~0,1%:
For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD
Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
Del %TestFile% /Q>NUL 2>NUL
Set U=U&&Set PEDIR=%RP%\MiniPE&&Set TargetP= U 盘&&Set TxtSp=
If Exist %RP%\MAOTAO Goto Err1
If Exist %PEDIR% Goto Err1
CLS
Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
Echo.
Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。
PAUSE>NUL
Start /Wait MYINS\HPUSBFW.EXE
Start /Wait MYINS\GRUBGUI.EXE
Echo.
Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续。。。
PAUSE>NUL
Goto GInstall

:NoUD
CLS
Title %Prog%——U 盘安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　║
Echo %L6%
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：
If "%Choice%"=="" Goto NoUD
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto NoUD
Exit

:Err0
Echo 错误：安装配置文件丢失！&&Echo.
Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.
Echo 请按任意键退出安装程序。。。
PAUSE>NUL
Exit

:Err1
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
Echo %L6%
Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
If "%TargetP%"=="硬盘" Set U=
If "%Choice%"=="" Goto Err1
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
If /I "%Choice%"=="2" Goto UnInstall
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto Err1
Exit

:UnInstall
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i
If Not "%U%"=="" Set OPD=%RP%
If Exist %OPD%\外置程序 RD %OPD%\外置程序 /S /Q>NUL 2>NUL
If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
If Exist %RP%\MiniPE RD %RP%\MiniPE /S /Q>NUL 2>NUL
%DelATTR% %RP%\BOOT.INI>NUL 2>NUL
Set TMPINIFile=BOOT_%RANDOM%.INI
If Exist %RP%\BOOT.BAK (
%DelATTR% %RP%\BOOT.BAK
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
) Else (
If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.INI|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
If Exist %RP%\%TMPINIFile% TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
)
If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
If Exist %RP%\%TMPINIFile% %DelATTR% %RP%\%TMPINIFile%&&Del %RP%\%TMPINIFile%>NUL 2>NUL
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
Title %Prog%——卸载完成
If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装。。。&&PAUSE>NUL 2>NUL&&Goto Start)
Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出。。。
PAUSE>NUL 2>NUL
Exit

:Install
Title %Prog%——普通安装
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo.&&Echo　　　　正在复制文件，请稍候。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:GInstall
If "%U%"=="" Title %Prog%——Grub安装
CLS
Set DefItem=0&&Set LDRP=MiniPE\
If "%U%"=="" Set DefItem=1
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto GInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto GInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
>%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
MYINS\MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MTLDR%U%.BIN -r -y>NUL 2>NUL
>>%RP%\MTLDR Echo default %DefItem%
>>%RP%\MTLDR Echo timeout 5
>>%RP%\MTLDR Echo.
For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
Echo fontfile /minipe/muifont.gz>>%RP%\MTLDR
Echo splashimage /minipe/bj2008.xpm.gz>>%RP%\MTLDR
>>%RP%\MTLDR Echo.
Echo title WinPE By: MAOTAO>>%RP%\MTLDR
For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
Copy /b %RP%\MTLDR+%PEDIR%\MTLDR%U%.bin %RP%\MTLDR>NUL 2>NUL
Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
Del %PEDIR%\MTLDR%U%.bin /Q>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR
Echo.
Echo 正在复制文件，请稍候。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y>NUL 2>NUL
If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin
Call :CopyAndSetFiles
Goto SUCCESS

:AInstall
Title %Prog%——Aero安装
CLS
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto AInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto AInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
Ren %PEDIR%\maotao.bin avldr.xpe
Ren %PEDIR%\maotaoa.bin maotao.bin
>%PEDIR%\airL.gz <nul Set/p=%Pass2%
Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo.
Echo 正在复制文件，请稍候。。。
MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
MOVE %PEDIR%\WINNT.XPE %RP%\>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:NoSys
CLS
Echo 好像您的机器中没有安装操作系统哦，请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出。。。
PAUSE>NUL 2>NUL
Exit

:CopyAndSetFiles
For /F "tokens=2 delims=." %%i In ('Ver') DO Set SysVer=%%i
If "%U%"=="" If %SysVer:~0,1% LSS 1 Set SysVer=2K
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y>NUL 2>NUL
If Not Exist %RP%\NTDETECT.COM MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTDETECT.COM -r -y>NUL 2>NUL
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
Copy ..\%OPFile% %PEDIR% /Y>NUL 2>NUL
Copy ..\%PEIni% %PEDIR% /Y>NUL 2>NUL
If "%U%"=="" %DelATTR% %RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
If "%U%"=="" Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
If "%U%"=="" TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
If "%U%"=="" Echo C:\MiniPE\MAOTAO.BIN="WinPE By: 老毛桃">>%RP%\BOOT.INI
If /I "%SysVer%"=="2K" (
%DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin
Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL
)
If Exist %RP%\%PEIni% %DelATTR% %RP%\%PEIni%
TYPE ..\%PEIni%|FIND /I /V "PESetup.EXE">%RP%\%PEIni%
%AddATTR% %RP%\%LDRP%LDRXPE
%AddATTR% %RP%\NTDETECT.COM
%AddATTR% %RP%\WINNT.XPE
If "%U%"=="" %AddATTR% %RP%\BOOT.INI
%AddATTR% %RP%\MiniPE /S /D
%AddATTR% %RP%\MiniPE\*.* /S /D
If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
If Exist %RP%\MTLDR %AddATTR% %RP%\MTLDR
Goto :EOF

:SUCCESS
Title %Prog%——安装完成
CLS
For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:
Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
If "%U%"=="" (
Echo.
Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
)
Echo.&&Echo.
Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
Echo.
Echo 请按任意键退出。。。
PAUSE>NUL 2>NUL
Exit

作者: earthblove 时间: 2007-12-1 07:31
标题: 非常感谢老毛桃
非常感谢，收到！
周末愉快！

作者: earthblove 时间: 2007-12-1 08:55
刚才兴趣使然，用QuickBFC将12K大小"安装.bat"转成exe文件，结果生成的exe变成了130K大小。而你的好像也只有12K，请问怎么做的？

再次感谢回复！

作者: awera 时间: 2007-12-2 16:27
呵呵，学习了。
那个bat转exe的工具不错，转成exe后体积更小。
我忘了是哪个了，很少用

作者: 无翼鸟飞翔 时间: 2007-12-2 19:53
ExeScript,,

作者: 1test1 时间: 2007-12-3 05:41

原帖由 无翼鸟飞翔 于 2007-12-2 07:53 PM 发表
ExeScript,,

是exescope

作者: 火焙鱼 时间: 2007-12-30 11:57
感谢版主和老毛桃提供批处理，但这个批处理不能安装.im_格式的硬盘pe。
请求老九大侠能否将你的xpehelp.exe写成批处理的形式！
主要是安装pe和卸载pe的程式，说明文档就不用了。
因为我想用批处理安装和卸载.im_格式的硬盘pe，先谢谢了，祝大家新年快乐！

作者: msuser 时间: 2007-12-30 15:31

原帖由 火焙鱼 于 2007-12-30 11:57 AM 发表
感谢版主和老毛桃提供批处理，但这个批处理不能安装.im_格式的硬盘pe。
请求老九大侠能否将你的xpehelp.exe写成批处理的形式！
主要是安装pe和卸载pe的程式，说明文档就不用了。
因为我想用批处理安装和卸载 ...

PE硬盘安装模板，用法：
把该模板与你的IM_文件放在同一目录下，右键点击该EXE文件，在右键菜单中选用WINRAR打开，注意不要使窗口最大化，然后将你的IM_文件拖入该窗口，OK。最后为该PE该成你想要的名称（扩展名不要动）

硬盘PE安装模板.rar

193.56 KB, 下载次数: 1125, 下载积分: 无忧币 -2

作者: web5151 时间: 2009-10-17 10:42
不错啊 l谢谢楼主和各位

作者: npxm 时间: 2011-3-16 10:34
为什么我按老毛桃提供的批处理另存为BAT文件后，运行后会出现找不到文件：C：\winnt.xpe,有谁能帮助解答一下吗，谢谢了！

欢迎光临无忧启动论坛 (http://wuyou.net/)