无忧启动论坛

标题: 移动硬盘同时自动建ud区和其它主分区，扩展分区的方法 [打印本页]

---

作者: rroo    时间: 2011-5-20 23:08
标题: 移动硬盘同时自动建ud区和其它主分区，扩展分区的方法
用fbinst.exe和gdisk32.exer把移动硬盘同时建ud区（20m）和其它主分区，扩展分区（10g主分区，100g,100g其它分区），批处理要怎么写。

看以下几楼。

5楼所用文件参考：点击进入下载－U盘移动硬盘UD区安装程序.rar

[ 本帖最后由 rroo 于 2011-5-22 10:36 编辑 ]

---

作者: rroo    时间: 2011-5-21 10:20
标题: 看
看来这个问题只有sinoxer大师会懂呀

---

作者: hcygpdyj    时间: 2011-5-21 22:48
正好年初给女儿的移动硬盘做过这样的，现将方法分享给需要的朋友。

其实很简单的，UD后，移动硬盘实际上分成了不可见及可见两部分，做好UD后，用操作系统的磁盘管理，不可见分区为“未分配”，可见部分为“活动，主分区”
些时只要将“未分配”部分设成分区，硬盘就是两个分区了，这下就好办了，你可以删除第二分区，然后对删除部分进行分区的相关操作（千万不要对第一部分进行操作唷），完后，再做FB（我是用原来的FBA文件，估计用小一点的FBA也可以吧，但没试过，用比原来大的FBA文件肯定是不行的，别试了。最好还是用原来的FBA文件）。注意，做FB时不能用强制格式化。
有兴趣的不妨一试。我觉得用移动硬盘的朋友，做一个这样的盘，真的是太好太好了，哈哈！

---

作者: 2011cf    时间: 2011-5-22 07:27
这是晨枫的BAT‘
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
@Echo Off
mode con cols=66 lines=26
Set Prog=晨枫U盘启动工具v3.0
Title %Prog% - 安装介绍
Cls
Echo.
Echo.
Echo 　欢迎您使用%Prog% 　
Echo.　
Echo.　　　         
Echo 　安装前建议在下一个界面上按“H”打开安装教程阅读后再进行操作.
Echo.
Echo 　以减少安装与使用过程中可能出现的问题. (有问题请详阅帮助说明.)
Echo.
Echo.
Echo 　如遇到解决不了的问题，欢迎浏览我们网站寻求帮助或加入QQ群讨论！
Echo.
Echo.
Echo 　   珠海晨枫工作室：Http://MyFeng.COM
Echo.
Echo.
Echo.
Echo.           →按任意键进入主界面 ...
Pause >Nul

:_Start
mode con cols=64 lines=26
CLS
COLOR 0F
Title %Prog% - 安装功能选项
Echo.
Echo 　　　　　　╭──────────────────╮
Echo 　　　　　　│　　　　　　　　　　　　　　　　　　│
Echo 　　　╭──┤　       %Prog%        ├──╮
Echo 　　　│　　│　　　　　　　　　　　　　　　　　　│　　│
Echo 　　　│　　└──────────────────┘　　│
Echo 　　　│　　　　　　　　　　　　　　　　　　　　　　　　│
Echo 　　　│ 　       请选择功能选项： 　  　　             │
Echo 　　　│　　　　　　　　　　　　　　　　　　　　　　　　│
Echo 　　　│            [1] U 盘标准安装(推荐)              │
Echo 　　　│            [2] U 盘双隐藏分区安装              │
Echo 　　　│            [3] 移动硬盘多分区安装              │
Echo 　　　│            [4] 添加引导镜像或软件              │
Echo 　　　│            [5] 恢复磁盘初始状态                │
Echo 　　　│            [H] 程序安装使用教程                │
Echo 　　　│            [F] 运行FbinstTool   　　　         │
Echo 　　　│            [Q] 退出安装程序   　　　     　    │
Echo 　　　│　　　　　　　　　　　　　　　　　　　　　　　　│
Echo 　　　├────────────────────────┤
Echo 　　　│　 为防数据丢失，安装前请先备份好您的重要资料   │
Echo 　　　├────────────────────────┤
Echo 　　　│　      珠海晨枫工作室　Http://MyFeng.COM     　│
Echo 　　　╰────────────────────────╯
Echo.
CHOICE /C 12345HFQ /N /M 　　　请选择要进行的操作(1/2/3/4/5/H/F/Q)：
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 GOTO _StIns
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 GOTO _HidePart
IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 GOTO _MDisk
IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5 GOTO _AddFile
IF ERRORLEVEL 5 IF NOT ERRORLEVEL 6 GOTO _Reset
IF ERRORLEVEL 6 IF NOT ERRORLEVEL 7 GOTO _Help
IF ERRORLEVEL 7 IF NOT ERRORLEVEL 8 GOTO _FBTool
IF ERRORLEVEL 8 GOTO _exit

