如果某个文件夹包含某个固定名称文件夹，则删除这个文件夹，应该怎么写

zhxy9804

如题，才疏学浅，不知道怎么写，特来求教
多谢啦！
大体意思是遍历c盘d盘，如果某个文件夹包含文件夹aaa，则删除这个文件夹

xzf680

试试看行不

1. Global Const $fp_a = "c:\aaa"
   
2. Global Const $fp_b = "d:\aaa"
   
3. 
   
4. If FileExists($fp_a) Or FileExists($fp_b) Then
   
5. DirRemove($fp_a)
   
6. DirRemove($fp_b)
   
7. EndIf
   

复制代码

zhxy9804

xzf680 发表于 2016-9-17 11:01
试试看行不

谢谢回复，但是你这个是批处理吗？
我的还要遍历c盘d盘所有的文件夹的啊

xzf680

zhxy9804 发表于 2016-9-17 11:40
谢谢回复，但是你这个是批处理吗？
我的还要遍历c盘d盘所有的文件夹的啊

这是au3
不会批处理哦！

slore

1. @echo off
   
2. set tf=aaa
   
3. for /f "delims=" %%i in ('dir /ad /b /s D:\ ^| findstr /i "\\%tf%$"') do (
   
4.   echo rd /s /q "%%~dpi"
   
5. )
   
6. pause
   
7. exit

复制代码

如果D盘根目录下直接存在aaa，整个D盘目录要清除。。。你最好先判断下。

nttwqz

xzf680 发表于 2016-9-17 14:05
这是au3
不会批处理哦！

请教个问题

findstr /i "\\%tf%$"'

中的\\是不是用\转义了本身？就像%转义其本身一样？


末尾的%%～dpi是为了更保险？好像%%i也可以

slore

nttwqz 发表于 2016-9-17 16:53
请教个问题

findstr /i "\\%tf%$"'

对的，\\是转义

%%~dpi是因为谁包含aaa删除这个文件夹而不是要删除aaa文件夹。
dpi的话，得到的是aaa的父目录。

nttwqz

slore 发表于 2016-9-17 15:54
如果D盘根目录下直接存在aaa，整个D盘目录要清除。。。你最好先判断下。

好吧，经测试，你这个清空根目录的原因就是这个"%%~dpi"

根目录的aaa路径自然是根目录，应写作"%%~dpnxi"

为何要加nx，因为要适应a.b这样的文件夹，当然，这里可以省去。

nttwqz

好吧，楼主的描述不够严谨

改了一下，现在是删除aaa的父文件夹，不会清空磁盘根目录，也不会删除根目录的aaa文件夹

1. 方法一：
   
2. 
   
3. @echo off
   
4. for %%a in (c d) do (
   
5.         pushd %%a:\
   
6.         for /r %%b in (aaa) do if exist %%b\ if /i not "%%~dpb"=="%%a:" rd /s /q "%%~dpb" && echo 已删除 %%~dpb
   
7. )
   
8. pause
   
9. 
   
10. 
    
11. 方法二：
    
12. 
    
13. @echo off
    
14. for %%c in (c d) do for /f "delims=" %%d in ('dir /ad /s /b  %%c:\ ^| findstr "\\aaa$"') do if /i not "%%~dpd"=="%%c:" rd /s /q "%%~dpd" && echo 已删除 %%~dpd
    
15. pause
    
16. 
    
17. 
    
18. 方法三：
    
19. 检索所有可见分区
    
20. 
    
21. @echo off
    
22. for /f "delims=" %%e in ('wmic fsdir where "filename='aaa' and path<>'\\'" get name ^| find ":") do rd /s /q "%%~dpe" && echo 已删除 %%~dpe

复制代码

zhxy9804

slore 发表于 2016-9-17 15:54
如果D盘根目录下直接存在aaa，整个D盘目录要清除。。。你最好先判断下。

提前加上一行，先删除根目录里面的

nttwqz

slore 发表于 2016-9-17 17:42
对的，\\是转义

%%~dpi是因为谁包含aaa删除这个文件夹而不是要删除aaa文件夹。

我理解的是删除aaa文件夹，楼主描述的话可以这样理解……

如果是删除aaa的父文件夹，删除磁盘根目录就没有错了，完全符合楼主的要求！！！嘿嘿

zhxy9804

nttwqz 发表于 2016-9-17 18:04
好吧，楼主的描述不够严谨

改了一下，现在是删除aaa的父文件夹，不会清空磁盘根目录，也不会删除根目录 ...

非常感谢哈

alltask

@echo off
set tf=aaa
for /f "delims=" %%i in ('dir /ad /b /s D:\ ^| findstr /i "\\%tf%$"') do (
  echo rd /s /q "%%~dpi"
)
pause
exit
第一行能看懂
第二行能看懂
最后一行能懂
倒数第二行懂
其它的就不懂了。
"\\%tf%$"'=当前盘下的aaa目录吗？$符号有什么用？？？
echo rd /s /q "%%~dpi" 这个能执行吗？echo 只是显示用的啊，能执行删除目录的作用吗？
delims=为什么要加双引号
这些都不懂哎，如果这些都懂了，是不是for命令基本毕业了？

wenday1999

学习了~~~