无忧启动论坛

标题: CPix 图片格式一键关联和选项设置 [打印本页]
作者: 2010hook    时间: 2023-10-1 18:04
标题: CPix 图片格式一键关联和选项设置
本帖最后由 2010hook 于 2024-7-10 18:16 编辑

CPix 是小巧、快速、功能强大的看图工具，原生单文件。

这是我监视格式关联注册整理出来的，用在PE和RamOS里最好。

  1. @echo off
  2. reg delete "HKLM\SOFTWARE\Microsoft\Windows Photo Viewer" /f >nul 2>nul
  3. reg add "HKLM\SOFTWARE\RegisteredApplications" /f /v "CPix" /d "SOFTWARE\Clients\Media\CPix\Capabilities" >nul
  4. reg add "HKLM\SOFTWARE\Clients\Media\CPix" /f /ve /d "CPix" >nul
  5. reg add "HKLM\SOFTWARE\Clients\Media\CPix\Capabilities" /f /v "ApplicationName" /t REG_EXPAND_SZ /d "CPix" >nul
  6. reg add "HKLM\SOFTWARE\Clients\Media\CPix\Capabilities" /f /v "ApplicationDescription" /t REG_EXPAND_SZ /d "CPix" >nul
  7. reg add "HKLM\SOFTWARE\Clients\Media\CPix\Capabilities" /f /v "ApplicationIcon" /t REG_EXPAND_SZ /d ""%~sdp0CPix.exe",0" >nul
  8. for %%a in (bmp jpg jpeg jpe jfif jfi jif gif apng png tif tiff wbmp ejpg mpo empo pl epl webp) do (
  9.         reg add "HKLM\SOFTWARE\Classes\.%%a" /f /ve /d "CPix.%%a" >nul
  10.         reg add "HKLM\SOFTWARE\Classes\.%%a\OpenWithProgids" /f /v "CPix.%%a" >nul
  11.         reg add "HKLM\SOFTWARE\Classes\CPix.%%a" /f /ve /d "%%a" >nul
  12.         reg add "HKLM\SOFTWARE\Classes\CPix.%%a\DefaultIcon" /f /ve /d "%%systemroot%%\System32\imageres.dll,-71" >nul
  13.         reg add "HKLM\SOFTWARE\Classes\CPix.%%a\shell\open\command" /f /ve /d ""%~sdp0CPix.exe" "%%1"" >nul
  14.         reg add "HKLM\SOFTWARE\Clients\Media\CPix\Capabilities\FileAssociations" /f /v ".%%a" /d "CPix.%%a" >nul
  15.         reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%a\UserChoice" /f /v "Progid" /d "CPix.%%a" >nul 2>nul
  16. )
  17. control /name Microsoft.DefaultPrograms /page pageDefaultProgram
复制代码


再分享CPix选项设置，这么样比较顺手。以下内容保存为 CPix.ini
  1. [Settings]
  2. FileSortMode = 1
  3. ExifOrientation = 1
  4. NoLoopSwitching = 0
  5. BkColorR = 60
  6. BkColorG = 60
  7. BkColorB = 60
  8. Ascending = 0
  9. FullScreen = 0
  10. ShowCmd = 1
  11. MaxMemory = 20
  12. MultimediaTimer = 1
  13. NumberAsNumber = 1
  14. MouseWheelToSwitchImage = 1
  15. FileNotAssociated = *.;*.cur;*.dll;*.exe;
  16. IgnoreAllNewVersions = 1
  17. MaintainFileDateTime = 0
复制代码

我发过几封邮件给开发者，得到热情答复，后续版本会支持命令行关联，支持直方图，支持JXL、WebP2新格式。
作者: 车厘子    时间: 2023-10-1 18:14
抢占沙发
作者: 语之男    时间: 2023-10-1 18:15
板凳可能就是给我准备滴
作者: yyz2191958    时间: 2023-10-1 18:19
谢谢分享
作者: yyz2191958    时间: 2023-10-1 18:23
我运行了，怎么不行？
作者: cuicongyuan    时间: 2023-10-1 19:45
可以关联GIF，第一次打开GIF文件时，CPix是空白，然后关闭CPix，再打开GIF文件时，可以了。
作者: zwmfyy    时间: 2023-10-1 19:59
谢谢分享
作者: sairen139    时间: 2023-10-1 21:48
能让开发者编译一个纯64位版本吗？上次发邮件给xsnip的开发者邮件犹如石沉大海，哈哈哈哈😂
作者: 2010hook    时间: 2023-10-1 21:54
本帖最后由 2010hook 于 2023-10-1 22:06 编辑
sairen139 发表于 2023-10-1 21:48
能让开发者编译一个纯64位版本吗？上次发邮件给xsnip的开发者邮件犹如石沉大海，哈哈哈哈😂

