一键转移个人资料 v1.0 (build 2011.06.24) - 无忧启动论坛

@echo off
title 命令提示符
if "%1"=="/?" goto help
if "%1"=="/h" goto help
if "%1"=="/H" goto help
if "%1"=="/u" goto original
if "%1"=="/U" goto original
title 转移系统资料文件夹的位置－向导
:input
cls
echo 当前系统资料文件夹的名称及位置：
echo.
for /f "tokens=2*" %%a in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Personal ^|findstr "Personal"') do set MD=%%b
echo 『我的文档』
if "%MD%"=="" set MD=%USERPROFILE%\My Documents
echo %MD%
echo.
for /f "tokens=3*" %%a in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" ^|findstr "Music"') do set MM=%%b
echo 『我的音乐』
if "%MM%"=="" set MM=%USERPROFILE%\My Documents\My Music
echo %MM%
echo.
for /f "tokens=3*" %%a in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Video" 2^>nul^|findstr "Video"') do set MV=%%b
echo 『我的视频』
if "%MV%"=="" set MV=%USERPROFILE%\My Documents\My Videos
echo %MV%
echo.
for /f "tokens=3*" %%a in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Pictures" ^|findstr "Pictures"') do set MP=%%b
echo 『图片收藏夹』
if "%MP%"=="" set MP=%USERPROFILE%\My Documents\My Pictures
echo %MP%
echo.
for /f "tokens=2*" %%a in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Favorites ^|findstr "Favorites"') do set F=%%b
echo 『收藏夹』
if "%F%"=="" set F=%USERPROFILE%\Favorites
echo %F%
echo.
for /f "tokens=2 delims={}" %%a in ('REG QUERY HKCU\Identities /v "Default User ID" 2^>nul^|findstr /i "Default"') do @set O=%%a
for /f "tokens=3*" %%a in ('REG QUERY "HKCU\Identities\{%O%}\Software\Microsoft\Outlook Express\5.0" /v "Store Root" 2^>nul^|findstr "Store"') do @set OE=%%b
echo 『Outlook Express』
if "%OE%"=="" set OE=%USERPROFILE%\Local Settings\Application Data\Identities\{88888888-8888-8888-8888-888888888888}\Microsoft\Outlook Express\
echo %OE%
echo.
set /P OK="请输入一个指令或目标驱动器：[H | Q | U | drive:] "
if "%OK%"=="h" set h=1&goto help
if "%OK%"=="H" set h=1&goto help
if "%OK%"=="q" echo.&echo 正在退出. . .&call :ProcDelay 200&goto end
if "%OK%"=="Q" echo.&echo 正在退出. . .&call :ProcDelay 200&goto end
if "%OK%"=="u" goto original
if "%OK%"=="U" goto original
if not exist %OK%\nul goto input
xcopy "%MD%\*.*" "%OK%\My Documents" /q /h /r /y>nul 2>nul
xcopy "%F%\*.*" "%OK%\My Documents\Favorites" /s /q /h /r /y>nul 2>nul
rd "%F%" /s /q>nul 2>nul
:: xcopy "%MM%\*.*" "%OK%\My Documents\My Music" /s /q /h /r /y>nul 2>nul
:: rd "%MM%" /s /q>nul 2>nul
:: xcopy "%MP%\*.*" "%OK%\My Documents\My Pictures" /s /q /h /r /y>nul 2>nul
:: rd "%MP%" /s /q>nul 2>nul
xcopy "%MV%\*.*" "%OK%\My Documents\My Videos" /s /q /h /r /y>nul 2>nul
rd "%MV%" /s /q>nul 2>nul
xcopy "%OE%\*.*" "%OK%\My Documents\Outlook Express" /s /q /h /r /y>nul 2>nul
rd "%OE%" /s /q>nul 2>nul
rd "%MD%" /q>nul 2>nul
reg delete "HKCU\Identities\{%O%}" /f>nul
reg add "HKCU\Identities" /v "Default User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities" /v "Last User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities\{88888888-8888-8888-8888-888888888888}" /v "User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities\{88888888-8888-8888-8888-888888888888}\Software\Microsoft\Outlook Express\5.0" /v "Store Root" /t REG_EXPAND_SZ /d "%OK%\My Documents\Outlook Express\" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Favorites" /t REG_SZ /d "%OK%\My Documents\Favorites" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" /t REG_SZ /d "%OK%\My Documents\My Music" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Pictures" /t REG_SZ /d "%OK%\My Documents\My Pictures" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Video" /t REG_SZ /d "%OK%\My Documents\My Videos" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" /t REG_SZ /d "%OK%\My Documents" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Favorites" /t REG_EXPAND_SZ /d "%OK%\My Documents\Favorites" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "My Pictures" /t REG_EXPAND_SZ /d "%OK%\My Documents\My Pictures" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Personal" /t REG_EXPAND_SZ /d "%OK%\My Documents" /f>nul
echo.
echo 文件夹内容已经转移，注册表信息已经更改，重新启动后生效！
call :ProcDelay 400
goto end
:original
reg add "HKCU\Identities" /v "Default User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities" /v "Last User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities\{88888888-8888-8888-8888-888888888888}" /v "User ID" /t REG_SZ /d "{88888888-8888-8888-8888-888888888888}" /f>nul
reg add "HKCU\Identities\{88888888-8888-8888-8888-888888888888}\Software\Microsoft\Outlook Express\5.0" /v "Store Root" /t REG_EXPAND_SZ /d "%USERPROFILE%\Local Settings\Application Data\Identities\{88888888-8888-8888-8888-888888888888}\Microsoft\Outlook Express\" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Favorites" /t REG_SZ /d "%USERPROFILE%\Favorites" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" /t REG_SZ /d "%USERPROFILE%\My Documents\My Music" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Pictures" /t REG_SZ /d "%USERPROFILE%\My Documents\My Pictures" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Video" /t REG_SZ /d "%USERPROFILE%\My Documents\My Videos" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" /t REG_SZ /d "%USERPROFILE%\My Documents" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Favorites" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Favorites" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "My Pictures" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\My Documents\My Pictures" /f>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Personal" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\My Documents" /f>nul
if not "%MD%"=="%USERPROFILE%\My Documents" xcopy "%MD%\*.*" "%USERPROFILE%\My Documents" /q /h /r /y>nul 2>nul
if not "%F%"=="%USERPROFILE%\Favorites" xcopy "%F%\*.*" "%USERPROFILE%\Favorites" /s /q /h /r /y>nul 2>nul
if not "%F%"=="%USERPROFILE%\Favorites" rd "%F%" /s /q>nul 2>nul
:: if not "%MM%"=="%USERPROFILE%\My Documents\My Music" xcopy "%MM%\*.*" "%USERPROFILE%\My Documents\My Music" /s /q /h /r /y>nul 2>nul
:: if not "%MM%"=="%USERPROFILE%\My Documents\My Music" rd "%MM%" /s /q>nul 2>nul
:: if not "%MP%"=="%USERPROFILE%\My Documents\My Pictures" xcopy "%MP%\*.*" "%USERPROFILE%\My Documents\My Pictures" /s /q /h /r /y>nul 2>nul
:: if not "%MP%"=="%USERPROFILE%\My Documents\My Pictures" rd "%MP%" /s /q>nul 2>nul
if not "%MV%"=="%USERPROFILE%\My Documents\My Videos" xcopy "%MV%\*.*" "%USERPROFILE%\My Documents\My Videos" /s /q /h /r /y>nul 2>nul
if not "%MV%"=="%USERPROFILE%\My Documents\My Videos" rd "%MV%" /s /q>nul 2>nul
if not "%OE%"=="%USERPROFILE%\Local Settings\Application Data\Identities\{88888888-8888-8888-8888-888888888888}\Microsoft\Outlook Express" xcopy "%OE%\*.*" "%USERPROFILE%\Local Settings\Application Data\Identities\{88888888-8888-8888-8888-888888888888}\Microsoft\Outlook Express" /s /q /h /r /y>nul 2>nul
if not "%OE%"=="%USERPROFILE%\Local Settings\Application Data\Identities\{88888888-8888-8888-8888-888888888888}\Microsoft\Outlook Express" rd "%OE%" /s /q>nul 2>nul
if not "%MD%"=="%USERPROFILE%\My Documents" rd "%MD%" /q>nul 2>nul
echo.
echo 注册表信息已经恢复，文件夹内容已经转移，重新启动后生效！
call :ProcDelay 400
goto end
:help
if "%h%"=="1" echo.
echo 转移系统资料文件夹的位置。
echo.
echo DATAMOVE [drive:] [/U] [/Q] [/H]
echo.
echo drive: 指定要转移到的目标驱动器
echo /U 恢复系统默认值
echo /Q 向导中退出
echo /H 显示帮助信息
echo.
echo 不加任何参数键入 DATAMOVE，可以启动一个向导。
echo.
echo 目标驱动器将自动添加文件夹路径 My Documents。
echo.
echo 命令行开关 /U 会将更改过的系统注册表信息还原。
echo 它不会还原回您之前已更改系统的任何值，而直接
echo 还原回系统的默认值。
echo.
if "%h%"=="1" pause&set h=&goto input
goto end
:ProcDelay number
Setlocal EnableExtensions
for /f "tokens=1-4 delims=:. " %%h in ("%TIME%") do set start_=%%h%%i%%j%%k
:wait_
for /f "tokens=1-4 delims=:. " %%h in ("%TIME%") do set now_=%%h%%i%%j%%k
set /a diff_=%now_%-%start_%
if %diff_% lss %1 goto wait_
Endlocal
:end
set MD=
set MM=
set MV=
set MP=
set F=
set O=
set OE=
set OK=
set h=

复制代码