[08年11月3日更新，再更新就是适用于VISTA下了]新版解决盘符错乱批处理

victor888 · 发表于 2008-10-11 23:18:31

只要有热心朋友的参与，这个脚本肯定会做到最好！BEST GOING......
＝＝
在此感谢MSFN论坛的JACLAZ和CN-DOS的顶级批处理高手的指点！

本次更新，在XP系统下，接近最终更新了。
代码优化，执行效率更高，对于盘符顺序正确的盘，不再删除盘符。

不论多少硬盘，多少虚拟盘，多少USB盘，多少光盘，此程序都会正确排列盘符顺序的。

本程序就是用于解决盘符错乱的，运行于NT系统，暂不适用于VISTA系统（因为VISTA下的DISKPART命令与XP不同）。无论是启动PE盘符错乱，还是使用USB盘安装XP使盘符错乱，运行一下此批处理，都正常了。

1：运行本程序，请将其放到系统盘运行；
2：运行此程序时，请关闭非系统盘打开的任何程序及文件，如果有安装到非系统盘的程序，则由于重排盘符，如果原来盘符就错乱的话，则有可能使程序指向出错，此种情况建议不要运行此程序。
3：在PE下运行此程序，请将其和这几个工具find.exe(有的PE竟然连这个也给精简了), fsutil, mountvol, diskpart,findstr.exe放到一块运行，这几个程序可以从XP系统的windows\system32目录获得。
本程序不会弄丢你的任何东西，如果运行失败，可以通过磁盘管理手动添加更改盘符。
MSFN英文讨论及链接：http://www.msfn.org/board/compatible-batch-file-o-t124539.html。

