U盘2次安装PE出错.批处理命令自动关闭.

zhtzh95

小弟新手
      PE安装U盘成功后一切使用正常,但后期因U盘文件出错,格式化U盘后PE文件丢失(原PE未用安装包卸载).在重新安装后发现问题,安装批处理命令窗口自动关闭. 尝试多次结果依然.
请问怎么解决此问题呢?

x.Nichdlas

发安装批处理出来看看吧 看是哪里留了安装信息影响到了

zhtzh95

@Echo Off
COLOR 2F
Set Prog=老毛桃制作的 WinPE 专用安装工具
Set L1=　　　　　　╭══════════════════╮
Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
Set L3=　　　╭══┤　%Prog%　 ├══╮
Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
Set L5=　　　║　　╰══════════════════╯　　║
Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
Set L7=　　　╟════════════════════════╢
Set L8=　　　║　版权所有：老毛桃　　仅供网友们交流　翻版不究　║
Set L9=　　　╰────────────────────────╯
Title %Prog%

Set PEFile=WinPE.IS_
Set PEIni=外置程序\WinPE.INI
Set LogFile=PEInstall.log
Set AddATTR=ATTRIB +S +H +R
Set DelATTR=ATTRIB -S -H -R

:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║
Echo %L6%
Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
Echo 　　　║　　[4] Grub安装/启动 (U 盘安装，支持 MD5 密码) ║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo 　　　║ 注意: Aero 安装项只适合系统分区在(HD0,0)分区 　║
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：
If "%Choice%"=="" Goto Start
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Goto HD
If /I "%Choice%"=="2" Goto HD
If /I "%Choice%"=="3" Goto HD
If /I "%Choice%"=="4" Goto UD
If /I "%Choice%"=="Q" Exit
Goto Start

:HD
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If "%RP%"=="" Goto NoSys
Set PEDIR=%RP%\MAOTAO
Set TargetP=硬盘&&Set TxtSp=
If Exist %PEDIR% Goto Err1
FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
If /I "%Choice%"=="1" Goto Install
If /I "%Choice%"=="2" Goto GInstall
If /I "%Choice%"=="3" Goto AInstall
Goto HD

:UD
CLS
Title %Prog%——U 盘安装
If "%NoUD%"=="Yes" Echo 错误：您设定的分区不存在或写保护或不是 U 盘分区，请按任意键重新设定。&&Echo.
Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
Echo.&&Echo.
If "%RP%"=="" Goto UD
If Not "%RP%"=="" Set RP=%RP:~0,1%:
Grub2U\FSUTIL.EXE FSINFO DRIVETYPE %RP%|FIND "可移动驱动器">NUL 2>NUL
If Not "%Errorlevel%"=="0" Set NoUD=Yes&&Goto UD
Set TestFile=%RP%\MaotaoTest_%RANDOM%.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
Del %TestFile% /Q>NUL 2>NUL
Set U=U&&Set PEDIR=%RP%\MAOTAO&&Set OP=%RP%&&Set TargetP= U 盘
If Exist %PEDIR% Goto Err1
CLS
Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
Echo.
Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。
PAUSE>NUL
Start /Wait Grub2U\HPUSBFW.EXE
Start /Wait Grub2U\GRUBGUI.EXE
Echo.
Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续。。。
PAUSE>NUL
Goto GInstall

:Err1
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
Echo %L6%
Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
If "%Choice%"=="" Goto Err1
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
If /I "%Choice%"=="2" Goto UnInstall
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto Err1
Exit

:UnInstall
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPU=%%i
If Not "%U%"=="" Set OPU=%OP%
If Exist %OPU%\外置程序 RD %OPU%\外置程序 /S /Q>NUL 2>NUL
If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
%DelATTR% %RP%\BOOT.INI>NUL 2>NUL
If Exist %RP%\BOOT.BAK (
%DelATTR% %RP%\BOOT.BAK
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
) Else (
If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL 2>NUL
If Exist %RP%\BOOT.BAK TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
)
If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
Title %Prog%——卸载完成
If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit

