无忧启动论坛

标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！ [打印本页]

作者: shier2817 时间: 2004-7-7 22:11
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
各位好，我是大连某网吧做技术的，从最近网上出现各种版本、各种系统的纯净GHOST以后，也跃跃欲试的想尝试一下，网吧用GHOST相当普遍和熟练了，但都是做单机镜像的比较多，目标机也是同配置，现在出这种万能GHSOT系统不过是先把驱动去掉而已，原理我明白了。。。
但我老是在想几个个问题：
格式无所谓了，GHOST8.0不但较好的支持了WINDOWS格式，连LINUX的格式也能支持，所以目标盘是什么格式不重要，都可以刻成功。
第一：大小。先说最简单的C做系统盘，以前在网吧，如果C分3G，做好系统后做个镜像，GHSOT到大小为≥3G的C盘上可以完成，（这个跟实际占用多少空间并无联系，我试过多次。）但>3G的C盘显示只有3G了，那些空间也不知道哪去了？
但GHOST到<3G的C盘就会提示错误。。。
所以我想请教：如果用万能GHOST系统，目标盘的C盘与制作母盘时的大小不同是如何解决的？大了可以完成，但那些空间呢？小了不让刻，怎么办？（比如一40G硬盘分为3，10，27[理论值]，用一个在C为4G的盘上做出GHO不让刻），现在的万能系统是如何解决这个问题的？我郁闷这个问题很久了，谢谢回答啊！！！
第二：非C分区。我在网上看到有的万能系统说可以GHOST到任意分区，这个在论坛上的教程里没有提到过，教程里只建议把系统做到C盘，如果我想克隆到其他盘，到底怎么可以无错实现？多谢解答！
第三：双分区。2000和XP我会保留一份给人装系统，但现在网吧里的客户机还多是98，我也想把98做成这样一个万能系统，这样以后做系统简单多了，但我做的98系统都是为了性能和优化把许多临时文件都转到了D盘，比如文档，TEMP，COOKIES等等，还有虚拟内存我也放在D盘，请教：有没办法可以让这个万能系统一次性克隆完毕2个分区？就是克隆完C以后还能再克一个逻辑盘。最好是能够在克隆前可以手动自由选择那个逻辑盘（其实我想逻辑盘是否可以不用GHOST的，用其他的方法编辑命令向某个指定的逻辑盘里复制或生成一些需要的文件什么的？）但不太会实践，希望各位前辈帮忙理顺一下思路，怎么可以实现？

小弟不胜感激各位，在此先行谢过啦！！！！！！！！！！

作者: 张三丰 时间: 2004-7-7 22:17
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
看不懂啊！

作者: laotang 时间: 2004-7-7 22:36
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
1 不知你是直接分区到分区，还是先把分区压缩成映像文件再CLONE到目标分区，但按道理讲不会有你说的问题（至少我从没有遇到过）
2 论坛上有相关的帖子，但说到最后好像是不推荐安装到非c分区
3 你可以把c盘和d盘分别制作成2个映像文件，比如说IMAGE_C.GHO和IMAGE_D.GHO
在AUTOEXEC.BAT加入两句：
Ghost -CLONE,MODE=PLOAD,SRC=IMAGE_C.GHO:1,DST=1:1 -SURE
Ghost -CLONE,MODE=PLOAD,SRC=IMAGE_D.GHO:1,DST=1:2 -SURE -RB