::created by VICTOR888, thanks to jaclaz in MSFN forum and batch experts in cn-dos forum
::revised on Nov 3, 2008
::ordering drive letters by drive type
::ordered drive letters are assigned to fixed disk, cdrom, usb hard disk and usb stick
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION
::get usbdisk amount
set /a usbdiskam=0
for /f %%a in ('reg query HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Disk\Enum /s ^| find "USBSTOR"') do (
set /a usbdiskam=!usbdiskam!+1
)
::get removable usb disk amount and their drive letters
set /a remusbam=0
FOR /F "tokens=*" %%a in ('fsutil fsinfo drives ^| FIND /V ""') DO (
set dr=%%a
SET dr=!dr:~-5,1!
IF !dr! GTR A (
FOR /F "tokens=1,2 delims=-" %%b IN ('fsutil fsinfo drivetype !dr!:') DO (
set cr=%%c
set cr=!cr:~1,2!
if "!cr!" equ "CD" (
SET vname=%%b
SET vname=!vname:~0,1!
for /f %%x in ('mountvol !vname!: /l ^| find "\"') do call set dvdrom=%%dvdrom%% %%vname%%
)
if "!cr!" equ "可移" (
set /a remusbam=!remusbam!+1
SET vname=%%b
SET vname=!vname:~0,1!
call set remusb=%%remusb%% %%vname%%
)
)
)
)
::get fixed usb disk amount
if %usbdiskam% GTR 0 (
set /a fixedusbam=%usbdiskam%-%remusbam%
) else (
set /a fixedusbam=0
)
::get total hard disks amount
set /a totalhdam=0
for /f "skip=9 tokens=2" %%a in ('echo list disk ^| diskpart.exe') do (
set /a totalhdam=!totalhdam!+1
)
::get innternal fixed hard disk amount
set /a fixedhdam=%totalhdam%-%fixedusbam%
::get internal hard disk drive letters and fixed usb drive letters
if %fixedusbam% equ 0 (
for /f "skip=9 tokens=2" %%a in ('echo list disk ^| diskpart.exe') do (
echo select disk %%a >selectdisk%%a.txt
echo detail disk >>selectdisk%%a.txt
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk%%a.txt') do (
set dr=%%b
call set fixdrv=%%fixdrv%% %%dr%%
)
del selectdisk%%a.txt
)
) else (
for /f "tokens=1 delims=" %%a in ('reg query HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Disk\Enum /v 0 ^| find "REG_SZ"') do set hd=%%a
if "%hd:~-7%" neq "USBSTOR" (
for /f "skip=9 tokens=2" %%a in ('echo list disk ^| diskpart.exe') do (
set /a counter=!counter!+1
echo select disk %%a >selectdisk%%a.txt
echo detail disk >>selectdisk%%a.txt
if !counter! LEQ %fixedhdam% (
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk%%a.txt') do (
set dr=%%b
call set fixdrv=%%fixdrv%% %%dr%%
del selectdisk%%a.txt
)
) else (
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk%%a.txt') do (
set dr=%%b
call set hdusb=%%hdusb%% %%dr%%
del selectdisk%%a.txt
)
)
)
) else (
echo select disk 0 >selectdisk0.txt
echo detail disk >>selectdisk0.txt
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk0.txt') do (
set dr=%%b
call set hdusb=%%hdusb%% %%dr%%
del selectdisk0.txt
)
for /f "skip=10 tokens=2" %%a in ('echo list disk ^| diskpart.exe') do (
set /a counter=!counter!+1
echo select disk %%a >selectdisk%%a.txt
echo detail disk >>selectdisk%%a.txt
if !counter! LEQ %fixedhdam% (
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk%%a.txt') do (
set dr=%%b
call set fixdrv=%%fixdrv%% %%dr%%
del selectdisk%%a.txt
)
) else (
for /f "tokens=3 skip=17" %%b in ('diskpart /s selectdisk%%a.txt') do (
set dr=%%b
call set hdusb=%%hdusb%% %%dr%%
del selectdisk%%a.txt
)
)
)
)
)
::get all drive letters except A
FOR /F "tokens=*" %%b in ('fsutil fsinfo drives ^| FIND /V ""') DO (
set dr=%%b
SET dr=!dr:~-5,1!
IF !dr! GTR B call set alldrv=%%alldrv%% %%dr%%
)
::get drive letters with mount point
FOR /F %%a in ('mountvol ^| findstr :\') do (
set dr=%%a
set dr=!dr:~0,1!
IF !dr! GTR A call set mountdrv=%%mountdrv%% %%dr:~0,1%%
)
)
::get virtual drives created by virtual CD soft, command subst, net use and ram disk etc.
set virdrv=%alldrv%
for %%a in (%mountdrv%) do call set virdrv=%%virdrv:%%a=%%
set virdrv=%virdrv% %systemdrive:~0,1%
::ordering drive letters by internal fixed hard disk, cdrom, hard usb disk and removalbe usbdisk
set neworder=%fixdrv% %dvdrom% %hdusb% %remusb%
call set neworder=%%neworder:%systemdrive:~0,1%=%%
set fulldrv=CDEFGHIJKLMNOPQRSTUVWXYZ
for %%a in (%virdrv%) do call set fulldrv=%%fulldrv:%%a=%%
:: get ordered vid
set /a n=0
for %%a in (%neworder%) do (
call :done %%a %%fulldrv:~!n!,1%%
set /a n+=1
)
if exist "c.txt" (
for /f "tokens=1,2 delims= " %%a in (c.txt) do mountvol %%b %%a
del c.txt
)
goto :eof
:done
if %1 neq %2 (
for /f %%b in ('mountvol %1: /l') do echo %%b %2: >>c.txt
mountvol %1: /d
)
goto :eof

复制代码

[ 本帖最后由 victor888 于 2008-11-3 14:31 编辑 ]

xuexiang · 发表于 2008-11-20 12:56:15

期待楼主更新支持ＶＩＳＴＡ的

HuAnGkUn · 发表于 2008-11-7 15:11:28

不错，谢谢版主持续不断的更新

世界第一等 · 发表于 2008-11-7 08:47:38

谢谢版主发这么好的工具测试一下看看

lsj0416 · 发表于 2008-11-3 15:49:36

找回丢失的盘符.rar (244 Bytes, 下载次数: 69)

a8775 · 发表于 2008-11-3 15:46:28

谢谢分享，先下载了。

victor888 · 发表于 2008-11-3 14:30:12

原帖由 lsj0416 于 2008-11-3 13:52 发表
2003下除硬盘以外的盘符全丢，包括虚拟光驱！