:_StIns
Set aName=U盘标准安装(推荐)
Call :_HD
Call :_InsMode
:_Part1
Set a=%USZ%
Set b=%ExSize%
Set /a StSZ=a-b
Cls
Echo.
Echo   === %aName%安装信息确认 ===
Echo.
Echo  引导模式:%bMode% %yBPB% %YNChs%
Echo.
Echo  UD区:%ExSize%M 可见区:%StSZ%M
Echo -----------------------------------------------------------
Call :_StStart
Call :_LoadFile
Goto _exit

:_HidePart
Set aName=U盘双隐藏分区安装
Call :_HD
Call :_InsMode
:_HPR
Set /a NewSz=%USZ%-%ExSize%
Title %Prog% - 设定第2隐藏分区大小
Cls
Echo.
Echo  磁盘:%HD% 容量:%USZ%MB %UnSG% UD区:%ExSize%M
Echo -------------------------------------------------
Echo.
ECHO  设定第2隐藏分区大小，直接输入数值无需带单位！
Echo.
Echo.
Set aHide=
Set /p aHide= →请输入第2隐藏分区大小(剩余:%NewSz%M)：
If "%aHide%"=="" Goto _HPR
echo %aHide% | findstr "[a-z]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入字母！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _HPR
echo %aHide% | findstr "[`~!@#$*()-_=+\{}'*;:,./?]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入符号！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _HPR
If "%aHide%"=="%NewSz%" (Cls & Echo. & Echo 设定值不得使用完剩余容量，请重新设置！& pause >nul & Goto _HPR)
if %aHide% gtr %NewSz% (Cls & Echo. & Echo 设定值大于剩余容量，请重新设置！& pause >nul & Goto _HPR)
Set /a alHide=%NewSz%-%aHide%
if %alHide% lss 32 (Cls & Echo. & Echo 剩余空间已小于32，请重新设置！& pause >nul & Goto _HPR)
Set a=%USZ%
Set b=%aHide%
Set c=%ExSize%
Set /a HPSZ=a-b-c
Set aSize=--size %HPSZ%M
Cls
Echo.
Echo   === %aName%安装信息确认 ===
Echo.
Echo  引导模式:%bMode% %yBPB% %YNChs%
Echo.
Echo  UD区:%ExSize%M 第2隐藏分区:%aHide%M 可见分区:%HPSZ%M
Echo -----------------------------------------------------------
Call :_StStart
Cls
Echo.
Echo  →正在创建第2隐藏分区,请稍候 ...
Gdisk32 %Gdst% /Y /CRE /PRI /FOR /Q >nul 2>nul
Call :_LoadFile
Goto _exit

