保留指定文件夹其余全删除

wenbieba · 发表于 2023-5-3 01:17:17

在某一文件夹下有若干个文件夹，用批处理历遍该文件夹，保留指定的几个文件夹，其余全删除，命令怎么写，请大神写下该命令

austere · 发表于 2023-5-3 03:12:31

@echo off
setlocal enableextensions
set "FolderPath=C:\Path\To\Folder"
set "KeepFolder1=Folder1"
set "KeepFolder2=Folder2"
set "KeepFolder3=Folder3"
rem 遍历目标文件夹
for /d %%f in (%FolderPath%\*) do (
rem 如果不属于保留文件夹，则删除该文件夹及其所有内容
if not "%%~nxf"=="%KeepFolder1%" if not "%%~nxf"=="%KeepFolder2%" if not "%%~nxf"=="%KeepFolder3%" (
echo Deleting folder "%%~f"...
rd /s /q "%%~f"
)
)
echo Done.
pause

复制代码

fzp070 · 发表于 2023-5-3 03:13:23

以【E:\123\】举个例，自己根据自己需要的实际目录修改及增加需保留的文件夹。

@echo off
cd /d E:\123
::删除[E:\123]文件夹内所有文件，除开子文件夹
del /f/q E:\123
:删除[E:\123]内除 AAA文件夹(及子文件夹) 外所有文件夹
for /f "delims=" %%b in ('dir /b "E:\123"') do (
if "AAA" NEQ "%%b" (
rd /s /q "E:\123\%%b")
)
ping -n 5 127.1>nul
exit

复制代码

wenbieba · 发表于 2023-5-3 11:32:22

austere 发表于 2023-5-3 03:12

谢谢
@echo off
echo "使用脚本删除文件夹A中除了特定文件意外的文件"
echo.
rem 进入文件夹A目录
cd A
rem 对文件夹进行遍历，除保留文件夹1、2以外的文件夹进行删除

for /D %%i in ("C:\Windows\web\") DO (
if not %%i==Screen (
if not %%i==Wallpaper (
echo 删文件夹：%%i
rd /S /Q %%i
) else (
rem 对保留文件夹2中的内容进行特殊处理，如有需求
)
)
)这是网上找的那个地方有误

wenbieba · 发表于 2023-5-3 11:32:54

fzp070 发表于 2023-5-3 03:13
以【E:\123\】举个例，自己根据自己需要的实际目录修改及增加需保留的文件夹。

谢谢

wenbieba · 发表于 2023-5-3 11:34:27

fzp070 发表于 2023-5-3 03:13
以【E:\123\】举个例，自己根据自己需要的实际目录修改及增加需保留的文件夹。

谢谢，这类写法
@echo off
echo "使用脚本删除文件夹A中除了特定文件意外的文件"
echo.
rem 进入文件夹A目录
cd A
rem 对文件夹进行遍历，除保留文件夹1、2以外的文件夹进行删除

for /D %%i in ("C:\Windows\web\") DO (
if not %%i==Screen (
if not %%i==Wallpaper (
echo 删文件夹：%%i
rd /S /Q %%i
) else (
rem 对保留文件夹2中的内容进行特殊处理，如有需求
)
)
)那个地方有误

fzp070 · 发表于 2023-5-4 00:43:37

本帖最后由 fzp070 于 2023-5-4 00:45 编辑

wenbieba 发表于 2023-5-3 11:34
谢谢，这类写法
@echo off
echo "使用脚本删除文件夹A中除了特定文件意外的文件"

6楼的代码主要有两个地方要修改下：
一是For命令那行代码，要加个*号，"C:\Windows\web\*"
二是if那行代码，要么改成2楼的if not "%%~nxi"==Wallpaper，要么就if not %%i==%cd%\Wallpaper (
如下几个方案应该都是可以的，但web目录是系统目录，可能会没有权限删除，修改下文件夹当前用户权限试试吧。
2楼方案根据6楼路径和排除文件夹的修改

@echo off
setlocal enableextensions
set "FolderPath=C:\Windows\web"
set "KeepFolder1=Screen"
set "KeepFolder2=Wallpaper"
set "KeepFolder3=Folder3"
rem 遍历目标文件夹
for /d %%f in (%FolderPath%\*) do (
rem 如果不属于保留文件夹，则删除该文件夹及其所有内容
if not "%%~nxf"=="%KeepFolder1%" if not "%%~nxf"=="%KeepFolder2%" if not "%%~nxf"=="%KeepFolder3%" (
echo Deleting folder "%%~f"...
rd /s /q "%%~f"
)
)
echo Done.
pause

复制代码

3楼方案根据6楼路径和排除文件夹的修改

@echo off
cd /d C:\Windows\web\
::删除[C:\Windows\web\]文件夹内所有文件，除开子文件夹
del /f/q C:\Windows\web\
::删除[C:\Windows\web\]内除 Screen和Wallpaper文件夹(及子文件夹) 外所有文件夹
for /f "delims=" %%b in ('dir /b "C:\Windows\web"') do (
if "Screen" NEQ "%%b" (
if "Wallpaper" NEQ "%%b" (
echo 删文件夹：%%b
rd /s /q "C:\Windows\web\%%b")
)
)
ping -n 5 127.1>nul
exit

复制代码

修改后的6楼方案

@echo off
echo "使用脚本删除文件夹A中除了特定文件意外的文件"
echo.
rem 进入文件夹web目录
cd /d "C:\Windows\web"
rem 对文件夹进行遍历，除保留文件夹1、2以外的文件夹进行删除
for /D %%i in ("C:\Windows\web\*") DO (
if not %%i==%cd%\Screen (
if not %%i==%cd%\Wallpaper (
echo 删文件夹：%%i
rd /S /Q %%i
) else (
rem 对保留文件夹2中的内容进行特殊处理，如有需求
)
)
)
pause

复制代码

wenbieba · 发表于 2023-5-4 20:41:01

fzp070 发表于 2023-5-4 00:43
6楼的代码主要有两个地方要修改下：
一是For命令那行代码，要加个*号，"C:\Windows\web\*"
二是if那行 ...

辛苦大师，
再麻烦大师写一个厉遍C盘删除Internet Explorer文件的命令

wenbieba · 发表于 2023-5-5 00:19:58

fzp070 发表于 2023-5-4 00:43
6楼的代码主要有两个地方要修改下：
一是For命令那行代码，要加个*号，"C:\Windows\web\*"
二是if那行 ...

@Echo Off
For /f "tokens=*" %%i in ('dir /a-d /b /s "C:\Program Files\IE文件夹" "C:\Program Files（x86）\IE文件夹"') do (Echo %%iDel /q /s /a /f "%%i")

wenbieba · 发表于 2023-5-6 18:33:49

austere 发表于 2023-5-3 03:12

for /F %%i in (' Type "%~dp0Windows\Remove.TXT" 2^>nul')
for /F "tokens=2 delims=: " %%a in ('dism /online /get-features ^| Findstr /I /C:"FeatureName : %%i"') do if "%%a" NEQ "" Call Dism /online /Disable-Feature /FeatureName:%%a >nul
)
运行之后无效果。麻烦大神指点

czg2008 · 发表于 2023-5-6 19:19:50

学习学习谢谢

lsc202 · 发表于 2023-6-1 18:37:38

本帖最后由 lsc202 于 2023-6-11 21:53 编辑

已解决

		自动登录	找回密码
密码			注册

[求助] 保留指定文件夹其余全删除

点评

点评

点评

点评