好像不能用于2003，等我晚上回家测试，谢谢你的报告。

lsj0416 · 发表于 2008-11-3 13:52:09

2003下除硬盘以外的盘符全丢，包括虚拟光驱！

nczw · 发表于 2008-11-3 11:33:08

很好用，就是批处理循环时间长了点。

victor888 · 发表于 2008-11-3 11:12:10

原帖由 lsj0416 于 2008-11-3 11:04 发表
2003行吗?上次的我测试丢盘符。我的机器装有虚拟光驱，读卡器，盘符一大堆，结果虚拟光驱丢失，读卡器盘符显示不全，试试这个！

等待你的报告。

lsj0416 · 发表于 2008-11-3 11:04:00

2003行吗?上次的我测试丢盘符。我的机器装有虚拟光驱，读卡器，盘符一大堆，结果虚拟光驱丢失，读卡器盘符显示不全，试试这个！

victor888 · 发表于 2008-11-3 10:43:41

XP下接近最终更新了，再更新就是使其适用于VISTA。

victor888 · 发表于 2008-11-1 21:13:24

请昨晚帮忙测试的朋友继续测试，BUG修正了。

7915083 · 发表于 2008-11-1 10:16:01

谢谢分享经验哈.学习了

nczw · 发表于 2008-11-1 09:22:51

看完了，下下来先试试看。

云飞日月 · 发表于 2008-10-31 23:19:25

支持大大的更新，今晚测试一下

HB天意 · 发表于 2008-10-31 23:11:43

虽然用不上，还是支持一下。
楼主精神可嘉。

victor888 · 发表于 2008-10-31 23:07:49

原帖由 lxl1638 于 2008-10-31 19:07 发表
路过而已，那堆代码会使人头晕。。。。。。。。。。。

该死的，等我最优化后再看。

lxl1638 · 发表于 2008-10-31 19:07:43

路过而已，那堆代码会使人头晕。。。。。。。。。。。

dfghj · 发表于 2008-10-31 15:39:46

刚开始接触，希望解决盘符问题

破碎无痕 · 发表于 2008-10-29 12:35:42

这个目前还在初级学习中,先仔细的看看
谢谢楼主分享了

cnmyxk · 发表于 2008-10-29 10:19:05

支持一个,同时鄙视用了人家代码还这样加密那样加密的小偷.

victor888 · 发表于 2008-10-29 09:09:56

没有，我不研究PE，不想研究，怕钻进去出不来。

fnycc · 发表于 2008-10-29 09:07:32

版主的附件是否加入了WMI服务？

victor888 · 发表于 2008-10-29 08:20:11

又更新了，请测试吧。

victor888 · 发表于 2008-10-21 08:15:52

用QQ联系一下：511519860

云飞日月 · 发表于 2008-10-21 08:00:54

我自己在pe中试了一下，五个命令都有，但是U盘启动，依然是U盘在D盘，本地硬盘中的D盘以及以后，还是变成了E盘以及以后，运行这个命令，本地硬盘中的D盘还是E盘，就是U盘变了，每运行一次，都随机变一次，其他盘符没有变化
这是啥原因？

victor888 · 发表于 2008-10-21 06:39:59

其实就是一个路径的问题，你看看，那几个命令应该在那个BASIC.WIM里。

qusibago · 发表于 2008-10-20 20:49:08

原帖由 victor888 于 2008-10-20 15:00 发表
你把那个FIND命令也加上再试试。

跟find无关，有可能用到的其他文件也被小马放到了basic.wim里面了吧。

victor888 · 发表于 2008-10-20 15:00:39

你把那个FIND命令也加上再试试。

		自动登录	找回密码
密码			注册

[08年11月3日更新，再更新就是适用于VISTA下了]新版解决盘符错乱批处理

回复 #69 云飞日月的帖子

回复 #65 qusibago 的帖子

浏览过的版块

[08年11月3日更新，再更新就是适用于VISTA下了]新版解决盘符错乱批处理

回复 #69 云飞日月 的帖子

回复 #65 qusibago 的帖子

浏览过的版块

回复 #69 云飞日月的帖子