作者: shier2817 时间: 2004-7-8 01:08
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
感谢3楼的回答
第一个问题假设：我制作万能母盘，C=5G，使用1.6G，制作成GHO
目标安装盘C只有3G，你是说完全可以克隆？
我记得以前是不行的，不过这个实验是很早的时候做过的，那时候GHOST的版本才5.几吧，从那以后，我一直认为这种克隆将是不被允许的。难道现在可以了？等我用8.0试下吧，谢谢你的回答，这个是我最郁闷的问题。
第二个问题论坛有的话我仔细翻翻，我刚到这里不久，看的不是很详细，耽误你的时间了，多谢！
第三个问题我想过向这样做是最简单的，但其实把临时的那些文件转移到非主分区不但是网吧这样做比较好，就是个人机如果装98也是这样做比较推荐（其实所有WINDOWS我都是这样做的），那如果光按您这种方法，给别人重新装系统的时候，那人家D盘里的东西不就完了？所以我想用一些命令在D盘安装的时候自动创建这些文件，保留住原来D盘的资料，这样是不是比较妥当？
其实光实现向D盘创建也并不难，但我想能否做成手动指定的？就是开始安装前提示选择向某个逻辑盘来创建这些文件，这样的选择提示有什么工具可以实现？或者您能给我点提示？
但就算实现询问选择盘的方式，还要保证，系统盘里的文件在安装的时候自动调用选择的盘来对应上，这个怎么可以实现？
比如：拿我的文档来说，安装前指定临时文件存放盘为D：，那安装完毕后，文档路径就自动改为“D:\My Documents”，如果指定临时文件盘为E：，那安装完后文档的位置就是“E:\My Documents”，这个怎么具体实现，请不吝指点一下，万谢了！
其实只要会了这个，现行的万能系统，包括2000，XP和2003的，都可以安装这些方式来做，这样算不算万能系统在系统优化上的又一个进步呢？何况如果有人不愿意更改这些文件的位置，只要安装前选临时文件盘为C：即可。
这种方法是否可行可用，请前辈们讨论一下啊！！！！！！

作者: shier2817 时间: 2004-7-8 15:21
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
再请各位前辈不吝赐教上面的问题！！！！
另，小弟正翻以前的老帖呢，突然有想到了一个关于GHOST万能系统的疑问：
各位前辈辛苦做出万能系统提供给我们这些菜菜，是为了方便，那如果某人就假设我吧，如果没有任何系统原盘，只下了这个万能系统，也刻录成光盘，成功安装了。。。
那请问我以后增删系统程序怎么办？其实删好说，在“添加删除”里卸载即可。那增呢？假设我装的是万能XP，我想再装进IIS（我不清楚先行万能版本有没安装，这里只拿IIS做例子，假设没安装），那怎么办，会提示我要安装盘的啊？那岂不是不万能了？
以前安装正常安装后，我为了以后安装系统程序简单，都把I386复制到D盘，反正现在的硬盘都吃得消。
但我也清楚，其实安装完毕后I386里有很多东西放在硬盘是没必要的，在增加新的系统程序时也用不到它们，因为里面的好多东西在安装系统时是必须安装过的，否则系统是不可能启动的，但我不清楚每个文件包的内容，不知道哪个有用，哪个没用，不知道哪位老大能做个分析，相信将是所有网虫之福！
如果把I386里那些可选程序组件的安装包提取出来，我想将不会太大，这样如果我上面那个第3个疑问如果被解决，那在系统安装的时候，可以把这些文件包自动复制到指定的逻辑盘里，那以后增删系统程序就不怕了。
希望大家帮助我一下，也会对所有和我一样的菜菜有许多的帮助。
感激不尽！！！！！！！！！！！！！！

作者: 满天飞 时间: 2004-7-8 21:15
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！

下面引用由shier2817在 2004/07/08 03:21pm 发表的内容：
假设我装的是万能XP，我想再装进IIS（我不清楚先行万能版本有没安装，这里只拿IIS做例子，假设没安装），那怎么办，会提示我要安装盘的啊？那岂不是不万能了？

我想万能XP中的"万能"指的并不是什么功能都齐全、而是对大多数主板都适合的意思。

作者: 金雕 时间: 2004-7-8 23:03
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！

下面引用由shier2817在 2004/07/08 01:08am 发表的内容：
感谢3楼的回答
第一个问题假设：我制作万能母盘，C=5G，使用1.6G，制作成GHO
目标安装盘C只有3G，你是说完全可以克隆？
我记得以前是不行的，不过这个实验是很早的时候做过的， ...

关于第一个假设，我想是可以的！这个并不是分区到分区，必须对应。而是由镜像文件到分区！所以应该能行，而且我也试过，至少我做的是可以的

作者: shier2817 时间: 2004-7-9 01:17
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
[这个贴子最后由shier2817在 2004/07/09 01:18am 第 1 次编辑]

