请大神写个批处理，1判断系统版本，2根据系统版本安装离线.net

享β亻寸木东 · 发表于 2022-5-8 10:30:38

本帖最后由享β亻寸木东于 2022-5-8 21:20 编辑

半吊子技术员小白一枚（白里透红）
请大神写个批处理，1判断系统版本，2根据系统版本安装离线.net

想解决的问题：很多系统未启用.net3.5，让批处理自动安装对应版本（1776*、1836*、1904*、2200*）的.net3.5
1判断系统版本比如“Microsoft Windows [版本 10.0.19044.1645]”
2根据系统版本安装离线.net3.5
执行：dism.exe /online /enable-feature /featurename:netfx3 /Source:C:\1904 备注（C:\1904文件夹里是离线net.3.5）
如果是22000执行：dism.exe /online /enable-feature /featurename:netfx3 /Source:C:\2200

万分谢谢

能运行了，一点都不谨慎，不完美，先凑合凑合

@ECHO off

::系统版本号判断
for /f "tokens=2 delims=[]" %%Q in ('ver') do for /f "tokens=2-4 delims=. " %%R in ("%%Q") do set "ver=%%R%%S"&set "verbuild=%%T"

if %verbuild% EQU 17763 goto 1776X

if %verbuild% EQU 18362 goto 1836X
if %verbuild% EQU 18363 goto 1836X

if %verbuild% EQU 19042 goto 1904X
if %verbuild% EQU 19043 goto 1904X
if %verbuild% EQU 19044 goto 1904X

if %verbuild% EQU 22000 goto 2200X

:1776X
set BB=1776X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:1836X
set BB=1836X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:1904X
set BB=1904X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:2200X
set BB=2200X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit

nttwqz · 发表于 2022-5-8 10:30:39

如果确有必要区分的话

::系统版本号判断
for /f "tokens=2 delims=[]" %%Q in ('ver') do for /f "tokens=2-4 delims=. " %%R in ("%%Q") do set "ver=%%R%%S"&set "verbuild=%%T"
::获取显示版本名称，例如21H2、20H2、1909、1903等
for /f "skip=2 tokens=3" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "DisplayVersion"') do set "displayversion=%%a"
::区分Win10、Win11
if %ver%==100 (
if %verbuild% lss 22000 (
set ab=10
) else (
set ab=11
)
)
::启用NetFx3，sxs版本自动适配，sxs文件夹命名方法：sxs\11\22H1、sxs\10\21H2、sxs\10\1909
if exist "%~dp0\sxs\%ab%\%displayversion%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~dp0\sxs\%ab%\%displayversion%"

复制代码

chishingchan · 发表于 2022-5-8 10:39:09

本帖最后由 chishingchan 于 2022-5-8 13:44 编辑

@echo off
rem 以下行返回：版本 10.0.22000.434
for /f "tokens=2 delims=[]" %%i in ('ver') do @set FullVer=%%i
:: 测试用！set FullVer=版本 10.0.22000.434
rem 以下行返回：10
for /f "tokens=2 delims=. " %%i in ('echo %FullVer%') do @set SVer=%%i
rem 以下行返回：22000
for /f "tokens=4 delims=. " %%i in ('echo %FullVer%') do @set MVer=%%i
:: echo %FullVer%
:: echo %SVer%
:: echo %MVer%
if %SVer% NEQ 10 goto Error1
if %MVer% EQU 22000 goto OK1
:: .
:: .
:: .
:OK1
echo 子版本号是 22000
goto 2200
goto End
:2200
echo 执行程序
goto End
:Error1
echo 本批处理不支持 Windows 10 以下系统！
:: .
:: .
:: .
:End
pause

复制代码

826773297 · 发表于 2022-5-8 10:44:26

pecmd不行吗

享β亻寸木东 · 发表于 2022-5-8 11:00:13

826773297 发表于 2022-5-8 10:44
pecmd不行吗

尽量用批处理CMD吧

享β亻寸木东 · 发表于 2022-5-8 11:18:28

nttwqz 发表于 2022-5-8 11:11
楼主是否用于SetupComplete.cmd，我这里有现成的。

谢谢我找桌面环境下的

nttwqz · 发表于 2022-5-8 11:25:26

享β亻寸木东发表于 2022-5-8 11:18
谢谢我找桌面环境下的

唉，看来你一点儿不会儿，稍微编辑一下不就好了。

::获取显示版本名称，例如21H2、20H2、1909、1903等
for /f "skip=2 tokens=3" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "DisplayVersion"') do set "displayversion=%%a"
::启用NetFx3，sxs版本自动适配，sxs文件夹命名方法：sxs\21H2、sxs\1909
if exist "%~dp0\sxs\%displayversion%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~dp0\sxs\%displayversion%"

复制代码

享β亻寸木东 · 发表于 2022-5-8 11:32:15

nttwqz 发表于 2022-5-8 11:25
唉，看来你一点儿不会儿，稍微编辑一下不就好了。

哦谢谢那win11的21H2怎么识别？

whitesneike · 发表于 2022-5-8 11:36:21

감사해요

nttwqz · 发表于 2022-5-8 11:42:31

本帖最后由 nttwqz 于 2022-5-8 11:46 编辑

享β亻寸木东发表于 2022-5-8 11:32
哦谢谢那win11的21H2怎么识别？

就目前来说，不需要识别。

