VHD系统迁移工具（测试） - 无忧启动论坛

@echo off
cd /d %~dp0
title VHD系统迁移工具 baby1277 2025.8.25
for %%i in (Dism wimserv) do if not exist %SystemRoot%\System32\%%i.exe echo.&echo 系统缺少必要的组件，按任意键退出。&pause>nul&exit
set path1=%~dp0
set path2=%path1: =%
if not "%path2%"=="%path1%" cls&echo.&echo 当前路径不能包含空格，按任意键退出。&pause>nul&exit
:xuan
cls
echo.
echo.
echo.
echo.本工具旨在实现VHD系统和物理磁盘系统之间的相向迁移，建议在PE或者非迁移目标的系统上运行。
echo.
echo.
echo.1. VHD系统迁移到物理磁盘系统
echo.
echo.
echo.2. 物理磁盘系统迁移到 VHD系统
echo.
echo.
set /p N=请输入需要对应的数字：
echo.
echo.
if "%N%"=="1" goto xuan0
if "%N%"=="2" goto xuan0
goto xuan
:xuan0
cls
echo.
echo.
if %N% equ 1 echo 选择了 VHD系统迁移到物理磁盘系统
if %N% equ 2 echo 选择了物理磁盘系统迁移到 VHD系统
echo.
echo.
echo.
echo.输入提示1：VHD文件路径不可以有汉字和特殊符号
echo.
if %N% equ 2 echo.输入提示2：VHD文件位置也可以不输入由脚本自行创建
echo.
set /p vhd=请输入迁移VHD文件的位置：
if %N% equ 2 if not defined vhd set vhd=%cd%\Win_%random:~-2%.vhdx
for /f "delims=" %%i in ('echo %vhd%') do set "dir=%%~di"&if /i not "%%~xi"==".vhd" if /i not "%%~xi"==".vhdx" goto xuan0
set path1=%vhd%
set path2=%path1: =%
if not "%path2%"=="%path1%" cls&echo.&echo 当前路径不能包含空格，按任意键退出。&pause>nul&exit
echo.
echo.
echo.输入提示：物理磁盘位置只要输入一个字母
echo.
echo.
set /p ben=请输入迁移物理磁盘位置：
echo.
echo.
cls
set abc=C D E F G H I J K L M N O P Q R S T X U V W Y Z
if %N% equ 1 if not exist "%vhd%" goto xuan0
if %N% equ 2 if not exist "%vhd%" call :mdvhd
if not exist %ben%: goto xuan0
cls
echo.
echo.
echo.
if %N% equ 1 echo. 由 %vhd% 迁移至 %ben%:\
if %N% equ 2 echo. 由 %ben%:\ 迁移至 %vhd%
echo.
echo.
echo.
echo 请确认以上信息无误后按回车键继续&pause>nul
cls
(echo select vdisk file="%vhd%"&echo detach vdisk)|diskpart >nul 2>nul
for %%i in (%abc%) do if exist %%i: set t%%i=ok
(echo select vdisk file="%vhd%"&echo attach vdisk&echo exit)|diskpart >nul 2>nul
for %%i in (%abc%) do if exist %%i: if not defined t%%i set pan1=%%i:\
call :xuan%N%
call :bcd
cls
echo.
echo.
echo.
if %N% equ 1 echo. 由 %vhd% 迁移至 %ben%:\ 完成，按任意键重启系统。
if %N% equ 2 echo. 由 %ben%:\ 迁移至 %vhd% 完成，按任意键重启系统。
echo.
echo.
echo.
pause>nul
:mdvhd
for %%i in (%abc%) do if not exist %%i: set pan=%%i
(echo create vdisk file="%vhd%" maximum=61440 type=expandable
echo Select vdisk file="%vhd%"
echo attach vdisk
echo create partition primary
echo format quick fs=ntfs label="SYSTEM"
echo assign letter=%pan%:
echo select vdisk file="%vhd%"
echo detach vdisk
echo exit
) | diskpart >nul 2>nul
goto :eof
:xuan1
DISM /Capture-Image /ImageFile:%dir%\temp.wim /CaptureDir:%pan1% /Name:"by_baby1277"
DISM.exe /Apply-Image /ImageFile:%dir%\temp.wim /Index:1 /ApplyDir:%ben%:\
bcdboot %ben%:\Windows /l zh-ch
goto :eof
:xuan2
DISM /Capture-Image /ImageFile:%dir%\temp.wim /CaptureDir:%ben%:\ /Name:"by_baby1277"
Dism /apply-image /imagefile:%dir%\temp.wim /Index:1 /applydir:%pan1%
bcdboot %pan1%Windows /l zh-ch
goto :eof
:bcd
(echo select vdisk file="%vhd%"&echo detach vdisk)|diskpart >nul 2>nul
bcdedit /set {bootmgr} Locale zh-cn
bcdedit /timeout 3
del /f /q %dir%\temp.wim
goto :eof

复制代码