自动安装当前目录下的inf的命令有吗

j2rong

打包了驱动。想做个压缩包实现自动安装，没有bat命令，放在这个inf同文件夹下面可以使用的

我是小青蛙

pnputil /add-driver "%ProgramFiles%\Drive\install\*.inf" /subdirs /install

l3429900

我是小青蛙 发表于 2025-12-11 10:20
pnputil /add-driver "%ProgramFiles%\Drive\install\*.inf" /subdirs /install

多谢，学习了

wn168cn@163.com

感谢2#分享

PCHH

学习了

smile_z

学习一下

j2rong

@echo off
chcp 936 >nul
net session >nul 2>&1 || (echo 请以管理员运行！ & pause & exit /b 1)

echo 正在安装驱动...

:: 保存当前目录路径，用于后续删除
set "SCRIPT_DIR=%~dp0"

:: 安装所有INF文件
for %%i in ("%SCRIPT_DIR%\*.inf") do (
    echo 安装: %%~nxi
    pnputil /add-driver "%%i" /install
)

echo.
echo 驱动安装完成！

:: 延迟确保安装完全完成
timeout /t 2 >nul

echo 正在删除文件夹：%SCRIPT_DIR%

:: 关键：先退出当前目录，否则无法删除
cd /d "%temp%"

:: 删除文件夹（包括脚本自身）
rmdir /s /q "%SCRIPT_DIR%" 2>nul

:: 检查是否删除成功
if exist "%SCRIPT_DIR%" (
    echo 删除失败！文件夹可能被占用。
    echo 请手动删除：%SCRIPT_DIR%
    timeout /t 5 >nul
) else (
    echo 文件夹已成功删除！
    timeout /t 1 >nul
)




这个可以，加了自删。管理员运行

nttwqz

楼上几位注意，win10不同版本的pnputil用法不同

guong

进来学习下

834772509

可以用DriverIndexer打包压缩包成exe

1. DriverIndexer.exe pack <驱动包/目录路径> <输出EXE路径>

复制代码

nttwqz

除了楼上的，还有个图形图形界面版的。
drvindex

ebaqiang

多谢，学习了