我写过，开发者回复：“我们在CPix后续版本考虑一下您提到的需求。”
其实平时用32bit程序比较安全，因为64bit系统限制了访问权限。
作者: yc2428    时间: 2023-10-1 23:34
非常感谢！
作者: chishingchan    时间: 2023-10-2 07:29
cuicongyuan 发表于 2023-10-1 19:45
可以关联GIF，第一次打开GIF文件时，CPix是空白，然后关闭CPix，再打开GIF文件时，可以了。

证明软件有写入注册表
作者: cuicongyuan    时间: 2023-10-2 09:58
chishingchan 发表于 2023-10-2 07:29
证明软件有写入注册表

CPix——readme.txt——1. 第一次运行本程序时，请以管理员身份运行，以确保本程序能够成功更新注册表，建立文件格式关联。
作者: KIM3298    时间: 2023-10-2 11:30
谢谢分享
作者: 3416510931    时间: 2023-10-2 14:59
sairen139 发表于 2023-10-1 21:48
能让开发者编译一个纯64位版本吗？上次发邮件给xsnip的开发者邮件犹如石沉大海，哈哈哈哈😂

纯64位软件对这类小软件有什么优势吗
作者: 3416510931    时间: 2023-10-2 17:21
请问删除关联的批处理怎么写
作者: BEIKING    时间: 2023-10-2 19:51
感谢分享
作者: anonyman    时间: 2023-10-2 22:07
这软件没有打印功能？
作者: 2010hook    时间: 2023-10-2 22:12
3416510931 发表于 2023-10-2 17:21
请问删除关联的批处理怎么写

我可以给你写，每字1000
作者: 3416510931    时间: 2023-10-3 09:51
2010hook 发表于 2023-10-2 22:12
我可以给你写，每字1000

试着改了一下，add改成delete，运行失败，显示语法错误，删掉参数能运行，但每一条都要按Y确认
作者: 3416510931    时间: 2023-10-3 10:01
@echo off
if "%1"=="" (
    call :Main
    call :Del
) >nul 2>nul
exit /b

:Main
    title
    fltmc >nul || mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~dpnx0","%*",,"runas",1)(window.close) && exit /b
   
:Uninstall
    (
        echo Windows Registry Editor Version 5.00  
        call :RegDissoc bmp  
        call :RegDissoc ejpg
        call :RegDissoc gif  
        call :RegDissoc jpg  
        call :RegDissoc jpeg
        call :RegDissoc jpe  
        call :RegDissoc png  
        call :RegDissoc tif  
        call :RegDissoc tiff
        call :RegDissoc wbmp
        call :RegDissoc webp
        echo [-HKEY_CLASSES_ROOT\CPix]
    ) >"%Temp%\Uninstall.reg"
    reg import "%Temp%\Uninstall.reg"
    del /f "%Temp%\Uninstall.reg"

goto :eof
::清除文件类型关联
:RegDissoc :: <%1=Ext>
    echo [-HKEY_CLASSES_ROOT\CPix.%1]
goto :eof

根据WPS2016 极限精简版 仅27.8MB 这个帖子改的
刚关联还好删，cpix用久了就会有部分注册表无法通过这个删除
作者: sulong    时间: 2023-10-3 10:03
了解了解，先谢谢分享
作者: 3416510931    时间: 2023-10-3 10:03
本帖最后由 3416510931 于 2023-10-3 10:12 编辑

要放到cpix文件夹上一层路径才能生效
@echo off

set "CPix=%~dp0CPix"
set "CPixReg=%CPix:\=\\%"
if "%1"=="" (
    call :Main
) >nul 2>nul
exit /b
::以管理员身份运行
:Main
    title CPix
    fltmc >nul || mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~dpnx0","%*",,"runas",1)(window.close) && exit /b


