批处理获取目标系统IP地址

semiuel · 发表于 2020-2-3 16:11:11

经常碰到很多电脑出现系统损坏甚至硬盘损坏导致不能进系统，但系统内设置的IP地址是静态地址。
只要目标系统的注册表文件SOFTWARE和SYSTEM没损坏，就可以用这个批处理在PE里获取到目标系统的IP地址，只需要用到REG.EXE运行后会在批处理所在目录生成一个Ipinfo.txt保存相关信息。

@echo off 2>nul 3>nul
setlocal enabledelayedexpansion
set /p Input=输入要查询的系统安装盘符[例如D]：
if /i "%Input%:" neq "%systemDrive%" (
for %%a in (software system) do (
if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
)
reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
call :GetIPInfo Temp_HIV1 Temp_HIV2
reg unload HKLM\Temp_HIV1 >nul
reg unload HKLM\Temp_HIV2 >nul
) else call :GetIPInfo SOFTWARE SYSTEM
start "" "%~dp0IPInfo.txt" & exit/b
:GetIPInfo
for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
if /i "%%a" == "Default" set /a x=%%c
)
set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
set "v2=ControlSet00%x%\Control\Network"
set "v3=ControlSet00%x%\services\Tcpip\Parameters"
set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
set "v=%%a"
if "!v:%v1%\=!" neq "!v!" (
set /a n+=1
for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
if /i "%%b" == "ServiceName" (
set "Guid!n!=%%d"
) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
)
)
)
if not defined n echo,找不到网卡&pause & exit
(for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
if /i "%%a" == "Domain" (
if "%%c" neq "" (echo,域名名称：%%c)else echo,域名名称：^<nul^>
) else if /i "%%a" == "HostName" echo,主机名称：%%c
))>"%~dp0IPInfo.txt"
for %%a in (%s%) do set "_%%a=1"
(for /l %%a in (1 1 %n%) do (
echo,&echo,网卡名称：!NetCard%%a!
for %%b in (%s%) do set "%%b="
for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
if defined flag (
for /f "tokens=1,2*" %%c in ("%%b") do (
if /i "%%c" == "Name" echo,连接名称：%%e& set "flag="
)
) else (
set "v=%%b"
for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" set flag=1
)
)
for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
)
if /i "!EnableDHCP!" == "0x1" (
echo,IP 模式：动态获取
echo,IP 地址：!DHCPIPAddress!
echo,子网掩码：!DHCPSubnetMask!
echo,默认网关：!DHCPDefaultGateway!
echo,DNS 地址：!DHCPNameServer!
) else (
echo,IP 模式：静态设置
echo,IP 地址：!IPAddress!
echo,子网掩码：!SubnetMask!
echo,默认网关：!DefaultGateway!
echo,DNS 地址：!NameServer!
)
))>>"%~dp0IPInfo.txt"

复制代码

下载地址：

获取目标系统IP地址.zip (1.25 KB, 下载次数: 136)

idd214 · 发表于昨天 14:25

谢谢分享

qq952290709 · 发表于 2021-11-28 12:57:17

这么好用的工具怎么不更新了，再完善下最好了。目前获取不到虚拟机的网卡信息。

cybersempron · 发表于 2020-2-7 10:23:46

semiuel 发表于 2020-2-3 17:30
查了一圈百度，暂时没找到方法从目标系统的注册表获取网卡MAC地址。

高深的办法我就不懂了，我也只会用笨办法：1.找一个有网络功能的PE，启动目标电脑。2.在PE里启动网络功能后，用ipconfig /all命令获取MAC地址。

ybshfhllj · 发表于 2020-2-5 23:44:59

可以进pe的话随随便便就可以获取MAC地址了

窄口牛 · 发表于 2020-2-5 07:19:11

用带网络功能的pe去之前的机器不就知道mac地址了？
原贴链接

2010sya · 发表于 2020-2-5 00:40:19

我觉得如果系统盘拿到别的机器上，再查询目标系统的mac就没有多大意义了，因为mac地址一般是和网卡硬件对应的！
或者，你只要查询出当前机器的mac就可以了。

semiuel · 发表于 2020-2-4 23:34:55

2013lirunext 发表于 2020-2-4 13:22
有的，前阵子我因为要改网卡的MAC地址（Windows 7系统），简单研究过，两种方法来实现，一种是用厂家工具 ...

我在自己这台电脑的注册表里找不到网卡的MAC地址，百度也只能找到修改MAC地址的帖子。
相关的帖子我看了一些，都是添加一个MAC地址，而不是修改。

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E972-E325-11CE-BFC1-08002BE10318}

这个键值下面的0000-00xx里其中一项或几项对应网卡，但也没在里面找到MAC地址。

mimi820 · 发表于 2020-2-4 15:41:11

