无忧启动论坛

标题: inf文件 [打印本页]

作者: wenbieba 时间: 2021-1-14 20:55
标题: inf文件
inf文件如何用批处理命令来安装，免去鼠标右键安装.
望大神写个命令

作者: maghreb 时间: 2021-1-14 21:18
for /f "delims=" %%a in ('dir /b /s /a-d ".\DriversBackup\*.inf"') do infdefaultinstall "%%a"

作者: 极冰凌心 时间: 2021-1-14 21:35
卸载呢？

作者: CodeHz 时间: 2021-1-14 22:32
安装：RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 128 path-to-inf\infname.inf
卸载：RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultUninstall 128 path-to-inf\infname.inf

作者: wenbieba 时间: 2021-1-15 08:03

CodeHz 发表于 2021-1-14 22:32
安装：RUNDLL32.EXE SETUPAPI.DLL,InstallHinfSection DefaultInstall 128 path-to-inf\infname.inf
卸载 ...

如何指定具体路径

作者: wenbieba 时间: 2021-1-15 08:04

maghreb 发表于 2021-1-14 21:18
for /f "delims=" %%a in ('dir /b /s /a-d ".\DriversBackup\*.inf"') do infdefaultinstall "%%a"

具体路径怎么指定

作者: wenbieba 时间: 2021-1-15 08:06

maghreb 发表于 2021-1-14 21:18
for /f "delims=" %%a in ('dir /b /s /a-d ".\DriversBackup\*.inf"') do infdefaultinstall "%%a"

这个自动识别当前文件夹下的inf吗

作者: maghreb 时间: 2021-1-15 08:58

wenbieba 发表于 2021-1-15 08:04
具体路径怎么指定

我的例子里inf路径为 .\DriversBackup\*.inf 啊
即当前批处理文件所在路径下DriversBackup文件夹里的所有inf文件(包括子文件夹)进行逐一安装，你也可以换成其他的，比如 D:\wo_shi_xiao_shuai_ge\*.inf

作者: maghreb 时间: 2021-1-15 09:21

wenbieba 发表于 2021-1-15 08:06
这个自动识别当前文件夹下的inf吗

可以自动识别安装驱动的inf文件延伸：在重装系统前可以先备份驱动，重装系统后再安装驱动，这样快速简洁(当然也可以辅以其他小程序来实现，比如DISM++的备份和还原功能)。

@echo off&mode con: cols=50 lines=13&title 驱动备份、还原工具 &color 17 &setlocal enabledelayedexpansion
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0&bcdedit >nul
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B
:UACAdmin
cls
echo.
echo                驱动备份、还原工具
echo --------------------------------------------------
echo.
echo.                [1] 备份驱动
echo.
echo.                [2] 恢复驱动
echo.
echo --------------------------------------------------
choice /c:1234 /n /m "输入你的选择 :"
echo --------------------------------------------------
if errorlevel 2 goto :Recurse
if errorlevel 1 goto :Backup
:B
:-B
:Backup
echo 正在备份驱动。。。
mkdir .\DriversBackup 2>nul
dism /online /export-driver /destination:.\DriversBackup >nul 2>nul
echo 驱动备份完成 & pause >nul 2>nul & goto UACAdmin
:R
:-R
:Recurse
echo 正在恢复驱动。。。
for /f "delims=" %%a in ('dir /b /s /a-d ".\DriversBackup\*.inf"') do infdefaultinstall "%%a"
echo 驱动恢复完成 & pause >nul 2>nul & goto UACAdmin

作者: CodeHz 时间: 2021-1-15 12:26

wenbieba 发表于 2021-1-15 08:03
如何指定具体路径

（后面那个不就是具体路径吗，自己替换成实际的就好了啊

欢迎光临无忧启动论坛 (http://wuyou.net/)