:_MDisk
Set aName=移动硬盘多分区安装
Call :_HD
Title %Prog% - 选择移动硬盘分区数
Cls
Echo.
Echo  已选择安装磁盘:%HD% 容量:%USZ%MB %UnSG%
Echo -------------------------------------------------
Echo.
ECHO.             ╭────────────╮
ECHO        ╭──┤    移动硬盘分区选择    ├──╮
ECHO        │    └────────────┘    │
ECHO        │                                    │
ECHO        │        [1] . 分成一个分区          │
ECHO        │                                    │
ECHO        │        [2] . 分成二个分区          │
ECHO        │                                    │
ECHO        │        [3] . 分成三个分区          │
ECHO        │                                    │
ECHO        │        [4] . 分成四个分区          │
ECHO        │                                    │
ECHO        │        [5] . 分成五个分区          │
ECHO        │                                    │
ECHO        ╰──────────────────╯
Echo.
CHOICE /C 12345 /N /M 　　　　请选择所需的分区数量(1/2/3/4/5)：
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 Set PNum=1
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 Set PNum=2
IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 Set PNum=3
IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5 Set PNum=4
IF ERRORLEVEL 5 IF NOT ERRORLEVEL 6 Set PNum=5
Call :_InsMode
If "%PNum%"=="1" Goto _Part1
Set P1=
Set P2=
Set P3=
Set P4=
Set P5=
Set Num=1
Set /a NewSz=%USZ%-%ExSize%
:_Pn
Title %Prog% - 设定第%Num%分区大小
Cls
Echo.
Echo  磁盘:%HD% 容量:%USZ%MB %UnSG% UD区:%ExSize%M
Echo --------------------------------------------------
Echo.
Echo  设定第%Num%/%PNum%分区大小，直接输入数值无需带单位！
if not "%P1%" == "" (Set a1=第1区:%P1%)
if not "%P2%" == "" (Set a2=第2区:%P2%)
if not "%P3%" == "" (Set a3=第3区:%P3%)
if not "%P4%" == "" (Set a4=第4区:%P4%)
if not "%P5%" == "" (Set a5=第5区:%P5%)
if not "%P1%" == "" (Echo.&Echo  %a1% %a2% %a3% %a4% %a5%) ELSE (Echo.)
Echo.
Set input=
Set /p input= →请输入第%Num%分区大小(剩余:%NewSz%M)：
If "%input%"=="" Goto _PN
echo %input% | findstr "[a-z]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入字母！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _Pn
echo %input% | findstr "[`~!@#$*()-_=+\{}'*;:,./?]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入符号！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _Pn
If "%input%"=="%NewSz%" (Cls & Echo. & Echo 设定值不得使用完剩余容量，请重新设置！& pause >nul & Goto _Pn)
if %input% lss 32 (Cls & Echo. & Echo 设定值不能小于32，请重新设置！& pause >nul & Goto _Pn)
if %input% gtr %NewSz% (Cls & Echo. & Echo 设定值大于剩余容量，请重新设置！& pause >nul & Goto _Pn)
Set /a ainput=%NewSz%-%input%
if %ainput% lss 32 (Cls & Echo. & Echo 剩余空间已小于32，请重新设置！& pause >nul & Goto _Pn)
Set P%Num%=%input%
if not "%P1%" == "" (Set a=%P1%)
if not "%P2%" == "" (Set b=%P2%)
if not "%P3%" == "" (Set c=%P3%)
if not "%P4%" == "" (Set d=%P4%)
if not "%P5%" == "" (Set e=%P5%)
Set /a NewSz=%NewSz%-a-b-c-d-e
Set /a Num=%Num%+1
If not "%Num%"=="%PNum%" Goto _Pn

:_PnOK
Title %Prog% - 最后分区大小
Set P%Num%=%NewSz%
if not "%P1%" == "" (Set a1=第1区:%P1%)
if not "%P2%" == "" (Set a2=第2区:%P2%)
if not "%P3%" == "" (Set a3=第3区:%P3%)
if not "%P4%" == "" (Set a4=第4区:%P4%)
if not "%P5%" == "" (Set a5=第5区:%P5%)
Cls
Echo.
Echo  磁盘:%HD% 容量:%USZ%MB %UnSG% UD区:%ExSize%M
Echo --------------------------------------------------------------
if not "%P1%" == "" (Echo.&Echo  %a1% %a2% %a3% %a4% %a5%) ELSE (Echo.)
Echo.
Echo  剩余所有空间划分给第%Num%/%PNum%分区，约：%NewSz%M
Echo.
Echo.
Echo  →按任意键确认到下一步！
pause >nul
Cls
Echo.
Echo   === %aName%安装信息确认 ===
Echo.
Echo  引导模式:%bMode% %yBPB% %YNChs% UD区:%ExSize%M
Echo.
Echo  %a1% %a2% %a3% %a4% %a5%
Echo --------------------------------------------------------------
Set Num=1
Set aSize=--size %P1%M
Call :_StStart
Cls
Echo.
Echo  →正在创建扩展分区,请稍候 ...
Gdisk32 %Gdst% /Y /CRE /EXT >nul 2>nul
:_PnRs
Title %Prog% - 创建第%Num%分区
Cls
Set /a Num=%Num%+1
If "%Num%"=="%PNum%" Goto _PnF
Echo.
Echo  →正在创建第%Num%/%PNum%分区,请稍候 ...
Call,Set PaSz=%%P%Num%%%
Gdisk32 %Gdst% /Y /CRE /LOG /SZ:%PaSz% /FOR /Q >nul 2>nul
If not "%Num%"=="%PNum%" Goto _PnRs

:_PnF
Title %Prog% - 创建第%Num%分区
Cls
Echo.
Echo  →正在创建第%Num%/%PNum%分区,请稍候 ...
Gdisk32 %Gdst% /Y /CRE /LOG /FOR /Q >nul 2>nul
Call :_LoadFile
Goto _exit