“满天飞”朋友：
我这里说的只不过是个比方罢了，我无意争辩“万能”的本意到底是指什么的，如果说话有疏漏的地方，那对不起了。我主要的意愿是希望前辈总结出来的辛苦成果，我们也不该只管拿来享用，如果可以尽量的使它更完善一些，那不也是造福所有网民吗？你说呢？我提这个问题就是想解决GHOST的系统以后安装系统组件的问题，如果这个可以完美的实现，我想应该算是GHOST系统的一大改进吧？（现行的版本如果使用者手头没有系统原安装盘是不是就束手无策？）
“金雕”朋友：
谢谢你的回答，我今天刻意实验了下，确实是可以的，记得以前5.几的版本好象不支持（不过那个GHSOT.EXE竟然在WINDOWS和DOS下全部可以使用，现行的不可以，才出来GHOST32.EXE），现在的8.0的GHO文件不管分区大小的，只要够使用空间就能刻，确实如此。再次谢谢你！

那现在我的问题就成了：
1.如果想把系统的My Documents、COOKIES、TEMP、CACHE、History、Favorites、Temporary Internet Files等一些临时文件和交换文件不安装到C盘，而是安装之前就可以自定选择一个逻辑盘来存放将如何实现？
其实同理我们也可以实现在选定的逻辑盘上自建Program Files文件夹，然后在这里安装那些常用的应用工具。。。
其实实现这个最好不是GHOST到这个逻辑盘（因为那样将无法保留原逻辑盘数据），而是命令生成文件或COPY文件，这个我想类似于批处理的方式就可以实现，但，如何可以让系统盘里存储的那些关于这些临时文件、交换文件和应用程序文件的路径随着我们安装前指定的盘符而自动更改呢？怎么实现，请指点一二！
2.解决了第一个问题，这个问题其实迎刃而解，就是向指定的逻辑盘内COPY那些可选但不是必选的系统组件安装原文件，这样以后这种GHOST系统想增加系统组件就简单的很了。但也有个问题，整个COPY I386文件夹太不实际，但我不清楚那些组件都分别对应在哪个安装包里，这个请前辈分析整理下，系统安装时必选的那些组件包我们就可以删除了，希望大家研究下，多多赐教，不胜感激！！！
3.我今天狂翻了论坛，好象都没找到比较完善的教程讲解如果制作可以安装到任意分区（就是说不光能按到C：）的万能GHOST系统的方法，如果哪为朋友有心，请给个连接，万谢了！！！

作者: shier2817 时间: 2004-7-9 11:22
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
顶起求解！

作者: Climbing 时间: 2004-7-9 12:39
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
1、修改My Documents等系统文件夹的默认位置可以通过批处理直接修改注册表。这些操作最好在Ghost完成后由用户自己选择再做，因为每台机器的分区情况均不同，不可能由恢复程序自由确定的。
2、Ghost系统不可能集成系统安装盘（否则就只能用DVD刻录了）。这好有一比，如果你只有Ghost系统光盘，它不可能帮你集成一台计算机的。
3、恢复到任意分区的方法也有，请访问Jujumao论坛，看死性不改的有关帖子。

作者: miren 时间: 2004-7-9 13:50
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
问题3本人认为你已在系统设置了你的临时文件夹和交换文件夹指向D盘
那么克隆的系统也就设置了，只需要在D盘创相应的文件夹就可以了，文件夹内的数据只有人工保存了。
（另外GHOST支持从映像文件中提取某个文件来还原）

作者: 金雕 时间: 2004-7-9 13:52
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
好像juju里的任意分区现在也不怎么完善呀！死性不改公布以后没有人测试

作者: 唯一闲人 时间: 2004-7-9 22:07
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
齐天宇的ghost xp盘就可以把我的文档啊，桌面什么的东东放到d盘，不过是克完后自动在d:建立我的桌面和文档之类的文件，我也想弄明白他是怎么做的，我想他可以解决这个问题吧，98应该也可以实现的，不过我还没有找到答案：（

