【3.3更新】NCAB 右键最大CAB压缩批处理（XP/WIN7/PE通用，支持多层目录/PE驱动优化） - 无忧启动论坛

@echo off
::V1.12 Build 2011.03.03 By NicTense
::http://hi.baidu.com/nictense
setlocal enableextensions
setlocal enabledelayedexpansion
if "%~1"=="" goto action
if /i "%~1"=="/reg" goto reg
:cab
if not exist "%~1" exit
dir "%~1" /ad>nul 2>nul||makecab.exe /V3 /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=0 /L "%~dp1." "%~1"&&goto next
pushd "%~f1"
set /p=<nul>"%temp%\%~n1.tmp"
for /f "tokens=*" %%b in ('dir *.inf /a-d /on /b 2^>nul') do echo "%~f1\%%~b">>"%temp%\%~n1.tmp"
for /f "tokens=*" %%b in ('dir * /a-d /on /b 2^>nul') do if /i "%%~xb" neq ".inf" echo "%~f1\%%~b">>"%temp%\%~n1.tmp"
for /f "tokens=*" %%a in ('dir * /s /ad /on /b 2^>nul') do (
set d=%%~a
set d=!d:%~f1\=!
for /f "usebackq tokens=*" %%b in (`dir "%%~a\*.inf" /a-d /on /b 2^>nul`) do echo "%%~a\%%~b" "!d!\%%~b">>"%temp%\%~n1.tmp"
for /f "usebackq tokens=*" %%b in (`dir "%%~a\*" /a-d /on /b 2^>nul`) do if /i "%%~xb" neq ".inf" echo "%%~a\%%~b" "!d!\%%~b">>"%temp%\%~n1.tmp"
)
makecab.exe /V3 /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=0 /D FolderSizeThreshold=2147483648 /D DiskDirectoryTemplate="%~dp1." /D CabinetNameTemplate="%~n1.cab" /D InfFileName="%temp%\%~n1.inf" /D RptFileName="%temp%\%~n1.rpt" /F "%temp%\%~n1.tmp"
for %%a in (inf rpt tmp) do del /q "%temp%\%~n1.%%a">nul 2>nul
:next
if "%~2" neq "" shift&goto cab
exit
:action
echo NCAB V1.12 文件/目录最大CAB压缩右键菜单 By NicTense
echo.
set /p o=请选择您要进行的操作：（ I 安装 / U 卸载 / Q 退出）
if /i "%o%"=="I" goto reg
if /i "%o%"=="U" goto uninstall
if /i "%o%"=="Q" exit
cls&goto action
:reg
reg add HKCR\*\shell\最大CAB压缩\command /ve /t REG_SZ /d "%SystemRoot%\system32\ncab.cmd "%%1"" /f>nul 2>nul
reg add HKCR\Directory\shell\最大CAB压缩\command /ve /t REG_SZ /d "%SystemRoot%\system32\ncab.cmd "%%1"" /f>nul 2>nul
if /i "%o%" neq "I" PECMD.EXE LINK %SendTo%\NCAB最大压缩,%SystemRoot%\system32\ncab.cmd&exit
2>nul reg query HKCR\Directory\shell\最大CAB压缩\command|FIND /i "ncab.cmd">nul||goto needadmin
copy /y "%~0" "%SystemRoot%\system32\ncab.cmd">nul
if exist "%~dp0ncab.lnk" copy /y "%~dp0ncab.lnk" "%USERPROFILE%\SendTo\NCAB最大压缩.lnk">nul
echo.&echo 安装成功，您现在可以在任意文件或目录上使用最大CAB压缩右键菜单了。&echo.&echo 按任意键退出...&pause>nul&exit
:uninstall
reg delete HKCR\*\shell\最大CAB压缩 /f>nul 2>nul
reg delete HKCR\Directory\shell\最大CAB压缩 /f>nul 2>nul
reg query HKCR\Directory\shell\最大CAB压缩>nul 2>nul&&goto needadmin
del /q "%SystemRoot%\system32\ncab.cmd">nul 2>nul
del /q "%USERPROFILE%\SendTo\NCAB最大压缩.lnk">nul 2>nul
echo.&echo 卸载成功，相关文件和右键菜单已删除。&echo.&echo 按任意键退出...&pause>nul&exit
:needadmin
echo.&echo 操作失败，您没有相关的权限，请退出后用管理员身份重新运行本程序。&echo.&echo 按任意键退出...&pause>nul&exit

复制代码