Goto :EOF
:_HD
Title %Prog% - 选择操作磁盘
Cls
Echo ┌───────────────┐
Echo │ 功能选择: %aName% │
Echo └───────────────┘
Echo.
ECHO  本机磁盘列表：
Echo --------------------------------->%temp%\HDLst.txt
fbinst --list >>%temp%\HDLst.txt
Echo --------------------------------->>%temp%\HDLst.txt
type %temp%\HDLst.txt
for /f "tokens=1 delims=:" %%i in ('findstr /n .* %temp%\HDLst.txt') do set Line=%%i
Set /a Ln=%Line%-3
Echo.
Echo  *请根据容量谨慎选择,后面会对所选磁盘进行格式化！
Echo.
Echo.
Set HDNum=
Set /p HDNum= →请输入要操作的磁盘号(0-%Ln%),按回车继续：hd
if "%HDNum%"=="" Goto _HD
echo %HDNum% | findstr "[a-z]" >nul && Cls &&Echo.&&Echo 错误：不能输入字母,只需输入磁盘号即可！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _HD
echo %HDNum% | findstr "[`~!@#$*()-_=+\{}'*;:,./?]" >nul && Cls &&Echo.&&Echo 错误：不能输入符号,只需输入磁盘号即可！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _HD
if %HDNum% gtr %Ln% (Cls & Echo.&Echo 选择的磁盘号不存在，按任意键返回请重新选择！& pause >nul & Goto _HD)
Set HD=(hd%HDNum%)
REM GDISK目标磁盘
Set /a Gdst=%HDNum%+1
REM 取磁盘大小
Set /a SK=%HDNum%+1
for /f "skip=%SK% delims=" %%i in (%temp%\HDLst.txt) do (Echo %%i>%temp%\nLine.txt&Goto _aa)
:_aa
for /f "tokens=2" %%i in (%temp%\nLine.txt) do set UnSize=%%i
for /f "tokens=3" %%i in (%temp%\nLine.txt) do set UnSG=%%i
Set /a USZ=%UnSize%/2048
Goto :EOF

:_InsMode
Title %Prog% - 选择制作模式
Cls
Echo.
Echo  已选择安装磁盘:%HD% 容量:%USZ%MB %UnSG%
Echo -------------------------------------------------
Echo.
ECHO.             ╭────────────╮
ECHO        ╭──┤   请选择要制作的模式   ├──╮
ECHO        │    └────────────┘    │
ECHO        │                                    │
ECHO        │       [1] . USB—HDD—FAT32        │
ECHO        │                                    │
ECHO        │       [2] . USB—HDD—FAT16        │
ECHO        │                                    │
ECHO        │       [3] . USB—ZIP—FAT32        │
ECHO        │                                    │
ECHO        │       [4] . USB—ZIP—FAT16        │
ECHO        │                                    │
ECHO        │       [5] . USB—ZIP--FAT16        │
ECHO        │             [复制BPB到MBR]         │
ECHO        │                                    │
ECHO        ╰──────────────────╯
Echo.
CHOICE /C 12345 /N /M 　　　　请选择要进行的操作(1/2/3/4/5)：
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 GOTO _HDD32
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 GOTO _HDD16
IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 GOTO _ZIP32
IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5 GOTO _ZIP16
IF ERRORLEVEL 5 IF NOT ERRORLEVEL 6 GOTO _ZIP16B
PAUSE
:_HDD32
Set aMode=--fat32
Set bMode=USB-HDD-FAT32
Goto _YnChs
:_HDD16
Set aMode=--fat16
Set bMode=USB-HDD-FAT16
Goto _YnChs
:_ZIP32
Set aMode=--zip --fat32
Set bMode=USB-ZIP-FAT32
Goto _YnChs
:_ZIP16
Set aMode=--zip --fat16
Set bMode=USB-ZIP-FAT16
Goto _YnChs
:_ZIP16B
Set aMode=--zip --fat16
Set bMode=USB-ZIP-FAT16
Set BPB=Y
Goto _YnChs
:_YnChs
Title %Prog% - CHS模式选择
IF /i "%BPB%"=="Y" Set yBPB=复制BPB到MBR
Cls
Echo.
Echo  已选择引导模式：%bMode% %yBPB%
Echo -------------------------------------------------
Echo.
Echo  是否强制使用CHS模式？
Echo.
Echo  (用于某些不能自动检测模式的BIOS)
Echo.
Echo.
Set aChs=
Set Choice=
Set /P Choice= →如需强制输入Y然后按回车，直接回车可跳过：
If /I "%Choice%"=="Y" Set aChs=--chs
:_UdSize
Title %Prog% - 自定义UD区大小
IF "%aChs%"=="" (Set YNChs=不强制CHS模式) ELSE (Set YNChs=强制CHS模式)
Cls
Echo.
Echo  已选择%YNChs%
Echo -------------------------------------------------
Echo.
Echo  是否自定义UD区(隐藏区)大小？磁盘容量:%USZ%MB
Echo.
Echo  (默认为256M，不得低于此值，无需要请按回车跳过)
Echo.
Echo.
Set Choice=
Set /P Choice= →如需设置直接输入数值，不重设直接按回车：
If "%Choice%"=="" Goto _DeExSize
echo %Choice% | findstr "[a-z]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入字母！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _UdSize
echo %Choice% | findstr "[`~!@#$*()-_=+\{}'*;:,./?]" >nul && Cls &&Echo.&&Echo 错误：只输入数值，不能输入符号！&&Echo.&&Echo 按任意键返回重新输入！&&pause>nul&&goto _UdSize
if %Choice% lss 256 (Cls & Echo. & Echo 设定值不能小于256，请重新设置！& pause >nul & Goto _UdSize)
If "%Choice%"=="%USz%" (Cls & Echo. & Echo 设定值不得使用完剩余容量，请重新设置！& pause >nul & Goto _UdSize)
if %Choice% gtr %USZ% (Cls & Echo. & Echo 设定值大于剩余容量，请重新设置！& pause >nul & Goto _UdSize)
If not "%Choice%"=="" Goto _SetExSize
:_SetExSize
Set ExSize=%Choice%
Goto :EOF
:_DeExSize
Set ExSize=256
Goto :EOF