作者: Climbing 时间: 2004-7-9 23:47
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
@echo off
rem 设置注册表键值类型，请到HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders下查询
set REGTYPE=REG_EXPAND_SZ
rem 设置个人文件夹的存放目录
set dst=D:\Personal
rem 修改完毕是否重新启动，重新启动前等待时间
set reboot=true
set wait=30
if not exist reg.exe goto _check
if not exist %windir%\system32\reg.exe goto _cpreg
goto _begin
:_check
if not exist %windir%\system32\reg.exe goto _err
goto _begin
:_err
echo .
echo Error: I cannot find reg.exe for modifying registry. Quit...
pause
goto _quit
:_cpreg
copy /y reg.exe %windir%\system32 > nul
:_begin
rem 建立相关的目录
if not exist "%dst%\My Documents\." md "%dst%\My Documents" > nul
if not exist "%dst%\My Documents\My Pictures\." md "%dst%\My Documents\My Pictures" > nul
if not exist "%dst%\Desktop\." md "%dst%\Desktop" > nul
if not exist "%dst%\Favorites\." md "%dst%\Favorites" > nul
if not exist "%dst%\Cookies\." md %dst%\Cookies > nul
if not exist "%dst%\Outlook Express\." md "%dst%\Outlook Express" > nul
rem 复制原目录中的文件到新的目录内
xcopy /e /y /q "%USERPROFILE%\My Documents" "%dst%\My Documents" > nul
if exist "%USERPROFILE%\桌面\." goto _cp_desk_1
if exist "%USERPROFILE%\Desktop\." goto _cp_desk_2
:_cp_desk_1
xcopy /e /y /q "%USERPROFILE%\桌面" "%dst%\Desktop" > nul
goto _cp_desk_exit
:_cp_desk_2
xcopy /e /y /q "%USERPROFILE%\Desktop" "%dst%\Desktop" > nul
goto _cp_desk_exit
:_cp_desk_exit
xcopy /e /y /q "%USERPROFILE%\Favorites" "%dst%\Favorites" > nul
xcopy /e /y /q "%USERPROFILE%\Cookies" %dst%\Cookies > nul
rem 备份要改变的注册表键值到%dst%\backup\UserShellFolders_bak.reg文件内
if not exist %dst%\backup\. md %dst%\backup > nul
if exist %dst%\backup\UserShellFolders_bak.reg goto _modireg
reg export "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" "%dst%\backup\UserShellFolders_bak.reg"
:_modireg
rem 更改相应的注册表键值
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Personal /t %REGTYPE% /d "%dst%\My Documents" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "My Pictures" /t %REGTYPE% /d "%dst%\My Documents\My Pictures" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Desktop /t %REGTYPE% /d "%dst%\Desktop" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Favorites /t %REGTYPE% /d "%dst%\Favorites" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Cookies /t %REGTYPE% /d "%dst%\Cookies" /f
rem 修改Outlook Express的默认保存位置
set userid=
tfind > nul
reg query "HKCU\Identities" /v "Default User ID" | tfind "Default User ID" | lmod set USERID=[$5] > temp.bat
call temp.bat
del temp.bat
if "%userid%"=="" goto _reboot
reg add "HKCU\Identities\%USERID%\Software\Microsoft\Outlook Express\5.0" /v "Store Root" /d "%dst%\Outlook Express" /f
:_reboot
if "%reboot%"=="true" shutdown -r -f -t %wait%