你可能没有对比过，目前最新版10和11的sxs文件夹是一样的文件。。。
也正是因为这样，后来放弃了这种方法，因为一般都是安装最新版Win10，所以只需在无人值守文件中集成最新版的sxs文件夹就好，不需要再判断。一般电脑都是联网的，需要的时候会提示，离线不离线启用已经不在重要，除非内网或者单机。

nttwqz · 发表于 2022-5-8 12:18:54

可以根据需要将下面的代码放在::启用NetFx3，sxs版本自动适配，sxs文件夹命名方法：sxs\11\22H1、sxs\10\21H2、sxs\10\1909前面

::假设Win10和Win11的23H2 23H1 22H2 22H1 21H2的sxs文件相同，强制指定替代，避免存放一堆相同的文件造成空间浪费
::此处仅举例，请自行测试哪些版本通用情况，已知目前10和11通用，觉得费劲可以放一堆版本。
for %%a in (23H2 23H1 22H2 22H1 21H2) do if /i "%displayversion%"=="%%a" (
set ab=10
set displayversion=21H2
)

复制代码

享β亻寸木东 · 发表于 2022-5-8 13:58:18

nttwqz 发表于 2022-5-8 12:18
可以根据需要将下面的代码放在::启用NetFx3，sxs版本自动适配，sxs文件夹命名方法：sxs\11\22H1、sxs\10\21 ...

非常感谢！抽空捣鼓捣鼓

享β亻寸木东 · 发表于 2022-5-8 14:04:11

本帖最后由享β亻寸木东于 2022-5-8 14:42 编辑

chishingchan 发表于 2022-5-8 10:39

谢谢，我研究研究！不太懂，不会用

断桥烟雨 · 发表于 2022-5-8 14:08:17

我研究研究！

zxwei · 发表于 2022-5-8 18:52:53

帮顶起来

邪恶海盗 · 发表于 2022-5-8 20:52:25

我觉得撸主可以试试我的SWAI v2.1...

断桥烟雨 · 发表于 2022-5-8 21:06:13

帮顶起来

享β亻寸木东 · 发表于 2022-5-8 21:12:21

邪恶海盗发表于 2022-5-8 20:52
我觉得撸主可以试试我的SWAI v2.1...

感谢您的回复.感谢您的回复.

享β亻寸木东 · 发表于 2022-5-8 21:12:33

断桥烟雨发表于 2022-5-8 21:06
帮顶起来

感谢您的回复.感谢您的回复.

享β亻寸木东 · 发表于 2022-5-8 21:14:10

nttwqz 发表于 2022-5-8 12:02
如果确有必要区分的话

用了这个，加上胡拼乱凑，反正能运行了，谢谢！

nttwqz · 发表于 2022-5-8 21:42:35

本帖最后由 nttwqz 于 2022-5-8 21:44 编辑

享β亻寸木东发表于 2022-5-8 21:14
用了这个，加上胡拼乱凑，反正能运行了，谢谢！

画蛇添足了。。。

if %verbuild% EQU 17763 goto 1776X
if %verbuild% EQU 18362 goto 1836X
if %verbuild% EQU 18363 goto 1836X
if %verbuild% EQU 19042 goto 1904X
if %verbuild% EQU 19043 goto 1904X
if %verbuild% EQU 19044 goto 1904X
if %verbuild% EQU 22000 goto 2200X
:1776X
set BB=1776X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:1836X
set BB=1836X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:1904X
set BB=1904X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit
:2200X
set BB=2200X
::启用NetFx3
if exist "%~d0\.NTE\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NTE\%BB%"
exit

复制代码

改成

for %%a in (17763 18362 18363 19042 19043 19044 22000) do if %verbuild% equ %%a set bb=%verbuild:~0,-1%X
::启用NetFx3
if exist "%~d0\.NET\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NET\%BB%"
exit

复制代码

如果你能确认除了最后一位前面版本相同能通用的话（我记得10 19044 和11的22000一样）

set bb=%verbuild:~0,-1%X
::启用NetFx3
if exist "%~d0\.NET\%BB%\*.*" dism /online /enable-feature /featurename:netfx3 /source:"%~d0\.NET\%BB%"
exit

复制代码

另外，通过set定义的变量不分大小写，所以BB=bb

享β亻寸木东 · 发表于 2022-5-9 08:19:41

本帖最后由享β亻寸木东于 2022-5-9 08:44 编辑

nttwqz 发表于 2022-5-8 21:42
画蛇添足了。。。

谢谢！！！通用

享β亻寸木东 · 发表于 2022-5-25 11:21:40

nttwqz 发表于 2022-5-8 21:42
画蛇添足了。。。

你好方便再发一下你的SetupComplete.cmd那个批处理吗？

nttwqz · 发表于 2022-5-26 21:00:01

享β亻寸木东发表于 2022-5-25 11:21
你好方便再发一下你的SetupComplete.cmd那个批处理吗？

SetupComplete.7z (48.29 KB, 下载次数: 57)

享β亻寸木东 · 发表于 2022-5-26 21:06:30

nttwqz 发表于 2022-5-26 21:00

非常谢谢-------

kaximoduo200 · 发表于 2022-6-28 19:22:03

试一下！！！！！！！！1

szwp · 发表于 2025-7-4 13:41:14

后面写得太重复了

		自动登录	找回密码
密码			注册

[求助] 请大神写个批处理，1判断系统版本，2根据系统版本安装离线.net

最佳答案

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

浏览过的版块