::执行创建注册表关联项
:Install
    (
        echo Windows Registry Editor Version 5.00
        call :RegAssoc bmp  CPix bmp icon
        call :RegAssoc ejpg CPix jpg icon
        call :RegAssoc gif  CPix gif icon
        call :RegAssoc jpg  CPix jpg icon
        call :RegAssoc jpeg CPix jpg icon
        call :RegAssoc jpe  CPix jpg icon
        call :RegAssoc png  CPix png icon
        call :RegAssoc tif  CPix bmp icon
        call :RegAssoc tiff CPix bmp icon
        call :RegAssoc wbmp CPix bmp icon
        call :RegAssoc webp CPix bmp icon
    ) >"%Temp%\Install.reg"
    reg import "%Temp%\Install.reg"
    del /f "%Temp%\Install.reg"

goto :eof

::关联相关文件类型
:RegAssoc :: <%1=Ext> <%2=ExeName> <%3=IconIndex图标编号> <%4=图标文件名>
    echo [HKEY_CLASSES_ROOT\CPix.%1\DefaultIcon]
    echo @="%CPixReg%\\%4\\%3.ico"
    echo [HKEY_CLASSES_ROOT\CPix.%1\Shell\Open\Command]
    echo @="\"%CPixReg%\\%2.exe\" \"%%1\""
    echo [HKEY_CLASSES_ROOT\.%1]
    echo @="CPix.%1"
goto :eof
作者: 2010hook    时间: 2023-10-3 16:01
标题: RE: CPix 图片格式一键关联和选项设置
3416510931 发表于 2023-10-3 10:01
刚关联还好删，cpix用久了就会有部分注册表无法通过这个删除

这个问题估计是你通过右键选择打开方式，然后被系统记录到注册表里了。
作者: vokins    时间: 2023-10-3 16:19
请问您下，这个软件是否支持heif格式啊？索尼和苹果手机都在用这个格式
作者: temp2005    时间: 2023-10-3 16:20
感谢分享
作者: 3416510931    时间: 2023-10-3 22:06
2010hook 发表于 2023-10-3 16:01
这个问题估计是你通过右键选择打开方式，然后被系统记录到注册表里了。

了解
作者: hdxzd    时间: 2023-10-6 20:25
谢谢分享！
作者: 创新科技2015    时间: 2023-10-8 14:33
        很给力!
作者: xjxlin    时间: 2023-10-8 15:17
收藏一下，感谢
作者: KIM3298    时间: 2023-10-8 15:29
谢谢分享
作者: boaz199    时间: 2023-10-23 20:17
頂，謝謝樓主的勞動和分享！數據會記錄每個信息對網絡的奉獻！
作者: 3416510931    时间: 2024-1-15 16:10
取消关联
@echo off

    fltmc >nul || mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~dpnx0","%*",,"runas",1)(window.close) && exit /b

for %%a in (avci avif bmp gif heic heif ico jfif jpe jpeg jpg jxr pic png psd psp raw tif tiff webp ejpg wbmp apng empo epl jfi jif mpo pbm pgm pl ppm) do (
        reg delete "HKCR\CPix.%%a" /f
        reg delete "HKLM\SOFTWARE\.%%a" /f
        reg delete "HKLM\SOFTWARE\Classes\CPix.%%a" /f
        reg delete "HKLM\SOFTWARE\Classes\CPix.%%afile" /f
        reg delete "HKLM\SOFTWARE\Classes.%%a\DefaultIcon" /f
        reg delete "HKCR\.%%a" /f /ve
        reg delete "HKCR\.%%a\OpenWithProgids" /f /v "CPix.%%afile"
        reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%a\OpenWithProgids" /f /v "CPix.%%a"
        reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%a\OpenWithProgids" /f /v "CPix.%%afile"
) >nul 2>nul

for %%b in (jfif jpe jpg jxr jfi jif mpo pbm pgm pl ppm) do (
        reg delete "HKCR\.%%b\OpenWithProgids" /f /v "CPix.jpegfile"
        reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%b\OpenWithProgids" /f /v "CPix.jpeg"   
) >nul 2>nul

(
        reg delete "HKCR\.tif\OpenWithProgids" /f /v "CPix.tifffile"
        reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.tif\OpenWithProgids" /f /v "CPix.tiff"
        reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.tif\OpenWithProgids" /f /v "CPix.tifffile"
        
        reg delete "HKCR\CPix" /f
        reg delete "HKLM\SOFTWARE\Classes\CPix" /f
) >nul 2>nul

作者: hehuiying    时间: 2024-4-20 08:05
谢谢分享
作者: 两笙山世    时间: 2024-4-20 08:09
感谢制作与分享！



欢迎光临 无忧启动论坛 (http://wuyou.net/) Powered by Discuz! X3.3