批处理版的易读网txt小说下载器

namejm

　　春节马上就要到了，貌似只剩下两天时间，在网上如何消遣？down一些txt小说回去慢慢欣赏，是件多么惬意的事情啊。namejm最近在网上转悠了好一阵子，发现一个非常干净的txt小说网站，名叫易读网，抓取txt小说十分方便。狂喜之余，做了个下载易读网txt小说的脚本，以方便广大书虫。
　　如有什么bug，或有什么好的建议，望各位及时反馈。

1. @echo off
   
2. :: 功能：
   
3. ::        按照多种方式下载易读网上的txt小说
   
4. :: 实现过程：
   
5. :: 1、下载指定的某篇小说：
   
6. ::        首先下载小说首页，通过首页提取出每一章节的下载地址，然后下载每一章节的html文件，转为txt文本，最后按章节顺序提取正文内容，拼合即可；
   
7. :: 2、根据配置文件下载指定的小说：
   
8. ::        首先，需要在当前脚本所在的文件夹下存在"要下载的小说列表.txt"文件，文件内容按照 "《小说名》"|小说URL 的格式，
   
9. ::        一行一条记录加以保存，前后不可有多余的字符；然后，把这个文件复制到 %destination%\tmp\要下载的小说列表\ 目录下，
   
10. ::        覆盖同名文件，用批处理读取其中的配置，接下来的步骤同1；
    
11. :: 3、下载指定页码上的所有小说：
    
12. ::        首先下载指定页面，把其中各篇小说的首页地址提取出来，接下来的步骤同1；
    
13. :: 4、下载指定页码范围内的所有小说：
    
14. ::        首先下载指定页码范围内的所有页面，接下来的步骤同1；
    
15. :: 5、下载全站的所有小说：
    
16. ::        首先下载全站所有页码上的所有页面，接下来的步骤同1；
    
17. 
    
18. mode con lines=26
    
19. set www=http://www.yilook.com
    
20. set TT=易读网txt小说下载器
    
21. set destination=易读txt小说
    
22. md "%destination%\tmp\要下载的小说列表\html" 2>nul
    
23. pushd "%destination%\tmp\要下载的小说列表\html"
    
24. 
    
25. :Main
    
26. cls
    
27. del /a /f /q *.* 2>nul
    
28. del /a /f /q ..\txt\*.* 2>nul
    
29. title %TT%
    
30. echo.&echo.
    
31. echo                    本程序可以按照以下方式下载易读网上的txt小说
    
32. echo.
    
33. echo                    易读网首页：http://www.yilook.com
    
34. echo.
    
35. echo                        1、下载指定的某篇小说
    
36. echo.
    
37. echo                        2、根据配置文件下载指定的小说
    
38. echo.
    
39. echo                        3、下载指定页码上的所有小说
    
40. echo.
    
41. echo                        4、下载指定页码范围内的所有小说
    
42. echo.
    
43. echo                        5、下载全站的所有小说
    
44. echo.
    
45. echo                        X、退出
    
46. set choice=
    
47. call :line
    
48. set /p choice=                请输入指定功能代码（1/2/3/4/5/X）：
    
49. if not defined choice goto Main
    
50. if /i "%choice:~0,1%"=="X" exit
    
51. set "choice=%choice:~0,1%"
    
52. if "%choice%"=="1" goto DownGivenNovel
    
53. if "%choice%"=="2" goto DownGivenNovels
    
54. if "%choice%"=="3" goto DownGivenPage
    
55. if "%choice%"=="4" goto DownGivenPages
    
56. if "%choice%"=="5" goto DownAllPages
    
57. goto Main
    
58. 
    
59. :DownGivenNovel
    
60. cls
    
61. title %TT%-指定网址
    
62. echo.&echo.
    
63. echo                请在易读网中找到某篇小说的URL，复制后粘贴到本窗口中使用。
    
64. echo.
    
65. echo                比如，《汉朝的那些事儿》，其URL地址为：
    
66. echo.
    
67. echo                    http://www.yilook.com/art_7200_8093.html
    
68. echo.
    
69. echo                把以上URL粘贴到本窗口即可下载《汉朝那些事儿》
    
70. echo.
    
71. echo                粘贴方法：鼠标点击右键，然后粘贴，不能使用快捷键Ctrl+V
    
72. call :line
    
73. echo                        请在下面输入小说的URL地址：
    
74. echo.
    
75. set URL=
    
76. set /p URL=            
    
77. if not defined URL goto DownGivenNovel
    
78. if /i "%URL:~0,1%"=="X" exit
    
79. if /i "%URL:~0,1%"=="M" goto Main
    
80. curl -O %URL%
    
81. htox32c /IP /O0 *.html
    
82. for /f "tokens=3" %%i in ('findstr "TITLE" "*.txt"') do echo "%%i"^|%URL%>..\要下载的小说列表.txt
    
83. goto DownNovel
    
84. 
    
85. :DownGivenNovels
    
86. cls
    
87. title %TT%-配置下载文件清单
    
88. echo.&echo.
    