:_StStart
Title %Prog% - 安装信息确认
Echo.
ECHO  →准备安装%Prog%到磁盘%HD% %UnSG%
ECHO.
Echo.
ECHO   警告：该磁盘所有分区及数据将被清除！
ECHO.
ECHO.
ECHO  →按任意键开始安装！
Echo 
pause >nul
Title %Prog% - 格式化磁盘
Cls
ECHO.
ECHO  →正在格式化磁盘%HD%,请稍候 ...
fbinst %HD% format --force %aMode% --extended %ExSize%M %aSize% --align %aChs% >nul 2>nul
IF /i "%BPB%"=="Y" fbinst %HD% sync --copy-bpb >nul 2>nul
Goto :EOF

:_LoadFile
Title %Prog% - 安装启动文件
Cls
ECHO.
ECHO  正在安装启动文件，这可能需要数分钟，请耐心等候 ...
fbinst %HD% load myfeng.fba >nul 2>nul
Title %Prog% - 安装成功
Cls
ECHO.
ECHO  恭喜您，%Prog%成功安装到磁盘%HD%
ECHO.
ECHO.
ECHO  提示：请弹出磁盘%HD%后重新插上再进行操作！
ECHO.
ECHO.
ECHO  →按任意键退出安装程序！
Echo 
pause >nul
@Start iexplore.exe http://myfeng.com
Goto _exit

:_AddFile
Title %Prog% - 添加引导镜像或软件
Set aName=添加引导镜像或软件
Call :_HD
Cls
Echo.
Echo  已选择写入磁盘：%HD% 容量:%USZ%MB %UnSG%
Echo -----------------------------------------------------
ECHO.
ECHO              ╭────────────╮
ECHO        ╭──┤    选择添加文件类型    ├──╮
ECHO        │    └────────────┘    │
ECHO        │                                    │
ECHO        │    [1] . 添加自定义引导镜像文件    │
ECHO        │                                    │
ECHO        │    [2] . 添加 PE2003 内置工具      │
ECHO        │                                    │
ECHO        │    [F] . 运行FbinstTool可视操作    │
ECHO        │                                    │
ECHO        │    [M] . 返回主菜单安装界面        │
ECHO 　　　 │　                                　│
ECHO 　　　 ╰──────────────────╯
Echo.
CHOICE /C 12FM /N /M 　　　　请选择添加文件类型(1/2/F/M)：
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 Goto _AddIMG
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 Goto _AddTool
IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 Goto _FbAdd
IF ERRORLEVEL 4 Goto _Start

