无忧启动论坛

标题: kcyou分享的自用WIN8.1RAMOS X64 内存系统 [打印本页]

作者: nxsywmydhjd 时间: 2017-8-4 16:07
标题: kcyou分享的自用WIN8.1RAMOS X64 内存系统
求大神们帮忙把下面这个帖子的中的系统 RAMOSWIN8.1内存系统  改成硬盘版  可启动的硬盘版系统或者帮改成VHD
求大神们帮忙把下面这个帖子的中的系统 RAMOSWIN8.1内存系统  改成硬盘版  可启动的硬盘版系统或者帮改成VHD
求大神们帮忙把下面这个帖子的中的系统 RAMOSWIN8.1内存系统  改成硬盘版  可启动的硬盘版系统或者帮改成VHD
http://bbs.wuyou.net/forum.php?m ... &extra=page%3D1 kcyou分享的自用WIN8.1RAMOS X64 内存系统

原系统下载地址：百度网盘链接: http://pan.baidu.com/s/1qYztlkK 密=+码: 7rwx

由于本人按原帖教程测试了一晚上  没能成功改成硬盘版  测试一直是缺少DLL ，改VHD 也没能成功。

求好心师傅们  帮帮忙帮忙改好的可以私聊我愿意支付20红包

求好心师傅们  帮帮忙帮忙改好的可以私聊我愿意支付20红包

作者: 2011aisht 时间: 2017-8-4 21:56
我反而想问.如何使用里面的.net4.0

作者: 苏州本是 时间: 2017-8-5 07:18
本帖最后由苏州本是于 2017-8-5 07:38 编辑

第一步：CoolG有篇帖子可以当成【理论步骤】看一下。
RamOS 安装到硬盘的三个重要步骤：

一。解压WIM
格式化硬盘分区为NTFS,解压WIM到该分区根目录，（例于安装到F:\）

二。修改注册表
1.导出当前系统 HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices 分支备用：

Windows Registry Editor Version 5.00
[HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices]
"\\??\\Volume{fad7b66d-bfdd-11e4-824e-806e6f6e6963}"=hex:3a,f2,23,87,00,00,7e,\
  00,00,00,00,00
"\\??\\Volume{fad7b66e-bfdd-11e4-824e-806e6f6e6963}"=hex:3a,f2,23,87,00,00,f0,\
  d2,05,00,00,00
"\\??\\Volume{fad7b66f-bfdd-11e4-824e-806e6f6e6963}"=hex:3a,f2,23,87,00,00,00,\
  38,06,00,00,00
"\\DosDevices\\C:"=hex:72,ad,72,ad,00,7e,00,00,00,00,00,00
"\\DosDevices\\D:"=hex:3a,f2,23,87,00,00,7e,00,00,00,00,00
"\\DosDevices\\E:"=hex:3a,f2,23,87,00,00,f0,d2,05,00,00,00
"\\DosDevices\\F:"=hex:3a,f2,23,87,00,00,00,38,06,00,00,00

2.（重要）修改RAMOS的注册表SYSTEM，添加MountedDevices注册表项
  把"\\DosDevices\\F:"=hex:3a,f2,23,87,00,00,00,38,06,00,00,00
改为"\\DosDevices\\X:"=hex:3a,f2,23,87,00,00,00,38,06,00,00,00

[HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices]
"\\DosDevices\\X:"=hex:3a,f2,23,87,00,00,00,38,06,00,00,00

3.删除FBWF服务：HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\FBWF

三。编辑BCD，添加启动项

第二步：【实际操作】请参考：将网上的Win8.1 RAMOS 还原成硬盘操作系统
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=337418

第三步：搜索rush的帖子。有【自动安装批处理文件】可以参考。为免你麻烦，给你贴一个版本。

@echo off
cls
color 1F
echo.
echo  Windows 8 RAMOS 安装程序
echo =========================
echo.
echo.
echo    　　　╔══════════════════════════╗
echo 　　　　　║　欢迎使用coolg Win8 RAMOS硬盘化安装程序！　　　　　║
echo 　　　　　║　本工具作者：rush　　　　系统作者：fish2006　　　　║
echo 　　　　　║　使用本工具时务必谨慎，作者不对任何后果负责　　　　║
echo 　　　　　║　本工具开源免费，诅咒改几个字再发还加密的！　　　　║
echo 　　　　　╚══════════════════════════╝
echo.
echo ***************************************************************************
echo 请先去双击挂载iso虚拟光盘！
SET /P CDROMDSK= 请输入挂载后的虚拟光驱分区号(C/D/E/F...)：
echo 请先去格式化目标分区！
SET /P ST= 请输入格式化后的目标分区号(C/D/E/F...)：
if /I "%ST%"=="X" goto EX
if /I "%ST%"=="" goto EX
echo 您的虚拟光驱位于%CDROMDSK%盘
echo 您的Win8.1RAMOS将安装到%ST%盘
"X:\Program Files (x86)\WimTool\WimTool.exe" %CDROMDSK%:\sources\BOOT.WIM  /ExtrFile ,%ST%:\
echo 挂载"%ST%:\Windows\system32\config\SYSTEM"注册表项
reg load HKLM\ss "%ST%:\Windows\system32\config\SYSTEM"
echo 您当前硬盘%ST%的序列号为
reg query HKLM\SYSTEM\MountedDevices\ /v "\dosdevices\%ST%:"
for /f "tokens=2*" %%i in ('reg query HKLM\SYSTEM\MountedDevices\ /v \dosdevices\%ST%:') do set value=%%j
echo %value%
echo 替换目标系统X盘的序列号……
REG ADD HKLM\ss\MountedDevices /v "\DosDevices\X:" /t REG_BINARY /d %value%
echo 让我们看看真的替换好了没有
reg query HKLM\ss\MountedDevices\
reg delete HKLM\ss\ControlSet001\Services\fbwf /f
reg unload HKLM\ss

