批处理自动查找所有可移动磁盘的physical编号和对应的盘符 - 无忧启动论坛

@echo off
setlocal EnableDelayedExpansion
set "SelectSequence=123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
for /f %%i in ('echo prompt $E ^| cmd') do set "KeyESC=%%i"
::::::::::::::::::::: Powershell 代码
set "psCommand=powershell -Command "^
$disks = Get-CimInstance -ClassName Win32_DiskDrive -Filter \"MediaType^='Removable Media' OR MediaType^='External Hard Disk Media'\"; ^
$outstr = ''; ^
foreach ($disk in $disks) { ^
$diskModel = $disk.Model; ^
$diskNumber = $disk.DeviceID.Replace('\\.\PHYSICALDRIVE', ''); ^
$partitions = Get-Disk -Number $diskNumber ^| Get-Partition; ^
$driveLetter = ''; ^
foreach ($partition in $partitions) { ^
$driveLetter = $driveLetter + ' ' + (Get-Volume -Partition $partition).DriveLetter + ':'; ^
} ^
$driveLetter = $driveLetter.trim(); ^
$outstr = $outstr + \"$diskNumber^^^&型号:$diskModel^($driveLetter^)`n\"; ^
} ^
Write-Host $outstr.TrimEnd(\"`n\"); ^
""
::::::::::::::::::::: Powershell 代码
set /a "c=0"
for /f "usebackq tokens=1,2 delims=&" %%A in (`%psCommand%`) do (
set /a "c+=1"
set "udisk[!c!].num=%%A"
set "udisk[!c!].str=%%B"
)
if !c!==0 (echo 没有检测到U盘，请插入U盘再运行！按任意键退出。& pause >nul 2>nul & goto :eof)
set "SelKey=!SelectSequence:~0,%c%!"
:select_U
for /l %%i in (1, 1, !c!) do echo %%i^) !udisk[%%i].str!
choice /c %SelKey% /m 请选择U盘：
set selection=%errorlevel%
echo 已选择 %KeyESC%[48;5;196m%KeyESC%[4m%KeyESC%[1m!udisk[%selection%].str!%KeyESC%[0m
choice /c YR /m 清除U盘数据并继续(Y/y)、重选(R/r)？
if errorlevel 2 goto :select_U
rem 此时已得到所选U盘的physical号码，即可以操作 \\.\PHYSICALDRIVE1 之类了
echo !udisk[%selection%].num!
REM (
REM echo list disk
REM echo sel disk 1
REM echo list volume
REM echo exit
REM ) | diskpart > nul 2>nul

复制代码