:Install
Title %Prog%——普通安装
If "%OP%"=="" Call :SetOP
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo 正在复制文件，请稍候 。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:GInstall
If "%U%"=="" Title %Prog%——Grub安装
CLS
Set DefItem=0&&Set LDRP=MAOTAO\
If "%U%"=="" Set DefItem=1&&If "%OP%"=="" Call :SetOP
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto GInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto GInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
>%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MTLDR%U%.BIN -r -y>NUL 2>NUL
>>%RP%\MTLDR Echo default %DefItem%
>>%RP%\MTLDR Echo timeout 5
>>%RP%\MTLDR Echo.
For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
Echo fontfile /maotao/muifont.gz>>%RP%\MTLDR
Echo splashimage /maotao/bj2008.xpm.gz>>%RP%\MTLDR
>>%RP%\MTLDR Echo.
Echo title WinPE  By: Maotao>>%RP%\MTLDR
For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
Copy /b %RP%\MTLDR+%PEDIR%\MTLDR%U%.bin %RP%\MTLDR>NUL 2>NUL
Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
Del %PEDIR%\MTLDR%U%.bin /Q>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR
Echo.
Echo 正在复制文件，请稍候 。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y>NUL 2>NUL
If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin
Call :CopyAndSetFiles
Goto SUCCESS

:AInstall
Title %Prog%——Aero安装
CLS
If "%OP%"=="" Call :SetOP
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto AInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto AInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
Ren %PEDIR%\maotao.bin avldr.xpe
Ren %PEDIR%\maotaoa.bin maotao.bin
>%PEDIR%\airL.gz <nul Set/p=%Pass2%
Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo.
Echo 正在复制文件，请稍候 。。。
MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
MOVE %PEDIR%\WINNT.XPE %RP%\>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:NoSys
CLS
Echo 好像您的机器中没有安装操作系统哦，请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit

:CopyAndSetFiles
For /F "tokens=2 delims=." %%i In ('Ver') DO Set SysVer=%%i
If "%U%"=="" If %SysVer:~0,1% LSS 1 Set SysVer=2K
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y>NUL 2>NUL
If Not Exist %RP%\NTDETECT.COM MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTDETECT.COM -r -y>NUL 2>NUL
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
If "%U%"=="" %DelATTR% %RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
If "%U%"=="" Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
If "%U%"=="" TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
If "%U%"=="" Echo C:\MAOTAO\MAOTAO.BIN="WinPE  By: 老毛桃">>%RP%\BOOT.INI
If /I "%SysVer%"=="2K" (
        %DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin
        Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K
        MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
        MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL
)
XCOPY ..\外置程序 /E %OP%\外置程序\ /Y /H /R>NUL 2>NUL
If Exist %OP%\%PEIni% %DelATTR% %OP%\%PEIni%
TYPE ..\%PEIni%|FIND /I /V "安装.EXE">%OP%\%PEIni%
>>%RP%\WINNT.XPE <nul Set/p=/rdexportascd /rdpath=MAOTAO\%PEFile%"
%AddATTR% %RP%\%LDRP%LDRXPE
%AddATTR% %RP%\NTDETECT.COM
%AddATTR% %RP%\WINNT.XPE
If "%U%"=="" %AddATTR% %RP%\BOOT.INI
%AddATTR% %RP%\MAOTAO /S /D
%AddATTR% %RP%\MAOTAO\*.* /S /D
%AddATTR% %OP%\外置程序 /S /D
%AddATTR% %OP%\外置程序\*.* /S /D
If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
If Exist %RP%\MTLDR %AddATTR% %RP%\MTLDR
If "%U%"=="" Call :AddLog
Goto :EOF

:AddLog
>%RP%\%LogFile% Cd.
>>%RP%\%LogFile% Echo ;此文件为 WinPE 的安装日志文件，请不要随意删除
>>%RP%\%LogFile% Echo ;否则可能会造成 WinPE 的卸载不够彻底！！！
>>%RP%\%LogFile% Echo.
>>%RP%\%LogFile% Echo WinPE镜像文件=%PEFile%
>>%RP%\%LogFile% Echo WinPE外挂位置=%OP%
>>%RP%\%LogFile% Echo WinPE安装日期=%Date% %Time%
%AddATTR% %RP%\%LogFile%
Goto :EOF

:SetOP
CLS
If "%NoOP%"=="Yes" Echo 错误：您设定的分区不存在或写保护，请按任意键重新设定。&&Echo.
Set /P OP=请设定 外置程序 存放的分区符（不需要冒号，例如 D）：
Echo.&&Echo.
If "%OP%"=="" Goto SetOP
If Not "%OP%"=="" Set OP=%OP:~0,1%:
Set TestFile=%OP%\MaotaoTest.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoOP=Yes&&Goto SetOP
Del %TestFile% /Q>NUL 2>NUL
Goto :EOF