89. echo                请确认当前目录下存在"要下载的小说列表.txt"文件
    
90. echo.
    
91. echo                并且该文件中的内容为 "《小说名》"^|小说目录页URL 的格式
    
92. echo.
    
93. echo                一行一条记录，前后不可有多余字符。如：
    
94. echo.
    
95. echo                "《寻人启事》"^|http://www.yilook.com/art_7238_6170.html
    
96. echo.
    
97. echo                若不满足如上条件，请自行配置好后方可使用本功能
    
98. call :line
    
99. echo.
    
100. set next=
     
101. set /p next=                要继续下一步吗？（Y/N）：
     
102. if not exist ..\..\..\..\要下载的小说列表.txt goto DownGivenNovels
     
103. if not defined next goto DownGivenNovels
     
104. set "next=%next:~0,1%"
     
105. if /i "%next%"=="X" exit
     
106. if /i "%next%"=="M" goto Main
     
107. if /i "%next%"=="Y" (
     
108.     copy /y ..\..\..\..\要下载的小说列表.txt ..\
     
109.     goto DownNovel
     
110. )
     
111. goto DownGivenNovels
     
112. 
     
113. :DownGivenPage
     
114. cls
     
115. title %TT%-指定页码
     
116. echo.&echo.&echo.&echo.
     
117. echo                您可以指定某一页码，本脚本将下载易读网上这一页内
     
118. echo.
     
119. echo                列出的所有小说
     
120. echo.
     
121. echo                如：输入3，将下载这一页面所列出的所有小说：
     
122. echo.
     
123. echo                        http://www.yilook.com/artlist_3.html
     
124. call :line
     
125. set page=
     
126. set /p page=                请输入指定页码：
     
127. if not defined page goto DownGivenPage
     
128. if /i "%page:~0,1%"=="X" exit
     
129. if /i "%page:~0,1%"=="M" goto Main
     
130. curl -O %www%/artlist_%page%.html
     
131. goto HTMLtoTXT
     
132. 
     
133. :DownGivenPages
     
134. cls
     
135. title %TT%-指定页码范围
     
136. echo.&echo.
     
137. echo                您可以指定某一页码范围，本脚本将下载易读网上这些页内
     
138. echo.
     
139. echo                列出的所有小说
     
140. echo.
     
141. echo                注意：起止页码必须用半角状态下的短横杠连接。
     
142. echo.
     
143. echo                如：输入 3-5，将下载易读网上下列页面内列出的所有小说：
     
144. echo.
     
145. echo                        http://www.yilook.com/artlist_3.html
     
146. echo                        http://www.yilook.com/artlist_4.html
     
147. echo                        http://www.yilook.com/artlist_5.html
     
148. call :line
     
149. set pages=
     
150. set /p pages=                请输入指定页码的范围（如3-5）：
     
151. if not defined pages goto DownGivenPages
     
152. if /i "%pages%"=="X" exit
     
153. if /i "%pages%"=="M" goto Main
     
154. curl -O "%www%/artlist_[%pages%].html"
     
155. goto HTMLtoTXT
     
156. 
     
157. :DownAllPages
     
158. cls
     
159. title %TT%-下载全站小说
     
160. curl -O %www%/artlist_1.html
     
161. htox32c /IP /O0 /U1+4 artlist_1.html
     
162. cls
     
163. for /f "tokens=6" %%i in ('findstr /i "第.*页" artlist_1.txt') do (
     
164.     curl -O "%www%/artlist_[2-%%i].html"
     
165. )
     
166. 
     
167. :HTMLtoTXT
     
168. cls
     
169. title %TT%-网页转换为txt
     
170. htox32c /IP /O0 /U1+4 *.html
     
171. md ..\txt 2>nul
     
172. del /a /f /q ..\txt\*.*
     
173. move *.txt ..\txt>nul
     
174. 
     
175. :PickupList
     
176. cls
     
177. echo.&echo    正在生成要下载的小说列表，请稍候...
     
178. cd.>..\要下载的小说列表.txt
     
179. for %%i in (..\txt\*.txt) do (
     
180.     title %TT%-生成下载列表_%%~nxi
     
181.     for /f "delims=<'> tokens=1,2" %%j in ('findstr /i "《.*》" "%%i"') do (
     
182.         echo "%%j"^|%www%/%%k>>..\要下载的小说列表.txt
     
183.     )
     
184. )
     
185. 
     
186. :DownNovel
     
187. cls
     
188. title %TT%-下载小说
     
189. echo.&echo.
     
190. echo                正在下载小说，请稍候...
     
191. md ..\..\..\整理结果 2>nul
     
192. del /a /f /q ..\..\..\整理结果\*.*
     
193. rd /q /s ..\..\已下载小说的原始文档
     
194. md ..\..\已下载小说的原始文档
     
