[20250319] 批处理：顺序和随机设置桌面壁纸（适用PE和正常系统）

BEIKING

1. @echo off
   
2. if /i "%UserName%" == "SYSTEM" (Goto GotAdmin) else (reg query "HKLM\SYSTEM\ControlSet001\Control\MiniNT" 1>nul 2>nul&&Goto GotAdmin)
   
3. :BatchGotAdmin
   
4. Set _Args=%*
   
5. if `%1` neq `` Set "_Args=%_Args:"=""%"
   
6. if exist %WinDir%\System32\fltMC.exe fltMC 1>nul 2>nul||mshta VBScript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c """"%~f0"" %_Args%""",,"runas",1)(Window.Close) 2>nul&&Exit /b
   
7. 
   
8. :GotAdmin
   
9. Pushd "%CD%"&cd /d "%~dp0"
   
10. find /? 1>nul 2>nul||(Color cf&echo 找不到 find.exe 文件，按任意键退出。&Pause >nul&Exit /b)
    
11. REM 内部参数初始化
    
12. Set "Ext=*.jpg *.jpeg *.png *.gif *.bmp" :: 支持壁纸类型
    
13. Set "Style=拉伸" :: 默认壁纸适应模式 (填充, 适应, 拉伸, 平铺, 居中, 跨区)
    
14. 
    
15. :Start
    
16. Title 切换壁纸&(if exist %WinDir%\System32\ureg.dll Mode 40,10 2>nul)&Color 2f
    
17. for /f "tokens=2*" %%i in ('reg query "HKCU\Control Panel\Desktop" /v "WallPaper" 2^>nul') do Set "OWP=%%~j"
    
18. Set Count=0&for /f "tokens=* usebackq" %%f in (`dir /a-d-s-h /b %Ext% 2^>nul^|find /v /c "%~nx0"`) do Set /a "Count=%%~f"
    
19. echo 壁纸数量: [%Count%]
    
20. if %Count% == 0 Color cf&echo 壁纸类型: ↓&echo  %Ext%&Call :Delay 3&Exit /b
    
21. REM 调用参数：-Next(默认) -Random +Next +Random
    
22. Set CP=-&Set GP=顺序切换&Set "Args=%~1"
    
23. if defined Args (
    
24.     Set "CP=%Args:~0,1%"
    
25.     if /i "%Args:~1%" == "Random" Set GP=随机切换
    
26. )
    
27. Goto %GP%
    
28. 
    
29. :顺序切换
    
30. for /f "tokens=* usebackq" %%f in (`dir /a-d-s-h /b /o:d %Ext% 2^>nul^|find /v "%~nx0"`) do (
    
31.     Copy "%%~f"+,, "%%~f" 1>nul 2>nul&Set "NWP=%%~f"&Goto 设置壁纸
    
32. )
    
33. Exit /b
    
34. 
    
35. :随机切换
    
36. Set Num=1&Set /a RNum=%Random%%%%Count%+1 2>nul
    
37. Setlocal EnableDelayedExpansion
    
38. for /f "tokens=* usebackq" %%f in (`dir /a-d-s-h /b %Ext% 2^>nul^|find /v "%~nx0"`) do (
    
39.     if !Num! == %RNum% (Endlocal&Set RNum=[%RNum%]&Set "NWP=%%~f"&Goto 设置壁纸)
    
40.     Set /a Num+=1
    
41. )
    
42. Endlocal&Exit /b
    
43. 
    
44. :设置壁纸
    
45. if /i "%CP%" == "+" (Copy /y "%NWP%" "%WinDir%\Web\Wallpaper\%NWP%" >nul&&Set "NWP=%WinDir%\Web\Wallpaper\%NWP%") else Set "NWP=%~dp0%NWP%"
    
46. if "%GP%" == "随机切换" if /i "%OWP%" == "%NWP%" if %Count% gtr 1 Goto 随机切换
    
47. echo "%NWP%"|find /i "填充" 1>nul 2>nul&&Set "Style=填充"
    
48. echo "%NWP%"|find /i "适应" 1>nul 2>nul&&Set "Style=适应"
    
49. echo "%NWP%"|find /i "拉伸" 1>nul 2>nul&&Set "Style=拉伸"
    
50. echo "%NWP%"|find /i "平铺" 1>nul 2>nul&&Set "Style=平铺"
    
51. echo "%NWP%"|find /i "居中" 1>nul 2>nul&&Set "Style=居中"
    
52. echo "%NWP%"|find /i "跨区" 1>nul 2>nul&&Set "Style=跨区"
    
53. echo 适应模式: %Style%
    
54. echo %GP%: %RNum% ↓
    
55. echo %NWP%
    
56. Pecmd.exe /? 1>nul 2>nul&&(Pecmd.exe WALL "%NWP%"&&reg delete "HKCU\Control Panel\Desktop" /f /v "Wallpaper.PECMD" 1>nul 2>nul)||(reg add "HKCU\Control Panel\Desktop" /f /v "WallPaper" /t REG_SZ /d "%NWP%" 1>nul 2>nul)
    
57. Set var=&for %%i in (填充010, 适应06, 拉伸02, 平铺10, 居中00, 跨区022) do (echo "%%~i"|find /i "%Style%" 1>nul 2>nul&&Set "var=%%~i")
    