作者: Climbing 时间: 2004-7-9 23:52
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
上面是2000/xp/2003移动用户文件夹的批处理程序，下面是用于win98的，我自己的产品：
@echo off
:: 下面两行用户不需要修改更不能删除，否则不能保证本批处理能够正常运行
if "%1"=="" command.com /E:32768 /C %0 CallMySelf
if "%1"=="" goto _end
:: ******************************************************************************
:: 下面属于用户需要设置的内容
:: ******************************************************************************
:: 1. 设置用户文档存放位置
:: Personal=%doc%
:: Favorites=%doc%\Favorites
:: My Pictures=%doc%\My Pictures
:: My Music=%doc%\My Music
:: Outlook Express=%doc%\My Mails\Outlook Express
set doc=D:\Climbing
:: 设置Internet临时文件存放位置
:: Cache=%cache%\Temporary Internet Files
set cache=E:\TEMP
:: 设置其它的用户文件存放位置，包括：Cookies, Desktop, Start Menu等
set other=D:\SYSTEM
:: 设置修改完毕是否重新启动，重新启动前等待时间
set reboot=true
set wait=30
:: ******************************************************************************
:: 以上属于用户自己设置的内容，下面的内容用户不需修改
:: ******************************************************************************
set cache=%cache%\Temporary Internet Files
:_begin
:: 建立相关的目录
echo 建立用户指定的文件存放目录...
if not exist "%doc%\nul" md "%doc%" > nul
if not exist "%doc%\My Mails\nul" md "%doc%\My Mails" > nul
if not exist "%doc%\My Mails\Outlook Express\nul" md "%doc%\My Mails\Outlook Express" > nul
if not exist "%doc%\My Pictures\nul" md "%doc%\My Pictures" > nul
if not exist "%doc%\My Music\nul" md "%doc%\My Music" > nul
if not exist "%doc%\Favorites\nul" md "%doc%\Favorites" > nul
if not exist "%cache%\nul" md "%cache%" > nul
if not exist "%other%\nul" md "%other%" > nul
for %%T in (Cookies Desktop StartMenu Templates SendTo Recent History) Do if not exist "%other%\%%T\nul" md "%other%\%%T" > nul
:: 复制原目录中的文件到新的目录内并删除原目录的内容
echo 开始复制原始目录中的内容到新目录...
:: 复制我的文档的内容
echo 复制“我的文档”...
if exist "C:\My Documents\nul" xcopy /e /c /i /h /y /q /r "C:\My Documents" "%doc%" > nul
::xyf deltree /y "C:\My Documents"
:: 复制收藏夹内容
echo 复制“收藏夹”...
if exist "%windir%\Favorites\nul" xcopy /e /c /i /h /y /q /r "%windir%\Favorites" "%doc%\Favorites" > nul
::xyf deltree /y "%windir%\Favorites"
:: 复制其它内容
echo 复制用户Cookies, 桌面、发送到、最近访问文档、历史记录等内容...
for %%T in (Cookies Desktop SendTo Recent History) DO if exist "%windir%\%%T\nul" xcopy /e /c /i /h /y /q /r "%windir%\%%T" "%other%\%%T" > nul
::xyf for %%T in (Cookies Recent History) DO deltree /y "%windir%\%%T"
echo 复制用户的程序组...
if exist "%windir%\Start Menu\nul" xcopy /e /c /i /h /y /q /r "%windir%\Start Menu" "%other%\StartMenu" > nul
if exist "%windir%\ShellNew\nul" xcopy /e /c /i /h /y /q /r "%windir%\ShellNew" "%other%\Templates" > nul
echo 文件复制完毕!
echo 备份用户要改变的注册表...
:: 备份要改变的注册表键值到%other%\backup\UserShellFolders_bak.reg文件内
if not exist %other%\backup\nul md %other%\backup > nul
if exist %other%\backup\UserShellFolders_bak.reg goto _modireg
Start /wait regedit /E "%other%\backup\UserShellFolders_bak.reg" "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
echo 备份用户注册表内容到“%other%\backup\UserShellFolders_bak.reg”文件。
:_modireg
:: 准备修改相应的注册表键值的reg文件
echo 开始为修改用户注册表做准备，生成相应的键值...
> _user_.reg echo REGEDIT4
>>_user_.reg echo.
>>_user_.reg echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders]
call far "\\" "\\\\" "%doc%"
>>_user_.reg echo "Personal"="%NEWSTRING%"
call far "\\" "\\\\" "%doc%\My Pictures"
>>_user_.reg echo "My Pictures"="%NEWSTRING%"
call far "\\" "\\\\" "%doc%\My Music"
>>_user_.reg echo "My Music"="%NEWSTRING%"
call far "\\" "\\\\" "%doc%\Favorites"
>>_user_.reg echo "Favorites"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\Desktop"
>>_user_.reg echo "Desktop"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\Templates"
>>_user_.reg echo "Templates"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\StartMenu"
>>_user_.reg echo "Start Menu"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\StartMenu\Programs"
>>_user_.reg echo "Programs"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\StartMenu\Programs\启动"
>>_user_.reg echo "Startup"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\StartMenu\Programs\管理工具"
>>_user_.reg echo "Administrative Tools"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\SendTo"
>>_user_.reg echo "SendTo"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\Recent"
>>_user_.reg echo "Recent"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\Cookies"
>>_user_.reg echo "Cookies"="%NEWSTRING%"
call far "\\" "\\\\" "%other%\History"
>>_user_.reg echo "History"="%NEWSTRING%"

