AUTOEXEC.BAT
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path %RAMD%\
copy a:\load\*.* %RAMD%\ > NUL
copy a:\autoexec.bat %RAMD%\ > NUL
copy a:\command.com %RAMD%\ > NUL
set comspec=%RAMD%\command.com
subst a: %RAMD%\
device usbaspi.sys /norst
device usbcd.sys /d:USB
lh mscdex /d:UIDE /d:USB
findcd.exe
lh smartdrv.exe
lh ctmouse.exe
lh tway32.exe
call shell.bat
SETRAMD.BAT
@echo off
set RAMD=
set CDROM=
a:\findramd
if errorlevel 255 goto no_ramdrive
if not errorlevel 3 goto no_ramdrive
goto do_shift
:loop
if errorlevel %1 goto no_shift
:do_shift
shift
shift
if not %1*==* goto loop
goto no_ramdrive
:no_shift
set ramd=%2
goto success
:no_ramdrive
echo The Windows 98 startup disk could not create a temporary drive for the
echo diagnostic tools. This may be because this computer has less than the
echo minimum required extended memory.
echo.
:success
set RAMD=%RAMD%:
SHELL.BAT
@ECHO OFF
:start
cls
echo.
echo.
echo.
echo.
echo.
echo.
echo ┌───────────────────────┐
echo │ NDVR监控系统恢复光盘 │
echo │ │
echo │ 1. 自动分区 │
echo │ 2. Pqmagic手工分区 │
echo │ 3. 恢复系统分区到出厂状态 │
echo │ 4. 重新启动 │
echo │ 5. 关机 │
echo └───────────────────────┘
echo.
CHOICE /C:12345 /N /T:5,10 "请选择操作[1/2/3/4/5]："
if errorlevel 255 goto start
if errorlevel 5 goto shutdown
if errorlevel 4 goto reboot
if errorlevel 3 goto restore
if errorlevel 2 goto pqmagic
if errorlevel 1 goto gdisk
goto start
:gdisk
echo.
echo 自动分区操作将导致硬盘上已有的数据资料全部清除，在
CHOICE /C:yn /N /T:n,10 "确认此操作前请备份重要数据资料，是否继续分区[Y/N]？"
if errorlevel 255 goto start
if errorlevel 2 goto start
if errorlevel 1 goto do_gdisk
goto start
:do_gdisk
%cdrom%
cd ghost11
gdisk 1 /del /all /i /nousb /y
gdisk 1 /batch:fast.txt /i /nousb /y
goto end
:pqmagic
echo.
echo 手动分区操作将导致硬盘上已有的数据资料全部或部分清除，
CHOICE /C:yn /N /T:n,10 "在确认此操作前请备份重要数据资料，是否继续分区[Y/N]？"
if errorlevel 255 goto start
if errorlevel 2 goto start
if errorlevel 1 goto do_pqm
goto start
:do_pqm
%cdrom%
cd pqmagic8
pqmagic
goto end
:restore
echo.
echo 恢复系统分区操作将导致硬盘系统分区上已有的数据资料全部清
CHOICE /C:yn /N /T:n,10 "除，在确认此操作前请备份重要数据资料，是否继续恢复[Y/N]？"
if errorlevel 255 goto start
if errorlevel 2 goto start
if errorlevel 1 goto do_rest
goto start
:do_rest
%cdrom%
cd ghost11
ghost -nousb -noide -clone,mode=pload,src=%cdrom%\ndvr.gho:1,dst=1:1 -batch -sure -rb
goto end
:reboot
reboot
:shutdown
shutdown
:end
reboot
