无忧启动论坛

标题: 对小马WINPE的的几个建议和全面改进(合盘提取,驱动分离,PETOOLS) [打印本页]
作者: HUNRYBECKY    时间: 2010-11-10 22:17
标题: 对小马WINPE的的几个建议和全面改进(合盘提取,驱动分离,PETOOLS)
小马的WINPE做的不错，但是我觉得还是值得改进，下面我对小马WINPE提出个人观点以及提出改进方法，包含了原代码，转贴请著名出处
一.对光盘中MAKEISO批处理的改进:
修改内容:一是精简优化部分代码;二是修正一些错误,如选择提示;三是对版面进行了微调;四是如果提取110M迷你网络,增加一个用户自定义的MAKEISO.LST文件以便用户自己定义提取那些东东
代码如下:
  1. @echo off
  2. :: 修改内容:一是精简优化部分代码;二是修正一些错误,如果选择提示;三是对版面进行了微调
  3. pushd %~dp0
  4. color 0b
  5. set prog=小马WINPE专用单ISO提取鸿越修改版
  6. title %prog%
  7. If Not Exist boot\oscdimg.exe Echo 没有找到安装文件oscdimg,请确保WINPE文件的完整！&&pause>nul&&Exit
  8. set l1=　　　　　　╭══════════════════╮
  9. set l2=　　　　　　║　　　　　　　　　　　　　　　　　　║
  10. set l3=　　　╭══┤　 %prog%├══╮
  11. set l4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
  12. set l5=　　　║　　╰══════════════════╯　　║
  13. set l6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
  14. set l7=　　　╟════════════════════════╢
  15. set l8=　　　║　版权所有：鹭鸟工作室  　　          盗版不究  ║
  16. set l9=　　　╰────────────────────────╯

  18. ::checkos
  19. if /i not "%os%."=="windows_nt." goto systemerro
  20. ::判断系统内核winver并设置系统版本theos
  21. ver|find /i " 6.1">nul &&set winver=WIN7&&  set theos=WIN7
  22. ver|find /i " 6.0">nul &&set winver=VISTA&&  set theos=VISTA
  23. ver|find /i " 5.0">nul &&set winver=WINNT&&  set theos=2000
  24. ver|find /i " 5.1">nul &&set winver=WINNT&&  set theos=XP
  25. ver|find /i " 5.2">nul &&set winver=WINNT&&  set theos=2003
  26. goto start

  28. :systemerro
  29. cls
  30. echo.
  31. echo.
  32. echo  注意：未经测试，本软件可能不适用于非 windows pe/2000/xp/2003/vista/win7 操作系统。
  33. echo  按回车键退出安装程序
  34. pause >nul
  35. exit

  37. :start
  38. cls
  39. set choice=
  40. set ismm=
  41. title %prog%—请选择提取模式
  42. echo.
  43. echo %l1%
  44. echo %l2%
  45. echo %l3%
  46. echo %l4%
  47. echo %l5%
  48. echo %l6%
  49. echo 　　　║ 　请选择提取模式：　　　　　　　　　　　　   　║
  50. echo 　　　║　　                                            ║
  51. echo 　　　║　[1] 提取 33m  内核骨头版  (仅含有系统内核)　  ║
  52. echo 　　　║　　                                            ║
  53. echo 　　　║　[2] 提取 50m  迷你u盘版   (仅外置BASIC包)     ║
  54. echo 　　　║　　                                            ║
  55. echo 　　　║　[3] 提取 100m 网络维护版  (含有网络和安装程序)║
  56. echo 　　　║　　                                            ║
  57. echo 　　　║　[4] 提取 220m 迷你小盘版  (砍掉了ie和wmp10)   ║
  58. echo 　　　║　　                                            ║
  59. echo 　　　║　[q] 退出提取模式　　　　　　　　　　　　　    ║
  60. echo %l6%
  61. echo %l7%
  62. echo %l8%
  63. echo %l9%
  64. echo.
  65. echo　　　         您现在使用的是Windows %theos% 操作系统 ！
  66. echo.

  68. set /p choice=　请选择要进行的操作(1/2/3/4/q) ，然后按回车：
  69. if "%choice%"=="" goto start
  70. if not "%choice%"=="" set choice=%choice:~0,1%
  71. if /i "%choice%"=="1" set mkiso=gutou
  72. if /i "%choice%"=="2" set mkiso=50mu
  73. if /i "%choice%"=="3" set mkiso=100mnet
  74. if /i "%choice%"=="4" set mkiso=220mini
  75. if "%save%"=="" call:savedir
  76. set isodir=%save%\winpe
  77. set isotem=%isodir%\%mkiso%
  78. goto:mkiso
  79. if /i "%choice%"=="q" exit
  80. goto start

  82. :savedir
  83. :: 修为:由于是公用，所以单独提取出来
  84. cls
  85. echo.&&echo.
  86. set /p save=请设定%mkiso%文件存放的分区符[不需要冒号，例如 D(推荐)]：
  87. if not "%save%"=="" set save=%save:~0,1%:
  88. goto:eof

  90. :mkiso
  91. cls
  92. title %prog%——正在制作%mkiso%.ISO文件...
  93. echo.
  94. echo.
  95. echo 正在整理必要文件，请稍后...

  97. :: 1.先提取公用模块骨头版，该版本不包含任何外挂WIM文件,但用户可以把minipe\WINPE.ini放置在U盘或硬盘根目录并把需要的程序和系统WIM文件分别放置到minipe\programs和minipe\system中,WINPE将自动加载到对应的程序或系统目录
  98. :: 另外小马版WINPE.ini是由启动镜像系统目录中的PECMD.INI全盘搜索而加载的，从而解决了及时是骨头版也可以扩展自己的应用程序；PETOOLS更是可以直接从所有磁盘根目录PETOOLS下加载程序并创建对应的快捷键。这两个方法特别适合U盘加载ISO骨头版从而减小内存占用
  99. set bootfile=boot\pe.bif
  100. if not exist "%isotem%" md "%isotem%"
  101. copy WINPE.im_ %isotem%\ /y>nul
  102. copy winnt.xpe %isotem%\ /y>nul
  103. copy bootfont.bin %isotem%\ /y>nul
  104. xcopy wxpe /e %isotem%\wxpe\ /h/r/c/y>nul
  105. if /i "%choice%"=="2" (call:50mu)
  106. if /i "%choice%"=="3" (call:50mu&&call:100mnet)
  107. if /i "%choice%"=="4" (call:220mini)
  108. cls

  110. echo.
  111. echo.
  112. echo 正在生成%mkiso%.ISO文件到%isotem% 目录...
  113. if exist boot\oscdimg.exe (
  114.   boot\oscdimg.exe -b"%bootfile%" -h -n -l"%mkiso%" -o "%isotem%" -t10/01/2010,00:00:00 "%isodir%\%mkiso%.iso">nul
  115. )

  117. title %prog%——制作完成
  118. rd /s /q %isotem%
  119. cls
  120. echo.
  121. echo. %mkiso%文件已成功生成至%isodir%目录内...
  122. echo.
  123. set /p ismm=返回主菜单请输入Y，输入Q退出，其他键打开该ISO文件。
  124. if /i "%ismm%"=="Y" call :start
  125. if /i "%ismm%"=="Q" EXIT
  126. start "" "%isodir%\%mkiso%.iso"
  127. EXIT

  129. :: 2.提取基础版(迷你u盘版)，该版本在骨头版基础上增加了基础工具包basic.wim
  130. :50mu
  131. if not exist %isotem%\minipe md %isotem%\minipe
  132. if not exist %isotem%\minipe\programs md %isotem%\minipe\programs
  133. copy minipe\bliss.jpg %isotem%\minipe\ /y>nul
  134. copy minipe\WINPE.ini %isotem%\minipe\ /y>nul
  135. copy minipe\programs\basic.wim %isotem%\minipe\programs\ /y>nul

  137. goto:eof

  139. :: 3.提取网络维护版,该版本在基础版本上增加了WINPE安装工具，增加了启动菜单和工具，增加了一些WIM外挂网络工具包
  140. :: 为了不修改本程序，这里使用加载一个用户文件列表文件来加载指定的WIM文件
  141. :100mnet
  142. set bootfile=boot\loader.bin
  143. if not exist %isotem%\minipe\system md %isotem%\minipe\system
  144. if not exist %isotem%\minipe\drivers md %isotem%\minipe\drivers
  145. xcopy setup /e %isotem%\setup\ /y /h /r>nul
  146. xcopy boot /e %isotem%\boot\ /y /h /r>nul
  147. copy menu.lst %isotem%\ /y>nul
  148. copy minipe\drivers\InfCacheBuild.exe %isotem%\minipedrivers\ /y>nul
  149. copy minipe\drivers\HYSOFT.INI %isotem%\minipedrivers\ /y>nul
  150. copy minipe\drivers\START_DRV.CMD %isotem%\minipedrivers\ /y>nul
  151. if not exist ".\wimlist.ini" (
  152.   copy minipe\system\mmc.wim %isotem%\minipe\system\ /y>nul
  153.   copy minipe\system\system.wim %isotem%\minipe\system\ /y>nul
  154.   copy minipe\drivers\DRIVERS_NET.CAB %isotem%\minipe\drivers\ /y>nul
  155.   copy minipe\drivers\DRIVERS_NET_WIRELESS.CAB %isotem%\minipe\drivers\ /y>nul
  156.   copy minipe\programs\nettools.WIM %isotem%\minipe\programs\ /y>nul
  157.   copy minipe\programs\diskgenius.wim %isotem%\minipe\programs\ /y>nul
  158.   copy minipe\programs\everest.wim %isotem%\minipe\programs\ /y>nul
  159.   copy minipe\programs\ghost.wim %isotem%\minipe\programs\ /y>nul
  160.   copy minipe\programs\Firefox.WIM %isotem%\minipe\programs\ /y>nul
  161. )
  162. IF EXIST ".\wimlist.ini" (
  163.    FOR /F "EOL=;DELIMS=" %%I IN (.\wimlist.ini) DO call copy "%%I" "%isotem%\%%I"/y >nul
  164.    )
  165. goto:eof

  167. :: 4.提取小盘维护版,复制所有文件
  168. :220mini
  169. set bootfile=boot\loader.bin
  170. xcopy *.* %isotem%\ /e /y /h /r>nul
  171. if exist %isotem%\autorun.inf attrib +h +r %isotem%\autorun.inf /s /d
  172. if exist %isotem%\background.bmp attrib +h +r %isotem%\background.bmp /s /d
  173. if exist %isotem%\datapane.bmp attrib +h +r %isotem%\datapane.bmp /s /d
  174. if exist %isotem%\startcd.ini attrib +h +r %isotem%\startcd.ini /s /d
  175. goto:eof