:: 备份并修改Outlook Express的默认保存位置
if exist %other%\backup\Outlook_bak.reg goto _modioutlookreg
Start /wait regedit /E "%other%\backup\Outlook_bak.reg" "HKEY_CURRENT_USER\Software\Microsoft\Outlook Express\5.0"
echo 备份Outlook Express文件存放位置相关注册表设置到“%other%\backup\Outlook_bak.reg”文件中。
:_modioutlookreg
>>_user_.reg echo.
>>_user_.reg echo [HKEY_CURRENT_USER\Software\Microsoft\Outlook Express\5.0]
call far "\\" "\\\\" "%doc%\My Mails\Outlook Express"
>>_user_.reg echo "Store Root"="%NEWSTRING%"
:: 将刚才生成的_user_.reg文件合并到现在的注册表中
echo 开始修改用户注册表...
Start /wait REGEDIT /S _user_.reg
::xyf del _user_.reg
:: 判断是否需要重新启动系统
if "%reboot%"=="true" goto _reboot
goto _quit
:: 等待指定的时间然后重新启动系统
:_reboot
echo 系统将于%wait%秒后重新启动...
wait %wait%
RUNDLL32 SHELL32.DLL,SHExitWindowsEx 2
:_quit
:: 清除设置的环境变量
set doc=
set cache=
set other=
set reboot=
set wait=
set NEWSTRING=
echo 注册表已按要求修改完毕，请记得立刻重新启动系统以使新的设置生效!
echo 按任意键退出程序...
pause > nul
:: 退出批处理
:_end
exit

作者: Climbing 时间: 2004-7-9 23:56
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
有感兴趣的，我制做软件包提供下载。上面提供的主要是批处理程序，批处理中会用到一些其它实用的程序。

作者: 纳兰龙珠 时间: 2004-7-10 05:42
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
系统这块我很笨哈~ “2817”的这几个问题我也想知道哈
但你们似乎对“2817”提的问题的几个关键性的地方搞错了，至于还原空间改变是否影响这问题既然[2817]说结束我也就不说了，以后有新动向再接着聊； “2817”的现在问的是一：原先嵌入于第一分区的文件夹目录如何设置到除第一分区以外的其任意分区，并！在不覆盖被征用第三方分区情况下包括连Program Files这个文件目录也一并移出第一分区（系统分区），我没理解错的话“2817”是想将第一分区完全作成一个承载平台，将系统必须外安装的额外文件全部移向第三方分区以达到相对纯净性，但这样做的前提“2817”希望使用GHOST集成预装是一并自动处理，或使用批处理，但具我所知GHOST好象是完全覆盖所指向的分区而无法针对某一分区内的特定区域（文件夹目录）进行还原，我用的xpboy的2003就可以但方法我不知道，你可以到http://www.xpboy.com/（不知道什么原因我进不去了）问问他怎么干的，记得有一次我挂从硬盘因为袭用有个奇怪而棘手的问题我把原先的第二硬盘的一个标记为隐藏的System Volume Information和其他几个文件夹删了搞的我重启动后原先2003系统默认的第二硬盘的一分区变成我当先系统二分区进去后发现原先BT和TEMP等目录全新建到里面了可见xpboy是使用了批处理处理这一问题的。
至于“2817”提到的在使用“添加删除”是遇到的提示需要安装盘的问题我觉得还是单独刻张盘将各系统和程序的完整安装文件压刻进去是目前最好的解决办法（我就这么干的）否则装在机机上太占地方，谁知道几百年才用他一下，当然啦为了不出意外保持连续性和一致性，希望制作预装包的兄弟能够提供此类ISO包下载
我很菜的哪说错了请指教不要笑我，
我是花骨朵你们要献出你们的爱心来关~怀我！爱~护我！

作者: 纳兰龙珠 时间: 2004-7-10 05:50
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
[这个贴子最后由纳兰龙珠在 2004/07/10 05:59am 第 3 次编辑]

下面引用由Climbing在 2004/07/09 11:56pm 发表的内容：
有感兴趣的，我制做软件包提供下载。上面提供的主要是批处理程序，批处理中会用到一些其它实用的程序。

我要！！！在哪下呀！·· :em29:
顶啊顶~顶啊顶~~顶啊顶啊~~顶啊顶~！
:em02: :em20: :em02: :em20: :em02:

作者: duduclm 时间: 2004-7-10 09:46
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
我也要。
谢谢了！！！

作者: shier2817 时间: 2004-7-10 10:32
标题: [求助]关于GHOST系统困扰我很久的几个问题，谢前辈了！
终于几位高手说话了
我太高兴了
我现在因工作原因还在忙些其他东西，等过个4，5天我专心研究下这个
到时候有疑问请大家一定要帮忙哈
特别感谢 Climbing 大哥提供那么完整的批处理，多谢！！！！！

欢迎光临无忧启动论坛 (http://wuyou.net/)