195. for /f "delims=| tokens=1,2" %%i in (..\要下载的小说列表.txt) do (
     
196.     curl --create-dirs -o "..\..\已下载小说的原始文档\%%~i\index.html" "%%~j"
     
197.     htox32c /IP /O0 /U1+4 "..\..\已下载小说的原始文档\%%~i\index.html"
     
198.     cls
     
199.     set lastchapter=1
     
200.     for /f "delims=' tokens=1,2" %%x in ('findstr /i "第.*节" "..\..\已下载小说的原始文档\%%~i\index.txt"') do (
     
201.         call :DownHTML "%%~i" "%%~x" "%%~y"
     
202.     )
     
203.     pushd "..\..\已下载小说的原始文档\%%~i\html"
     
204.     htox32c /IP /O0 *.html
     
205.     popd
     
206.     md "..\..\已下载小说的原始文档\%%~i\txt" 2>nul
     
207.     move "..\..\已下载小说的原始文档\%%~i\html\*.txt" "..\..\已下载小说的原始文档\%%~i\txt"
     
208.     call :PickupTXT "%%~i"
     
209.     move "..\..\已下载小说的原始文档\%%~i\%%i.txt" ..\..\..\整理结果
     
210. )
     
211. title %TT%-整理完毕
     
212. echo                整理完毕
     
213. pause
     
214. exit
     
215. 
     
216. :DownHTML
     
217. :: 下载小说各章节页面文件
     
218. set "chapter=%~2"
     
219. set "chapter=%chapter:*第=%"
     
220. set "chapter=%chapter:~0,-2%"
     
221. title %TT%-正在下载 "%~1_第 %chapter% 节"
     
222. if %lastchapter% lss %chapter% set lastchapter=%chapter%
     
223. curl --create-dirs -o "..\..\已下载小说的原始文档\%~1\html\%chapter%.html" "%www%/%~3"
     
224. goto :eof
     
225. 
     
226. :PickupTXT
     
227. :: 按先后顺序提取各章节页面正文并合并之
     
228. cls
     
229. title %TT%-正在提取 %1
     
230. echo.&echo     正在合并各章节，请稍候...
     
231. cd.>"..\..\已下载小说的原始文档\%~1\%~1.txt"
     
232. for /l %%i in (1,1,%lastchapter%) do (
     
233.     title %TT%-正在处理 "%~1\%%i.html"
     
234.     findstr /ibc:"　　" "..\..\已下载小说的原始文档\%~1\txt\%%i.txt">>"..\..\已下载小说的原始文档\%~1\%~1.txt"
     
235.     echo.>>"..\..\已下载小说的原始文档\%~1\%~1.txt"
     
236. )
     
237. goto :eof
     
238. 
     
239. :line
     
240. echo.
     
241. echo ________________________________________________________________________________
     
242. if defined choice (
     
243.     echo                退出 X                                返回主界面 M
     
244. )
     
245. echo.&echo.
     
246. goto :eof

复制代码

正文中提到的第三方命令行工具可以在这些地方找到：
　　1、Curl.exe：http://curl.haxx.se/（官网）或http://bbs.bathome.net/thread-1761-1-1.html
　　2、HtoX32c.exe：http://win32lab.com/（官网，日文）或http://bbs.bathome.net/thread-1974-1-1.html（带中文帮助信息）

　　注意：curl.exe需要配合libssl32.dll和libeay32.dll方可使用，若当前机器%windir%中没有这两个dll，请在网上自行搜索下载这两个dll，放到%windir%目录下或curl.exe同一目录下使用——本来想传到论坛上来的，不过压缩了之后仍然达到600多K，上传不到论坛里来，只好作罢，貌似老周也太吝啬了，竟然只给了400K的上传权限，5555。

[ 本帖最后由 namejm 于 2010-2-22 22:28 编辑 ]

netwinxp

LS的好久没见踪迹了，批处理的功力还是那样的精湛，另外，单附件400K，你可以用分卷压缩，传多个分卷压缩包不就解决了*^_^*

namejm

　　注意：curl.exe需要配合libssl32.dll和libeay32.dll方可使用，若当前机器%windir%中没有这两个dll，请在网上自行搜索下载这两个dll，放到%windir%目录下或curl.exe同一目录下使用——本来想传到论坛上来的，不过压缩了之后仍然达到600多K，上传不到论坛里来，只好作罢，貌似老周也太吝啬了，竟然只给了400K的上传权限，5555。

x9tian

原帖由 diwu2005 于 2010-2-14 21:08 发表
下载了两个文件，生成了CMD文件，但运行之后，只多了几个空文件夹，什么小说也没下载到(所有的菜单都运行了N遍)，呵呵，楼主不知你自己测试了没有

在批处理前加上　path=%~dp0;%path% 就行了，

wbdos

相当厉害啊！！ 下来看看

diwu2005

下载了两个文件，生成了CMD文件，但运行之后，只多了几个空文件夹，什么小说也没下载到(所有的菜单都运行了N遍)，呵呵，楼主不知你自己测试了没有

freesoft00

dos区重量级人物，支持。

快雪时晴

强人啊，原创！
不知/dos时代菜鸟/有何指教？

没完整看，
不了解Curl，我熟悉Wget，
我觉得写段vbs估计会简单的多