58. if defined var (
    
59.     reg add "HKCU\Control Panel\Desktop" /f /v "TileWallpaper" /t REG_SZ /d "%var:~2,1%" 1>nul 2>nul
    
60.     reg add "HKCU\Control Panel\Desktop" /f /v "WallpaperStyle" /t REG_SZ /d "%var:~3%" 1>nul 2>nul
    
61. )
    
62. Call :Flush
    
63. if not defined Args Call :Delay 1
    
64. Exit /b
    
65. 
    
66. :Delay :: 延迟操作 <%1=Sec|延迟秒数> [%2=+|显示倒计时]。
    
67. if "%~2" == "+" (Set #=2) else Set #=1
    
68. if exist %WinDir%\System32\timeout.exe (timeout /t %~1 %#%>nul) else if exist %WinDir%\System32\choice.exe (choice /t %~1 /d y /n >nul) else ping 127.1 -n %~1 >nul
    
69. Goto :eof
    
70. 
    
71. :Flush :: 可能不生效，需要手动重启资源管理器。
    
72. Set N=20
    
73. :FLoop
    
74. Set /a N-=1&@start "" rundll32.exe user32.dll,UpdatePerUserSystemParameters 1,True
    
75. if "%n%" neq "0" Goto FLoop
    
76. Goto :eof

复制代码

PE系统，调用 Pecmd WALL 命令设置桌面壁纸，很稳定都生效
正常系统，注册表设置壁纸路径后，调用 rundll32.exe user32.dll,UpdatePerUserSystemParameters 1,True 刷新桌面，有一定概率不生效。需要多次刷新

【支持脚本内部参数设置】
Set "Ext=*.jpg *.jpeg *.png *.gif *.bmp" :: 支持壁纸格式
Set "Style=拉伸" :: 默认壁纸适应模式 (填充, 适应, 拉伸, 平铺, 居中, 跨区)

【支持命令行参数调用】
-Next               按顺序设置脚本所在文件夹图片为桌面壁纸 (无参默认)
-Random          按随机设置脚本所在文件夹图片为桌面壁纸
+Next              按顺序复制脚本所在文件夹图片到系统Web目录，并设置为桌面壁纸
+Random         按随机复制脚本所在文件夹图片到系统Web目录，并设置为桌面壁纸

【支持通过图片文件名，设置壁纸为指定适应模式】
若图片文件名带有以下名称，则设置壁纸为指定适应模式。
填充, 适应, 拉伸, 平铺, 居中, 跨区
例如：01_拉伸.jpg
　　　02_平铺.png
　　　03_居中.bmp

【使用方法】
复制源码到记事本保存，务必保存为ANSI格式，若为UTF-8格式执行会报错
将脚本文件置于壁纸同一目录执行，不支持下级目录。

(附件为旧版，帖子源码为新版)

BEIKING

感觉应该比用第三方程序方便

a583091790

是呀这串 rundll32.exe user32.dll,UpdatePerUserSystemParameters，我有时也不会刷新生效。墙纸没更换成功

BEIKING

a583091790 发表于 2022-11-29 15:23
是呀这串 rundll32.exe user32.dll,UpdatePerUserSystemParameters，我有时也不会刷新生效。墙纸没更换成功

我处理了，连续刷新20次，，可以的

IDK灬飘渺

pe随机壁纸，有点意思

likeyouli

我改成2次 试试可以不 (随机设置桌面壁纸)
   先谢谢了

zp1688

感觉应该比用第三方程序方便

zhangze

系统有换壁纸的功能啊！

9zhmke

也许需要延时再刷新

come77

用处不大，感谢分享

wy66

谢谢分享

飞黄腾达9

谢谢分享

cuicongyuan

支持！

9zhmke

BEIKING 发表于 2022-11-29 15:27
我处理了，连续刷新20次，，可以的

也许需要延时再刷新

liuyanjun

感谢分享 很有用

chinaren12

这个win7和win10不都可以随机更换壁纸吗？只要你选择主题就行了。

楼主这个应该是专门为PE设计的。

2010laodu

感谢分享 很有用

lxj0209103

windows 11 系统 Set n=20 :循环 改成Set n=2 :循环 刷新2次没有更新壁纸，windows 11 PE没有问题，

dszsdyx

挺好的，换换风格。

miraclex

谢谢了啊

papachi

来试试看呗。谢谢。

jh198354

感谢分享！

being

Win7 X86 只能改一次，后面的不成功，结束explorer.exe也不行。也许需要重启

BEIKING

壁纸切换脚本更新

调用参数：
-Next        顺序切换壁纸(默认)
+Next       顺序切换壁纸，壁纸文件拷入到%WinDir%\Web\Wallpaper\
-Random   随机切换壁纸
+Random  随机切换壁纸，壁纸文件拷入到%WinDir%\Web\Wallpaper\

使用方法：
将脚本文件置于壁纸同一目录执行，不支持下级目录。
壁纸目录只能有脚本文件和壁纸文件，不能存在其他文件或文件夹，会影响壁纸切换！

baolinqiu1

随机壁纸，有点意思

千城

这个切换丝滑吗，会不会有闪屏现象？

macowen

谢谢来着分享！！

hycsl888

这个系统幻灯片不就是吗？

hehuiying

谢谢分享