:CPY_BOOTFILE
echo 现在复制启动文件
SET /P SEL_BOOT= 如果你是传统BIOS模式请输入1回车，是UEFI模式输入2回车：
if /I "%SEL_BOOT%"=="1" goto BCD_BIOS
if /I "%SEL_BOOT%"=="2" goto BCD_UEFI
echo 输入有错
pause
goto CPY_BOOTFILE

:BCD_BIOS
copy %CDROMDSK%:\bootmgr %ST%:\
xcopy /s /y %CDROMDSK%:\boot %ST%:\boot\
BOOTICEx86.exe /DEVICE=%ST%: /partitions /activate
echo 请自行修改BCD
echo 1.请把上面的引导设备类型改为Partition，并且在下面选择目标盘
echo 2.请把下面启动到WinPE去掉！
echo 3.请点击底部“保存当前系统设置”
BOOTICEx86.exe /edit_bcd /easymode /file=%ST%:\boot\bcd
goto DEL_JUNK

:BCD_UEFI
xcopy /s /y %CDROMDSK%:\EFI %ST%:\EFI\
echo 请自行修改BCD
echo 1.请把上面的引导设备类型改为Partition，并且在下面选择目标盘
echo 2.请把下面启动到WinPE去掉！
echo 3.请点击底部“保存当前系统设置”
BOOTICEx86.exe /edit_bcd /easymode /file=%ST%:\efi\microsoft\boot\bcd

:DEL_JUNK
echo 删除垃圾中
del /f /q %ST%:\Windows\ampa.exe
del /f /q %ST%:\Windows\TransParent2.ico
del /f /q %ST%:\Windows\update0.ico
del /f /q %ST%:\Windows\update1.ico
del /f /q %ST%:\Windows\Sh.ini
del /f /q %ST%:\Windows\Sh.exe
del /f /q %ST%:\Windows\system32\drivers\fbwf.sys
del /f /q %ST%:\Windows\fbwf.cfg
del /f /q %ST%:\fbwf.cfg
echo 修改初始化文件中……
echo start /b /w au3381.exe %WinDir%\System32\LetterSwap.au3 /auto /log %temp%\LetterSwap.log /IgnoreLetter XYB>%ST%:\Windows\system32\RamOSetup.cmd
echo start /b regedt32.exe /s %WinDir%\System32\PE3_CUSTOM.reg>>%ST%:\Windows\system32\RamOSetup.cmd
echo start /b regedt32.exe /s %WinDir%\System32\win81-x64-wim-setup.reg>>%ST%:\Windows\system32\RamOSetup.cmd
echo start /b regedt32.exe /s %WinDir%\System32\7zip-new-unicode.x64.reg>>%ST%:\Windows\system32\RamOSetup.cmd
echo echo.^>%Windir%\system32\RamOSetup.cmd>>%ST%:\Windows\system32\RamOSetup.cmd
echo 特别说明：
echo 1.由于SH会误报，本安装程序删除了SH挂载支持，但保留内置wim文件，
echo 你只需要到W81X文件夹下面去解压一下就能用了，都是一些绿色软件。
echo 2.如果您喜欢自带的Primo Ramdisk ，您可以自行研究system32目录下的
echo RAMDISK.cmd文件，双击就能加载内存盘！
echo 安装好了！
pause

作者: 苏州本是 时间: 2017-8-5 07:56
小白可以只看第二步，可以熟悉步骤。
老白懂.bat的可以直接改动批处理，更省事。
大神请绕过。

作者: nxsywmydhjd 时间: 2017-8-5 12:19

苏州本是发表于 2017-8-5 07:56
小白可以只看第二步，可以熟悉步骤。
老白懂.bat的可以直接改动批处理，更省事。
大神请绕过。

大哥你微信号，多少，按你的2号教程成功了

作者: nxsywmydhjd 时间: 2017-8-9 14:46

nxsywmydhjd 发表于 2017-8-5 12:19
大哥你微信号，多少，按你的2号教程成功了

谢谢哥

欢迎光临无忧启动论坛 (http://wuyou.net/)