:_AddIMG
Title %Prog% - 添加自定义引导镜像
Cls
Echo.
Echo  已选择写入磁盘：%HD% 容量:%USZ%MB %UnSG%
Echo ----------------------------------------------------------
Echo.
ECHO  增加引导镜像文件到已制作好的启动盘！
Echo.
ECHO  未使用%Prog%制作启动盘不能使用本工具！
Echo.
Echo  文件写入到UD区MYIMG目录！
Echo.
ECHO  仅支持: .IMG .IMA .GZ .ISO .BIN格式可引导镜像文件！
Echo.
ECHO  如需添加其它文件，在上一界面按F使用FbinstTool操作！
ECHO.
Echo ----------------------------------------------------------
ECHO  启动盘制作时UD区默认为256M,除启动文件占用后约剩余25M空闲
ECHO  如需添加大文件,请制作时注意预留好所需空间.
Echo ----------------------------------------------------------
ECHO.
ECHO.
Set Choice=
Set /P Choice= →把要添加的镜像文件拖到本窗口，按回车继续：
Cls
for /F "usebackq delims=[]" %%I in (`echo %Choice%`) do set FileName=%%~nxI
ECHO.
ECHO  正在复制镜像文件到磁盘%HD%,请稍候 ...
fbinst %HD% add "myimg/%FileName%" %Choice% >nul 2>nul
if not %ERRORLEVEL% == 0 (
Cls
Echo.
Echo  出错提示：文件写入失败！
Echo.
Echo  请确认所选磁盘是否已经安装为启动盘.
Echo.
Echo  →按任意键返回安装主界面！
Echo 
pause >nul
Goto _Start)
Cls
ECHO.
ECHO  镜像文件"%FileName%"添加成功！
Echo -----------------------------------------------------
ECHO.
ECHO  使用方法：
ECHO.
ECHO  设置从U盘启动进到引导界面后，进入 [07] 运行我的镜像文件，
ECHO.
ECHO  选择：“运行 %FileName%”。注：镜像文件必须可引导。
ECHO.
ECHO.
ECHO  →按任意键退出程序！
Echo 
pause >nul
Goto _exit
:_AddTool
Title %Prog% - 添加PE工具
Cls
Echo.
Echo  已选择写入磁盘：%HD% 容量:%USZ%MB %UnSG%
Echo ----------------------------------------------------------
Echo.
ECHO  增加PE工具到已制作好的启动盘！
Echo.
ECHO  未使用%Prog%制作启动盘不能使用本工具！
Echo.
Echo  文件写入到UD区UdTools目录！
Echo.
ECHO  仅支持: .EXE .WIM .BAT .CMD格式的单个文件的工具！
Echo.
ECHO  如需添加其它文件，在上一界面按F使用FbinstTool操作！
ECHO.
Echo ----------------------------------------------------------
ECHO  启动盘制作时UD区默认为256M,除启动文件占用后约剩余25M空闲
ECHO  如需添加大文件,请制作时注意预留好所需空间.
Echo ----------------------------------------------------------
ECHO.
ECHO.
Set Choice=
Set /P Choice= →把要添加的文件拖到本窗口，按回车继续：
Cls
for /F "usebackq delims=[]" %%I in (`echo %Choice%`) do set FileName=%%~nxI
ECHO.
ECHO  正在复制文件到磁盘%HD%,请稍候 ...
fbinst %HD% add "udtools/%FileName%" %Choice% >nul 2>nul
if not %ERRORLEVEL% == 0 (
Cls
Echo.
Echo  出错提示：文件写入失败！
Echo.
Echo  请确认所选磁盘是否已经安装为启动盘.
Echo.
Echo  →按任意键返回安装主界面！
Echo 
pause >nul
Goto _Start)
Cls
ECHO.
ECHO  PE工具"%FileName%"添加成功！
Echo -----------------------------------------------------
ECHO.
ECHO  使用方法：
ECHO.
ECHO  设置从U盘启动进入到PE后，点"开始菜单" 顶部的 UdTools 目录下
ECHO.
ECHO  选择：“%FileName%”。
ECHO.
ECHO.
ECHO  →按任意键退出程序！
Echo 
pause >nul
Goto _exit
:_FbAdd
Title %Prog% - 使用FbinstTool
Cls
ECHO.
ECHO.   === 文件添加操作说明 ===
Echo ----------------------------------------------------------
ECHO.
ECHO  添加自定义引导镜像,复制到UD区MYIMG目录
Echo.
ECHO  具体详阅UD区MYIMG\UDMyFeng.TXT(此文件不能删除)
ECHO.
Echo ----------------------------------------------------------
ECHO.
Echo  添加PE工具,复制到UD区UdTools目录
Echo.
ECHO  具体详阅UD区UdTools\本目录说明.txt
ECHO.
Echo ----------------------------------------------------------
ECHO  启动盘制作时UD区默认为256M,除启动文件占用后约剩余25M空闲
ECHO  如需添加大文件,请制作时注意预留好所需空间.
Echo ----------------------------------------------------------
ECHO.
ECHO  →按任意键运行FbinstTool.
pause >nul
Goto _FBTool