:SUCCESS
Title %Prog%——安装完成
CLS
Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
If "%U%"=="" (
Echo 外置程序 文件夹按照您的设置，复制到了 %OP% 盘。
Echo.
Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
)
Echo.&&Echo.
Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit

原版的   这个问题我已经出现好多次了   就是安完PE后如果没有正常用安装文件进行卸载的话,PE就在也安不进去了.

也就是像安装是提示的那样,卸载时请再次运行此程序. 因为没有用程序正常卸载就格式化了.难到是U盘在安装时写入了什么?必须得用工具进行修复或卸载?

x.Nichdlas

看了一下 感觉如果是u盘安装的话不该出现不能再次安装的问题啊

你试试用bootice把u盘的mbr换成非Grub 4 Dos的再安装看看
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=57675



为了防止批处理自动关闭 你可以利用开始菜单的运行 输入cmd进入命令行
在命令行下执行这个批处理 或许可以看到错误信息更方便判断

[ 本帖最后由 x.Nichdlas 于 2009-11-10 15:13 编辑 ]

zhtzh95

格式化了几片问题依旧，郁闷啊。
换U盘从新安装使用可以正常，如没正常卸载直接格式化的情况下一样出现这问题。（PE无法正常安装了）我在去试试CMD看看是什么情况，等等回来报道。

x.Nichdlas

你用什么格式化的 如果只是Windows右键盘符格式化 是不会清空mbr的（应该没错吧）

你用bootice打开你的u盘写“主引导记录”为Windows 5.x后再试试安装

zhtzh95

近来较忙现在才反映问题解决进度多不助了.

格式化过了,开始时主引导记录按扭为灰色,将其格式化成USB-ZIP 或 USB-HDD  后主引导记录按扭可以进行选择.但格式化成window nt 5.x后问题依旧.
     有尝试过使用HPUSBFW(毛桃PE安装程序原带)格式化后U盘格式为FAT   window nt 5.x   按安装仍然无法继续.


有点怀疑是安装了GRUBGUI(毛桃PE安装程序原带)没有正常卸载引起的问题.  我在去看下相关的资料.

zhtzh95

:Err1
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
Echo %L6%
Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
If "%Choice%"=="" Goto Err1
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
If /I "%Choice%"=="2" Goto UnInstall
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto Err1
Exit

:UnInstall
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPU=%%i
If Not "%U%"=="" Set OPU=%OP%
If Exist %OPU%\外置程序 RD %OPU%\外置程序 /S /Q>NUL 2>NUL
If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
%DelATTR% %RP%\BOOT.INI>NUL 2>NUL
If Exist %RP%\BOOT.BAK (
%DelATTR% %RP%\BOOT.BAK
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
) Else (
If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL 2>NUL
If Exist %RP%\BOOT.BAK TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
)
If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
Title %Prog%——卸载完成
If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit




这里应该能解决问题,谁看的懂吗?

LOVPE

有些防毒软件会阻止PE的安装，尤其是主防，看是不是。

另：bootice在VISTA系统下有时会慌报，即用bootice改写MBR提示成功，但实际上没有（比如原是ZIP格式，改成U+提示成功，重启VISTA再进bootice看主引导竟然还是ZIP）
后来我用WINHEX前64个扇区填00后，再用系统属性格式化，再进bootice改写MBR才成功。

zhtzh95

VISTA下格式化也试过了。
目前还未找到解决方案。

有个地方希望大家注意下，应该能解决的，就是毛桃安装包的BAT文件里的那句话     如果您需要将 WinPE 卸载，请重新运行本安装程序。否则将无法卸载干净。   ？？？ 分析卸载部分内容应该能找到解决方案，可我看不懂。 也不知道是哪里的问题，里面没有注明。希望知道的朋友分享下。

不过到是有个另类的解决方法。下载安装PE 工具包也可以启动到PE。安装完后占用空间34M 挺小的，不过工具到挺全的，集成了常用的PM   PTDD GHOST11 注册表 等软件。
下载地址http://9.gddx3.crsky.com/200905/TonPE-v1.91.zip