感谢分享

edit009 · 发表于 2020-2-4 15:23:31

有点意思，用这个条件得是PE带CMD吧？

2013lirunext · 发表于 2020-2-4 13:22:50

semiuel 发表于 2020-2-3 17:30
查了一圈百度，暂时没找到方法从目标系统的注册表获取网卡MAC地址。

有的，前阵子我因为要改网卡的MAC地址（Windows 7系统），简单研究过，两种方法来实现，一种是用厂家工具修改网卡硬件的MAC地址（修改后在任何系统或网卡拿到别的电脑都有效，也就是说这种方法影响到了硬件），一种是修改系统注册表（在别的系统/重装系统或网卡拿到别的电脑，MAC地址都会恢复出厂值，也就是说注册表的修改没有影响到网卡硬件）。注册表的话隐约记得是先找到“本地连接”对应的注册表，然后新建一个项，把这个项的值修改为要设置的MAC地址，注销或重启生效。由于是在台式机搞的，现在带笔记本回家了，资料一时找不到，等找到了再回复了。
要注意的是某些特殊情况，有的电脑可能有多个网卡，分别对应“本地连接1”、“本地连接2”、“本地连接3”，可能需要做些判断/处理，不然在有多个网卡的机器，就获取不到或者出现其它bug（个人猜测，说错勿怪）

semiuel · 发表于 2020-2-4 12:17:07

cybersempron 发表于 2020-2-3 23:51
从目标电脑获取MAC地址倒是好弄呀，无论你什么系统，系统安装100次，MAC地址也是一样的呀（假如只有一块网 ...

请大神帮忙理一下该怎么用批处理获取MAC地址
但纠正一点，是“目标系统”而不是“目标电脑”
也就是说可能是这样的情况：
一块包含系统的硬盘拿到不同的电脑上，获取到的MAC地址都应该是目标系统的那个MAC地址。

cybersempron · 发表于 2020-2-3 23:51:37

从目标电脑获取MAC地址倒是好弄呀，无论你什么系统，系统安装100次，MAC地址也是一样的呀（假如只有一块网卡），通俗说一句，MAC地址就是网卡地址呀，你系统怎么坏，只要网卡不坏，就可以轻易得到MAC地址呀，这个比获取静态IP容易多了。

ljmmjl · 发表于 2020-2-3 22:00:21

这个很有用，谢谢分享。

qq952290709 · 发表于 2020-2-3 18:48:23

这个是非常实用的工具，谢谢楼主分享！希望能继续更新完善！！

semiuel · 发表于 2020-2-3 17:30:53

查了一圈百度，暂时没找到方法从目标系统的注册表获取网卡MAC地址。

semiuel · 发表于 2020-2-3 17:22:12

都市浪子666 发表于 2020-2-3 17:01
ipconfig /all

ipconfig只能获取到本机网卡信息

2012andyle113 · 发表于 2020-2-3 17:14:51

感谢分享

2010pzhg · 发表于 2020-2-3 17:05:25

这个很有用，谢谢分享。

都市浪子666 · 发表于 2020-2-3 17:01:27

semiuel 发表于 2020-2-3 16:47
大神们帮忙研究一下看批处理怎么获取网卡MAC地址，然后添加到批处理里面。
首先，要尽量少用外部命令，适 ...

ipconfig /all

semiuel · 发表于 2020-2-3 16:47:51

本帖最后由 semiuel 于 2020-2-3 17:00 编辑

大神们帮忙研究一下看批处理怎么获取网卡MAC地址，然后添加到批处理里面。
首先，要尽量少用外部命令，适应跟版本的PE；
第二，要从目标系统的注册表获取，而不是从本机获取
第三，要考虑到多网卡

心零 · 发表于 2020-2-3 16:46:12

本帖最后由心零于 2020-2-3 16:48 编辑

wych12 发表于 2020-2-3 16:42
如何加，恳请老师指点下！谢谢！！！

我是菜鸟！！
百度搜索：获取MAC地址

brettwand · 发表于 2020-2-3 16:43:32

不是很明白，跟着你们学习了。

wych12 · 发表于 2020-2-3 16:42:18

心零发表于 2020-2-3 16:31
还得加上获取MAC，碰到过内网静态IP+MAC绑定上网的。

更恐怖的是还有部分老企业有IE的用局域网LAN设置。 ...

如何加，恳请老师指点下！谢谢！！！

心零 · 发表于 2020-2-3 16:31:08

还得加上获取MAC，碰到过内网静态IP+MAC绑定上网的。

更恐怖的是还有部分老企业有IE的用局域网LAN设置。

不过这种情况几年都碰不上1例。

		自动登录	找回密码
密码			注册

[分享] 批处理获取目标系统IP地址

点评

点评

点评

点评

点评

点评

点评