:_Reset
Set aName=恢复磁盘初始状态  
Call :_HD
Title %Prog% - 重置磁盘
Cls
Echo.
ECHO  正准备把磁盘%HD%恢复至初始状态！
Echo.
ECHO.
ECHO   警告：该磁盘所有分区及数据将被清除！
ECHO.
ECHO.
ECHO  →按任意键将开始恢复磁盘！
Echo 
pause >nul
Cls
ECHO.
ECHO  →正在把磁盘%HD%恢复至默认状态,请稍候 ...
fbinst %HD% format --force --raw >nul 2>nul
Cls
ECHO.
ECHO  磁盘%HD%重置成功！
ECHO.
ECHO  提示：请弹出磁盘%HD%后重新插上再进行操作！
ECHO.
ECHO.
ECHO  →按任意键退出程序！
Echo 
pause >nul
@Start iexplore.exe http://myfeng.com
Goto _exit

:_FBTool
@Start FbinstTool.exe
Goto _exit

:_Help
Help\Index.htm
Goto _Start

:_exit
if exist "%temp%\nLine.txt" del /q "%temp%\nLine.txt"
if exist "%temp%\HDLst.txt" del /q "%temp%\HDLst.txt"
exit
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

---

作者: rroo    时间: 2011-5-22 08:53
标题: 回复 #4 2011cf 的帖子
谢了。这里还有一种方法：
参考：【原创】【更新】gdisk32快速 整数 分区工具 批处理
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=138208

修改了上面的cmd，命名为gdisk.CMD,修改好的代码如下：

@echo off
set pro=gdisk32
:choicedisk
echo.
echo 磁盘明细列表:
%pro%
echo.
Set /P disk=请选择硬盘(Disk)序号，然后回车:
If /I '%disk%'=='1' goto MENU
If /I '%disk%'=='2' goto MENU
If /I '%disk%'=='3' goto MENU
echo.
ECHO 所选硬盘序号太大，请参看“磁盘明细列表”
goto choicedisk

:MENU
cls
color 4E
Echo.
Echo 　　　　　　┏━━━━━━━━━━━┓
Echo 　　　　　　┃　　　　　　　　　　　┃
Echo 　　　　　　┃　GDisk 分区中文向导　┃
Echo 　　┏━━━┫　 ☆完美整数分区☆ 　┣━━━┓
Echo 　　┃  　　┃　　王钟  倾心制作　　┃　　　┃
Echo 　　┃  　　┃　　　　　　　　　　　┃　　　┃
Echo 　　┃　　　┗━━━━━━━━━━━┛　　　┃
Echo 　　┃　　　　　　　　　　　　　　　　　　　┃
Echo 　　┃　　　　 你选择了第 %disk% 个硬盘 　　　　 ┃
Echo 　　┃　　　  　　 1. 分区信息  　　　  　  ┃
Echo 　　┃　　　  　　 2. 删除分区  　　　  　  ┃
Echo 　　┃　　　　　　 3. 新建分区     　  　　 ┃
Echo 　　┃　　　　　　 Q. 退出程序    　　　　　┃
Echo 　　┃　　　　　　　　　　　　　　　　　　　┃
Echo 　　┗━━━━━━━━━━━━━━━━━━━┛
Echo.

Set Choice=
Set /P Choice=　　　请选择操作（1/2/3/Q），然后按回车键：
If /I '%Choice%'=='1' GOTO SEE
If /I '%Choice%'=='2' GOTO DELP
If /I '%Choice%'=='3' GOTO BEGIN
If /I '%Choice%'=='Q' GOTO END
Goto MENU

:SEE
cls
echo 请等待载入...磁盘 %disk% 明细列表:
%pro% %disk%
echo.
echo 按任意键返回主菜单
pause>nul
goto menu

