UltraISO 单文件打包注册问题 - 无忧启动论坛

;NSIS单文件打包模板_CCleaner_20170827
;********************************************************************
;*定义变量
;********************************************************************
!define APP "CCleaner" ; 程序主要名（不带空格）
!define VER "5.33.0.6162" ; 版本号
!define APPNAME "${APP}_${VER}" ;程序全名,带版本号
!define APPDIR "$TEMP\${APP}" ;主程序解包路径
!define /date DATE "%Y.%m.%d.%H" ;定义DATE为年.月.日.时
!define TIMEVER "Build ${DATE}" ;定义TIMEVER为 Build 年月日时
;********************************************************************
;*基本信息
;********************************************************************
Caption "${APP}" ;标题栏显示文字
OutFile "${APPNAME}_自用版.exe" ;指定成品输出的路径和文件名
Icon "${APP}.ico" ;设置程序的ico图标
;********************************************************************
;*常规属性设置
;********************************************************************
SilentInstall silent
;设置为静默安装
AutoCloseWindow True
;安装完成的时候窗口自动关闭
!include "x64.nsh"
;加入x64头文件，后面判断系统位数会用到
SetCompressor /SOLID lzma
;指定压缩方式/所有的数据将被压缩在一个区块里，这样可以提高压缩率。
SetCompressorDictSize 32
;设置使用 LZMA 压缩器时的字典大小 (默认为 8MB)
RequestExecutionLevel admin
;安装程序需要的执行级别none|user|highest|admin。设为默认值none将由Windows来判断执行级别,none和admin实际上具有相同效果。
SetOverwrite on
;File命令文件是否覆盖。on全覆盖;off全不覆盖;try默认覆盖,覆盖不了的就略过;ifnewer只有旧文件被覆盖;ifdiff新旧不一的文件才被覆盖,且设为新文件的日期。
;********************************************************************
;*版本信息
;********************************************************************
VIProductVersion "${DATE}" ;在文件属性版本表格的顶部添加产品版本号。
VIAddVersionKey /LANG=2052 "FileDescription" "${APP}自用版" ;文件说明
VIAddVersionKey /LANG=2052 "ProductName" "${APP}" ;产品名称
VIAddVersionKey /LANG=2052 "ProductVersion" "${VER}" ;产品版本
VIAddVersionKey /LANG=2052 "LegalCopyright" "" ;版权
VIAddVersionKey /LANG=2052 "CompanyName" "" ;公司
#VIAddVersionKey /LANG=2052 "OriginalFilename" "${APPNAME}_自用版.exe" ;原文件名
VIAddVersionKey /LANG=2052 "FileVersion" "${TIMEVER}" ;版本号
;********************************************************************
;*运行
;********************************************************************
Section "main" ;创建区段，名称为main
;----------------主程序运行前的准备工作-------------------
SetOutPath "${APPDIR}" ;设置文件解压路径为$TEMP\CCleaner，且当路径不存在时创建
File /a /r "${APP}\*" ;解压一个文件夹，同时也指定了该文件夹打包的来源路径
;-------------------运行主程序----------------------
${If} ${RunningX64} ;判断系统是不是64位
Execwait "${APPDIR}\CCleaner64.exe" ;如果当前系统是64位就运行CCleaner64.exe并且等待运行结束
${Else}
Execwait "${APPDIR}\CCleaner.exe" ;反之则运行CCleaner.exe并且等待运行结束
${EndIf}
;-----------主程序运行结束后的清理工作--------------
SetOutPath "$TEMP" ;解压路径设置到$TEMP，最后才能完全删除$TEMP\CCleaner文件夹
RMDir /r /REBOOTOK "${APPDIR}" ;删除文件夹$TEMP\CCleaner
SectionEnd ;区段结束

复制代码