PE2.0,3.0,4.0 精简自动化测试批处理 - 无忧启动论坛

@echo off
setlocal enabledelayedexpansion
title WIMLite
rem 文件夹结构说明=======================
rem 在D 盘建立 Temp 文件夹
rem D:\Temp\winpe 放制作成ISO映像所需文件
rem D:\Temp\lite 存放卸载wim 后的文件
rem =====================================
set counter=
set a=
set "kernelfile=system32filelist.log"
set "wimdst=D:\Temp\winpe\iso\sources\boot.wim"
set "wimsrc=D:\Temp\lite"
set "sysdir=D:\Temp\lite\Windows\system32"
set vmruname="D:\Program Files\VMware\VMware Workstation\vmrun.exe"
set vmfilename="D:\Backup\我的文档\My Virtual Machines\Windows Server 2003 Enterprise Edition\Windows Server 2003 Enterprise Edition.vmx"
set "flagfile=D:\Temp\hello.txt"
set "errlogfile=errfile.log"
set "sucesslogfile=sucessfile.log"
set "etfsbootfilenmae=D:\Temp\winpe\etfsboot.com"
set "sourcelication=D:\Temp\winpe\iso"
set "tragetfile=D:\Temp\winpe.iso"
rem 倒计时
set "countime=70"
rem 检查相关文件是否存在
if not exist !vmruname! (
echo !vmruname! is missing.
echo Press any key to exit.
pause >nul
goto end)
if not exist !vmfilename! (
echo !vmfilename! is missing.
echo Press any key to exit.
pause >nul
goto end)
echo 获取需要检查的文件数量
if exist !kernelfile! (
for /f "delims=" %%i in (!kernelfile!) do (set /a a+=1)
) else (
echo !kernelfile! is missing.
echo Press any key to exit.
pause >nul
goto end)
for /f "delims= " %%i in (!kernelfile!) do (
echo.
echo 1. 删除成功标志文件
if exist !flagfile! del !flagfile!
echo 2. 重命名文件 %%i
ren !sysdir!\%%i %%i.bak
rem 恢复文件
rem ren !sysdir!\%%i %%i..
set /a counter+=1
title WIMLite 正在测试的文件 %%i 这是第 !counter! 个，总共 !a! 个
if exist !wimdst! (
echo 3. 追加映卷
WimTool.EXE /Boot /Append !wimsrc! !wimdst! "MyTools"
) else (
echo 3. 制作映像
WimTool.EXE /Boot /Compress Maximum /Capture !wimsrc! !wimdst! "MyTools")
if not exist !wimdst! (
echo !wimdst! is missing.
echo Press any key to exit.
pause >nul
goto end)
echo 4. 制作成ISO文件，减少将映像文件写入U盘所占用的时间
Oscdimg.exe -n -b!etfsbootfilenmae! !sourcelication! !tragetfile!
if not exist !tragetfile! (
echo !tragetfile! is missing.
echo Press any key to exit.
pause >nul
goto end)
echo 5. 启动虚拟机测试
!vmruname! start !vmfilename!
echo 6. 开始计时，必须在 !countime! 秒内写入成功标志，否则视为失败。
ping -n !countime! 127.0.0.1 >nul
rem 判断此文件删除是否会影响 PE 正常运行
if exist !flagfile! (
echo 7. %%i 可以删除，写入可以删除日志
echo %%i >>!sucesslogfile!
) else (
echo 7. %%i 不能删除，正在恢复文件 %%i，写入不能删除日志
ren !sysdir!\%%i.bak %%i
echo %%i >>!errlogfile!
)
rem echo 这里暂停一下，检查相关文件，检测批处理是否按照预期运作
rem pause
echo 8. 关闭虚拟机为下一次测试做好准备
!vmruname! stop !vmfilename!
)
rem 如果有错误产生就暂停，方便查看故障原因
if %errorlevel%==1 pause
:end
exit

复制代码