:DELP
cls
echo.
echo 请等待载入...磁盘 %disk% 明细列表:
%pro% %disk%
echo.
echo 输入要删除的分区序号，输入"ALL"删除所有分区:
set DP=
Set /P DP=:
set PDP=/P:%DP%
if /i '%DP%'=='all' set PDP=/all
echo.
echo 正在删除 %DP% 分区...
echo.
%pro% %disk% /del %PDP%
if '%PDP%'=='/all' goto menu
echo.
Set /P todel=:所选分区已删除，是否继续删除分区(Y/N)？
if /i '%todel%'=='Y' goto DELP
goto menu

:BEGIN
cls
setlocal enabledelayedexpansion
echo 请等待载入...磁盘 %disk% 明细列表:
%pro% %disk%
echo.
set size=
Set /P size=输入ud区大小(单位:M,如20):
%pro% %disk% /cre /pri /sz:%size% /for /q
echo.
echo 输入各分区大小(单位:GB),空格或","分开,最后一个分区不输:
echo.
echo 例1:要分5G,15G,50G,(余)50G 共４分区，输入前３个:5 15 50(Enter)
echo.
echo 已有分区（无论几个）用一个 0 表示：
echo.
echo 例2:主、2逻辑分区已存在,再分逻辑分区5G,及余下10G，输入:0 5(Enter)
echo 　　　　　　　　 　　  　 　   　                      ▲
set size=
Set /P size=各分区大小:

echo.
echo 输入"NTFS"或"FAT"进行相应格式化，输入"N"或省略则不格式化:
set frmt=
Set /P frmt=:
set frmty=
If /I '%frmt%'=='ntfs' set frmty=/for /q /ntfs&&set ss=1024
If /I '%frmt%'=='fat' set frmty=/for /q&&set ss=1028-8
echo 开始分区，稍等...
echo 分区过程信息:
for /f "tokens=1,2,3,4,5,6,7,8,9 delims=, " %%c in ("%size%") do (
set /A cp=%%c*%ss%
%pro% %disk% /cre /pri /sz:!cp! %frmty%
%pro% %disk% /act /p:2
%pro% %disk% /cre /ext
for %%i in (%%d,%%e,%%f,%%g,%%h,%%i,%%j,%%k) do (
set /A op=%%i*%ss%
%pro% %disk% /cre /log /sz:!op! %frmty%
))
%pro% %disk% /cre /log /end %frmty%
%pro% %disk% /del /p:1
echo.
echo 分区完成！
echo.
echo 按任意键返回主菜单
pause>nul
goto menu
:END

---

作者: 2011lkymail    时间: 2011-7-11 20:12
标题: 回复 #4 2011cf 的帖子
2011cf :你好，你真是太厉害了！你帖中的“晨枫的BAT”是不是就是
http://myfeng.cn/news_display.asp?keyno=115
下载里的“安装程序.exe”文件呢？这个文件是一个EXE文件，你怎么把它弄成BAT文件呢？
你莫不就是晨枫本人。。。。。。
真的是受益良多，谢谢!
在这里向你请教一些技术问题：
我已成功的安装了“晨枫U盘启动工具v3.0”到两个U盘，很好很满意。
现在我想将“晨枫U盘启动工具v3.0”安装到我的一个320G的移动硬盘，我的这硬盘已分了5个区，第一分区是2G，现在有一个Winpe系统，第一分区的数据可以备份到别的分区，但其它的分区数据太大无法备份。
我的问题是：我想在第一分区更换成“晨枫U盘启动工具v3.0”来作为启动盘，而不对这块移动硬盘重新分区格式化（第一分区可以进行分区等操作），也就是保留这块硬盘的数据资料，不知是否能实现，若能，请指教如何来实现。
先谢了！
可否能加我QQ，让我能更直接地得到你的帮助。我的QQ：237406489

---

作者: 20116339    时间: 2011-7-12 00:29
路过，学习中。。。。。。。。。

---

作者: 2010汲水先生    时间: 2011-7-18 23:18
标题: 回复 #6 2011lkymail 的帖子
貌似你运行那个EXE后会在系统的临时文件夹中产生一个BAT文件吧，里面的内容就是上面的批处理吧

---

作者: 2011lkymail    时间: 2011-7-19 16:32
标题: 回复 #8 2010汲水先生 的帖子
的确是这样，你真的好厉害，学习了，谢谢！

---

作者: ndyzx    时间: 2011-7-20 00:26
标题: 回复 #4 2011cf 的帖子
好强大的，批处理，学习了。

---

欢迎光临 无忧启动论坛 (http://wuyou.net/)

Powered by Discuz! X3.3