复制代码
二.对驱动安装包进行了分离,而且对代码进行了大量优化处理
驱动更改(驱动更新到http://bbs.wuyou.net/forum.php?mod=viewthread&tid=134718&;extra=page%3D2)
1.采用分离设计,把驱动支持WIM（放system目录）和CAB驱动程序（放drivers目录）分离并把CAB驱动程序单独提取出来,这样方便驱动更新。我对驱动支持批处理和驱动安装批处理的代码进行了重新编写，所有驱动安装在一个批处理中完成。
2.删除3D音效这个无用而庞大的文件sound\DSOUND3D.DLL
3.在网络WIM中增加TEAMVIEWER需要的sensapi.dll和SOUGUO浏览器需要的t2embed.dll核心文件;增加QQLIVE多媒体QUARTZ.DLL(无该文件缓冲90%不动)/jscript.dll,MSHTML.DLL,MSHTML.TLB,MSHTMLED.DLL,MSLS31.DLL网络相关文件(无这些文件则无法显示媒体库)到对应的SOUND.WIM和SYSTEM.WIM中并注册,注意的是IE和wmp10中已经包含这些文件,如果存在这些包则可不用包含这些文件
4.网卡相关的网络工具NETTOOLS、INTERNET EXPLORER、opera.wim、tm2008.wim和声卡相关多媒体程序multimedia、wmp10.wim等并单独封包WIM,安装网卡和声卡时才创建对应的快捷方式(main.ini改为hysoft.ini以便被自动执行安装，如果没有hysoft.ini则自动创建以便在不改变当前路径的情况对批处理进行处理)
5.关于浏览器选择:建议首先选用不依赖IE内核的浏览器,如谷歌/OPERA/FIREFOX浏览器/SOGOU双核浏览器。

驱动目录中HYSOFT.INI用于创建快捷方式,代码如下
  1. `驱动更新到http://bbs.wuyou.net/forum.php?mod=viewthread&tid=134718&extra=page%3D2
  2. LINK !%Desktop%\安装我的驱动,%CurDir%\START_DRV.CMD,DRV,%SystemRoot%\system\HANGUP.ICO
  3. LINK !%Desktop%\安装所有驱动,%CurDir%\START_DRV.CMD,ALL,%CurDir%\InfCacheBuild.exe
  4. LINK %Programs%\驱动支持\安装所有驱动,%CurDir%\START_DRV.CMD,ALL,%CurDir%\InfCacheBuild.exe
  5. LINK %Programs%\驱动支持\安装声卡驱动,%CurDir%\START_DRV.CMD,SOUND,%SystemRoot%\sound\SOUND_PART.ICO
  6. LINK %Programs%\驱动支持\安装网卡驱动,%CurDir%\START_DRV.CMD,NET,%SystemRoot%\system\NET_PART.ICO
  7. LINK %Programs%\驱动支持\安装我的驱动,%CurDir%\START_DRV.CMD,DRV,%SystemRoot%\system\HANGUP.ICO
  8. LINK %Programs%\驱动支持\安装显卡驱动,%CurDir%\START_DRV.CMD,VGA,%CurDir%\AutoSC.exe
  9. LINK %Programs%\驱动支持\万能显卡驱动1,%CurDir%\万能显卡驱动1.EXE
  10. LINK %Programs%\驱动支持\万能显卡驱动2,%CurDir%\万能显卡驱动2.EXE
  11. LINK %Programs%\驱动支持\万能显卡驱动说明,%CurDir%\万能显卡驱动说明.TXT
  12. `IFEX %CurDir%\START_DRV.CMD,EXEC !%CurDir%\START_DRV.CMD
  13. EXIT
复制代码
所有驱动安装只用一个批处理START_DRV.CMD,代码如下:
  1. @ECHO OFF
  2. :: 本WINPE德常用驱动更新地址http://bbs.wuyou.net/forum.php?mod=viewthread&tid=134718&extra=page%3D2
  3. :: 如果内置驱动无法找到,可以使用XCAB或PECAB把自己或收集的驱动打包为CAB或者直接把INF驱动放本目录使用本工具加载即可,另外本程序也试图从本地硬盘的WINDOWS目录搜索相关驱动程序并安装
  4. mode con cols=70 lines=25
  5. COLOR 02
  6. CLS
  7. ECHO.
  8. ECHO    ╔──────────────────────────────╗
  9. ECHO    │                                                            │
  10. ECHO    │                  鸿越WINPE驱动支持工具                     │
  11. ECHO    │              本程序由鸿越软件小布点编写制作                │
  12. ECHO    │         你可把自己的驱动用PECAB打包后用本工具加载          │
  13. ECHO    │     本程序可以自由复制,使用和发布,版权归作者本人所有       │
  14. ECHO    │  QQ:9399100 QQ群号:29946542 E-MAIL:xiaobudian528@sina.com  │
  15. ECHO    │                                                            │
  16. ECHO    ╚──────────────────────────2010─㊣╝
  17. ECHO.
  18. ECHO.
  19. REG ADD "HKCU\SOFTWARE\Microsoft\Driver Signing" /f /v "Policy" /t REG_BINARY /d 00>NUL
  20. REG ADD "HKCU\SOFTWARE\Microsoft\Driver Signing" /f /v "Policy" /t REG_BINARY /d 00>NUL
  21. IF /I "%1"=="SOUND" GOTO:SOUND
  22. IF /I "%1"=="NET" GOTO:NET
  23. IF /I "%1"=="VGA" GOTO:VGA
  24. IF /I "%1"=="DRV" GOTO:DRV
  25. IF /I "%1"=="ALL" (TITLE 一键安装所有驱动&&GOTO:ALL)
  26. GOTO:ALL

  28. :INFCACHE
  29. START /Wait .\InfCacheBuild.exe %SystemRoot%
  30. PECMD UPNP -pnp
  31. GOTO:EOF

  33. :NETLINK
  34. SET K=HKLM\SYSTEM\CurrentControlSet\Services&&SET W=AutoShareServer&&SET S=AutoShareWks
  35. REG ADD %K%\Lanmanserver\parameters /v %S% /t REG_DWORD /d 0 /f>nul
  36. REG ADD %K%\Lanmanserver\parameters /v %W% /t REG_DWORD /d 0 /f>nul
  37. REG ADD %K%\lanmanworkstation\parameters /v %S% /t REG_DWORD /d 0 /f>nul
  38. REG ADD %K%\lanmanworkstation\parameters /v %W% /t REG_DWORD /d 0 /f>nul
  39. REGSVR32 /s %windir%\system32\stobject.dll
  40. FOR /F %%i IN ('@reg query "HKLM\SYSTEM\CurrentControlSet\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}" /s^|find /i "\Connection"') DO >nul REG ADD %%i /v ShowIcon /t REG_DWORD /d 1 /f>nul
  41. ::安装和启动无线网络(由于驱动支持中安装会跳出对话框所以转移到这里)
  42. PECMD UPNP -v -c s -i MS_WZCSVC
  43. PECMD SERV WZCSVC
  44. If Exist "%USERPROFILE%\桌面\安装网卡驱动.LNK" DEL "%USERPROFILE%\桌面\安装网卡驱动.LNK"
  45. PECMD IFEX %ProgramFiles%\nettools\hysoft.ini,load %ProgramFiles%\nettools\hysoft.ini
  46. IF EXIST "%ProgramFiles%\INTERNET EXPLORER\IEXPLORE.EXE" (
  47.    DEL /Q/F "%ProgramFiles%\INTERNET EXPLORER\MSHTML*" >NUL
  48.    ECHO EXEC !%%CurDir%%\INSIE6.CMD>"%ProgramFiles%\INTERNET EXPLORER\hysoft.ini"
  49.    PECMD load %ProgramFiles%\INTERNET EXPLORER\hysoft.ini
  50. )
  51. GOTO:EOF

  53. :SOUNDLINK
  54. :: 不能在INI中使用PECMD EXEC来执行批处理,除非在批处理中PUSHD %~dp0转到当前路径处理,否则路径有问题,这里不对WMP10.WIM进行修改而添加HYSOFT.INI以便使用PECMD LOAD进行处理
  55. If Exist "%USERPROFILE%\桌面\安装声卡驱动.LNK" DEL "%USERPROFILE%\桌面\安装声卡驱动.LNK"
  56. PECMD IFEX %ProgramFiles%\multimedia\hysoft.ini,load %ProgramFiles%\multimedia\hysoft.ini
  57. IF EXIST %ProgramFiles%\WMP10\INSWMP.CMD (
  58.    DEL /Q/F %ProgramFiles%\WMP10\QUARTZ.DLL>NUL
  59.    ECHO EXEC !%%CurDir%%\INSWMP.CMD>"%ProgramFiles%\WMP10\hysoft.ini"
  60.    PECMD load %ProgramFiles%\WMP10\hysoft.ini
  61. )
  62. GOTO:EOF

  64. :SOUND
  65. ECHO 正在安声卡驱动...
  66. PECMD.EXE DEVI ".\DRIVERS_SOUND.CAB"
  67. CALL:INFCACHE
  68. CALL:SOUNDLINK
  69. GOTO:END

  71. :NET
  72. ECHO 正在安网卡驱动...
  73. FOR /F %%i IN ('Dir /B /A-D ^".\DRIVERS_NET*.CAB^"') DO PECMD DEVI ".\%%i"
  74. CALL:INFCACHE
  75. CALL:NETLINK
  76. GOTO:END

  78. :VGA
  79. ECHO 正在安显卡驱动...
  80. PECMD.EXE DEVI ".\DRIVERS_VGA.CAB"
  81. CALL:INFCACHE
  82. If Exist "%USERPROFILE%\桌面\安装显卡驱动.LNK" DEL "%USERPROFILE%\桌面\安装显卡驱动.LNK"
  83. ::START /Wait .\AutoSC.exe
  84. GOTO:END

  86. :DRV
  87. ECHO 正在安装用户自定义驱动...
  88. :: 搜索MYDRIVERS下的驱动文件和系统目录的驱动文件,如果还找不到就使用当前内置驱动程序,为了减小体积,建议使用SMARTDRIVERS提取驱动并用PECAB打包(不打包发现不能直接加载INF文件)MYDRV.CAB文件,其他驱动包则可省略
  89. ::FOR /R  %%I IN (*.INF) DO CALL PECMD.EXE DEVI %%I
  90. ::FOR /R  %%I IN (.) DO CALL PECMD.EXE DEVI "%%I\*.INF"
  91. PECMD.EXE DEVI ".\DRIVERS_MY*.CAB"
  92. PECMD.EXE DEVI ".\MY*.CAB"
  93. If Exist "%USERPROFILE%\桌面\安装显卡驱动.LNK" DEL "%USERPROFILE%\桌面\安装显卡驱动.LNK"
  94. If Exist "%USERPROFILE%\桌面\安装我的驱动.LNK" DEL "%USERPROFILE%\桌面\安装我的驱动.LNK"
  95. If Exist "%USERPROFILE%\桌面\安装所有驱动.LNK" DEL "%USERPROFILE%\桌面\安装所有驱动.LNK"
  96. :: ECHO 正在搜索系统目录下的驱动...
  97. ::PECMD.EXE DEVI \Windows\Inf\*.inf
  98. ::PECMD.EXE DEVI \WINNT\Inf\*.inf
  99. CALL:INFCACHE
  100. CALL:SOUNDLINK
  101. CALL:NETLINK
  102. GOTO:END

  104. :ALL
  105. :: 安装所有驱动包含了用户驱动包
  106. ECHO 正在安装声显网驱动...
  107. PECMD.EXE DEVI ".\*.CAB"
  108. If Exist "%USERPROFILE%\桌面\安装所有驱动.LNK" DEL "%USERPROFILE%\桌面\安装所有驱动.LNK"
  109. If Exist "%USERPROFILE%\桌面\安装我的驱动.LNK" DEL "%USERPROFILE%\桌面\安装我的驱动.LNK"
  110. CALL:INFCACHE
  111. CALL:SOUNDLINK
  112. CALL:NETLINK
  113. GOTO:END


  116. :END
  117. ECHO 完成安装,正在进行后期处理...
  118. DEL /Q/F %SystemRoot%\INF\*.PNF %SystemRoot%\INF\INFCACHE.1
  119. REG ADD "HKCU\SOFTWARE\Microsoft\Driver Signing" /f /v "Policy" /t REG_BINARY /d 00>NUL
  120. REG ADD "HKCU\SOFTWARE\Microsoft\Driver Signing" /f /v "Policy" /t REG_BINARY /d 00>NUL
  121. PECMD FIND EXPLORER.EXE,KILL EXPLORER.EXE
  122. IF EXIST %SystemRoot%\system\PENetCfg.exe Start "" "%SystemRoot%\system\PENetCfg.exe "
  123. EXIT
  124. [code]
  125. 三.虽然PETOOLS的外置程序没有多大问题,但是我也对其进行了改良,原来文件比较多,现在只需要一个批处理即可，而且代码非常智能,在自动创建外置PETOOLS的创建快捷方式的同时，能自动导入注册表或者执行INF安装，还可以指定批处理参数1用于整合到原始菜单中.代码如下:
  126. [code]
  127. @ECHO OFF
  128. :: 鸿越软件原创工具,在自动创建外置PETOOLS的创建快捷方式的同时，能自动导入注册表或者执行INF安装，还可以指定批处理参数1用于整合到原始菜单中
  129. :: 使用方法:如果要自动加载则在WINPE.INI中添加一行FORX !\PETOOLS\PETOOLS.INI,MYPETOOLS,1,LOAD %MYPETOOLS%
  130. ::          MAIN.INI中的代码只是加载本批处理EXEC !%CurDir%\PETOOLS.CMD
  131. mode con cols=70 lines=25
  132. COLOR 02
  133. CLS
  134. ECHO.
  135. ECHO    ╔──────────────────────────────╗
  136. ECHO    │                                                            │
  137. ECHO    │                 鸿越PETOOLS自动搜索工具                    │
  138. ECHO    │              本程序由鸿越软件小布点编写制作                │
  139. ECHO    │         你可把自己的驱动用PECAB打包后用本工具加载          │
  140. ECHO    │     本程序可以自由复制,使用和发布,版权归作者本人所有       │
  141. ECHO    │  QQ:9399100 QQ群号:29946542 E-MAIL:xiaobudian528@sina.com  │
  142. ECHO    │                                                            │
  143. ECHO    ╚──────────────────────────2010─㊣╝
  144. ECHO.
  145. ECHO.
  146. SET WGZY=外挂资源
  147. FOR /F "TOKENS=2*" %%I IN ('REG QUERY "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Programs" ^|find "Programs"') DO SET myprg=%%J
  148. IF EXIST "%myprg%\PETOOLS" RD /Q/S "%myprg%\PETOOLS"
  149. for /r %%i in (*.exe *.wim *.reg *.inf *.txt) do (
  150.     if not exist "%myprg%%%~pi" md "%myprg%%%~pi"
  151.     if /i "%%~xi"==".reg" regedit /s "%%i"
  152.     if /i "%%~xi"==".inf" (
  153.          ECHO %%~xi|FIND "%WGZY%"
  154.          IF "%ERRORLEVEL%"=="1" RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 128 "%%i"
  155.     ) else (
  156.     echo 正在创建%%i的快捷方式
  157.     pecmd link %myprg%%%~pi%%~ni,%%i
  158.    )
  159. )
  160. :: 对外挂XP资源进行处理,使用原来的菜单
  161. IF EXIST "%myprg%\PETOOLS\%WGZY%"  RD /Q/S "%myprg%\PETOOLS\%WGZY%"
  162. CALL .\%WGZY%\XP资源快捷方式.CMD
  163. :: 如果用户想把现在的菜单和原来的菜单整合则可以使用批处理参数1
  164. if /i "%1"=="1" xcopy /y /s "%myprg%\PETOOLS\*.*"  "%myprg%">NUL
  165. if /i "%1"=="1" RD /Q/S "%myprg%\PETOOLS"
  166. exit
复制代码


最后,由于更改了很多东西,所以WINPE.INI需要变更以下,代码如下
  1. _sub mountwimfile
  2.         name wimname=%swim%
  3.         moun %swim%,%mountpath%\%wimname%\,1
  4.         load %mountpath%\%wimname%\main.ini
  5. _end

  7. team envi soft=%curdrv%\minipe|envi bsc=%soft%\programs|envi sys=%soft%\system|envi drv=%soft%\drivers|envi pf=pagefile.sys
  8. `forx \%pf%,lastpf,0,file %lastpf%
  9. load %drv%\hysoft.ini `安装驱动,创建加载驱动的快捷方式,采用驱动支持和驱动包分离形式以便随时更新驱动
  10. envi mountpath=%systemroot%
  11. forx %sys%\*.wim,swim,0,call mountwimfile `安装system目录下的声卡和网卡驱动支持,其中也包括了DX和MMC工具
  12. envi mountpath=x:\program files
  13. forx %bsc%\*.wim,swim,0,call mountwimfile `安装基础应用程序,其中部分没有使用main.ini的表示纯绿色,如果包含hysoft.ini表示我的专用包,在安装驱动时自动安装
  14. FORX !\PETOOLS\PETOOLS.INI,MYPETOOLS,1,LOAD %MYPETOOLS% `安装PETOOLS中的非WIM包外置程序,如果没有本命令也可以在进入WINPE使用另外一个PETOOLS加载工具加载
  15. ifex %curdrv%\startcd.exe,link %startmenu%\winpe安装程序,%curdrv%\startcd.exe    `开始菜单建立光盘自动播放快捷方式
  16. find mem>168,wall %soft%\bliss.jpg `设置桌面背景
  17. ifex %bsc%\internet explorer.wim,envi $path=%path%;%programfiles%\internet explorer `添加IE环境变量
  18. exit
复制代码

[ 本帖最后由 HUNRYBECKY 于 2010-11-10 22:19 编辑 ]
作者: wbz2cdma    时间: 2010-11-11 00:18
非常好，学习了，自己修改一下。
作者: llztt    时间: 2010-11-11 08:26
也很喜欢小马哥的PE，不过没有楼主这么深水平提不出好建议来，无线网卡驱动好加吗？
作者: HUNRYBECKY    时间: 2010-11-11 22:20
原帖由 llztt 于 2010-11-11 08:26 发表
也很喜欢小马哥的PE，不过没有楼主这么深水平提不出好建议来，无线网卡驱动好加吗？


无线网卡很好加。使用SMARTDRIVE提取后再使用PECAB或XCAB工具打包为CAB文件，放到驱动目录即可。
作者: zhdd2000    时间: 2010-11-11 22:27
LZ说的小马PE是哪版的？
是 小马_WINPE_2K3_永久珍藏_深度五周年纪念版（Build101022）么？
作者: HUNRYBECKY    时间: 2010-11-12 20:30
原帖由 zhdd2000 于 2010-11-11 22:27 发表
LZ说的小马PE是哪版的？
是 小马_WINPE2K3_永久珍藏_深度五周年纪念版（Build101022）么？


我的不是最新版本的，看了下，最新版本没有增加新功能，只是修正了一些错误，由于我自己修改的地方比较多，所以一直没有更新。小马PE没有打印机功能，最近正准备集成。
作者: 穿云鹤    时间: 2010-11-12 21:13
比较深奥，学习了，谢谢。
作者: photo510    时间: 2010-11-14 14:58
小马PE做的不错。多谢！

[ 本帖最后由 photo510 于 2010-11-14 15:27 编辑 ]
作者: mapeimapei    时间: 2010-11-14 18:55
谢谢楼主的热心优化，希望更多人以此版为模板，diy适合自己的PE。
作者: llztt    时间: 2010-11-14 20:32
恩那，支持小马哥PE越做越好，最近整的几个盘都是集成了小马哥的PE呢。。

坛里其他几位大大的，尤其是集成多个PE的模板，实在没时间和能力去消化了，而且也觉得多个PE使用率太低，所以就一个足矣。。



欢迎光临 无忧启动论坛 (http://wuyou.net/) Powered by Discuz! X3.3