[更新376#2825]PECMD2012.1.80.13_Win32_64.多窗口多线程.裸机系统2.3.3.1+18M酷M...

mdyblog

527104427 发表于 2022-4-23 13:24
m大不如举个例子吧，我看他跟我一样，是个编程小白，啥也不懂的。

我就是随口一说，m大不必 ...

CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  ///chx1=1040 以只读方式打开(&R)
下面
CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%IDOK%
这样会的获得 打开按钮的 句柄w
可以移动
ENVI @@POS=%w%:X:y:W:H
ENVI @@POS=%w%:250


CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%IDCANCEL%
为 取消 按钮
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%IDOK%
            ENVI @@POS=%w%:250:
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%IDCANCEL%
            ENVI @@POS=%w%:250:
效果：

527104427

Anson4 发表于 2022-4-23 12:10
M大辛苦了，感谢更新！
我测试了一下，想提几点建议，M大看看能不能优化一下：
1. 增加调整窗口大小的 ...

调整了下布局，默认弹出到屏幕中间，你看看这样满意吗



还有，强迫症受不了这个白边，顺便也处理了一下





//authored by mdyblog@163.com
@IFEX %&CurFile%.LOG, LOGS * %&CurFile%.LOG
@TEAM ENVI^ EnviMode=1| ENVI^ ForceLocal=1
//SET &RetBrow=0
//SET< RetBrow=\XXX
//MESS. RetBrow[%RetBrow%]

SET$ &NL=0d 0a
SET$ &NLd=0d
SET$ &NLa=0a
SET$ TAB=09

IFEX #%&bX64%=3, SET &PTR_LEN=8!  SET &PTR_LEN=4
IFEX #%&bX64%=3, SET &SetWindowLongPtrW=SetWindowLongPtrW! SET &SetWindowLongPtrW=SetWindowLongW
SET &cmb1=1136
SET &cmb13=1148
SET &stc2=1089
SET &stc3=1090
SET &chx1=1040
SET &IDOK=1
SET &IDCANCEL=2
CALC -base=16 #&&CDN_INITDONE=0 - 601 - 0x0000
CALC -base=16 #&&CDM_GETFOLDERPATH=0x0400 + 100 + 0x0002

SET &SW_HIDE=0x0
CALC #&&WM_NOTIFY=0x004E
CALC #&&WM_COMMAND=0x0111
SET &WM_INITDIALOG=0x0110
CALC -base=16 #&&GWLP_WNDPROC=-4

SET &BorwOriWndProc=0
SET &RetBrow.flg=0
SET &RetBrow=

ENVI^ WndProc1,&&WndProc1Adr
ENVI^ WndProc2,&&WndProc2Adr


_SUB OnWndProc1  //hdlg uiMsg wParm lParam
    @TEAM SET &hdlg=%~1| SET &uiMsg=%~2| SET &wParam=%~3| SET &lParam=%~4
        IFEX #[ %uiMsg%=%WM_INITDIALOG% & %hdlg%<>0 & %RetBrow.flg%=0 ],
        {        SET$ &wcsClassName1=*2048 0
                SET$ &wcsClassName2=*2048 0
        CALL $--ret:&&hParent user32.dll,GetParent,#%hdlg%
        CALL $--ret:&&n1 --qd user32.dll,GetClassNameW,#%hParent%,*wcsClassName1,#2047
        CALL $--ret:&&n2 --qd user32.dll,GetClassNameW,#%hdlg%,*wcsClassName2,#2047
                FIND $%wcsClassName1% = %wcsClassName2%,
        {        SET RetBrow.flg=0x1
            ^CALL $--ret:&BorwOriWndProc --qd user32.dll,%SetWindowLongPtrW%,#%hParent%,#%GWLP_WNDPROC%,#%WndProc2Adr%
                }
        }
    //HWND hwndFrom;UINT_PTR idFrom;UINT code;
        IFEX #%uiMsg%=%WM_NOTIFY%,
    {        ENVI?ints %lParam%=&&pnmh_code:(%PTR_LEN% * 2)    //LPNMHDR-->code
                IFEX #%CDN_INITDONE%=%pnmh_code%,
                {        CALL $--ret:&hParent user32.dll,GetParent,#%hdlg%
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%cmb1%
            CALL $--ret:&&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //cmb1=1136 文件类型
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%cmb13%
            CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //cmb13=1148 文件名
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%stc3%
            CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //stc3=1090 文件名标签
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%stc2%
            CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //stc2=1089 文件类型标签
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%chx1%
            CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  ///chx1=1040 以只读方式打开(&R)

           //以下重新布局

            CALL $--ret:&&w1 user32.dll,GetDlgItem,#%hParent%,#%IDCANCEL%
            ENVI @@POS=?%&&w1%:&&left1::&&wide1:&&high1

            CALL $--ret:&&w2 user32.dll,GetDlgItem,#%hParent%,#1120   //listbox
            ENVI @@POS=?%&&w2%::&&top2::&&high2

            ENVI @@POS=%&&w1%:(%&&left1%-20):(%&&top2%+%&&high2%+20)  //移动“取消按钮”

            CALL $--ret:&&w3 user32.dll,GetDlgItem,#%hParent%,#%IDOK%
            ENVI @@POS=%&&w3%:(%&&left1%-%&&wide1%-20-10):(%&&top2%+%&&high2%+20)  //移动“确定按钮”

            SCRN -win &&wide4,&&high4
            ENVI @@POS=?%hParent%:::&&wide5:&&high5
            ENVI @@POS=%hParent%:((%&&wide4%-%&&wide5%)/2):((%&&high4%-%&&high5%)/2)::(%&&top2%+%&&high2%+20+%&&high1%+45)   //调整主窗口高度、坐标

            CALL $--ret:&&w6 user32.dll,GetDlgItem,#%hParent%,#1091   //“查找范围”标签
            ENVI @@POS=?%&&w6%:&&left6::&&wide6:&&high6
            ENVI @@POS=%&&w6%:(%&&left6%+14)::(%&&wide6%-14):(%&&high6%-2)   //调整“查找范围”标签宽、高、坐标

           //以上重新布局

                }
        }
        EXIT= 0
_END

_SUB OnWndProc2  //hWnd uiMsg wParm lParam
    @TEAM SET &hWnd=%~1| SET &uiMsg=%~2| SET &wParam=%~3| SET &lParam=%~4
        IFEX #[ %uiMsg%=%WM_COMMAND% & %wParam%=%IDOK% ],
    {
        SET RetBrow.flg=0x00
        SET$ RetBrow=*8192 0 0
        CALL $--ret:&&w user32.dll,GetDlgItem,#%hwnd%,#%cmb13%
        SET$ &&V=*8192 0
        CALL $--qd --ret:&&ok user32.dll,GetWindowTextW,#%w%,*&V,#8191
        ENVI @@SENDMSG=%hwnd%:%CDM_GETFOLDERPATH%;8191;@RetBrow
        SED -ex &&i=?1,[\*\?],,&V
        IFEX [ '%RetBrow%'<>'' && '%V%'<>'' & #%i%<1 &  %RetBrow%\%&&V% ], SET RetBrow=%RetBrow%\%&&V%
        CALL $--qd --ret:&&ret user32.dll,%SetWindowLongPtrW%,#%hwnd%,#%GWLP_WNDPROC%,#%BorwOriWndProc%
        ENVI @@SENDMSG=%hwnd%:%uiMsg%;%IDCANCEL%;%lParam%
        EXIT= 0
        EXIT _SUB
    }
        IFEX #[ %uiMsg%=%WM_COMMAND% & %wParam%=%IDCANCEL% ],
    {
        SET RetBrow.flg=0x00
        CALL $--qd --ret:&&ret user32.dll,%SetWindowLongPtrW%,#%hwnd%,#%GWLP_WNDPROC%,#%BorwOriWndProc%
        ENVI @@SENDMSG=%hwnd%:%uiMsg%;%IDCANCEL%;%lParam%
        //EXIT= %IDCANCEL%
        EXIT _SUB
    }
    CALL $#,%BorwOriWndProc%,#%1,#%2,#%3,#%4
        EXIT= 0
_END

//带上 ;RetBrow.flg， 自动初始化标志RetBrow.flg
//只选择目录 注意带引号  注意 *..*   0x80000
BROW RetBrow;RetBrow.flg,"%WinDir%\*..*",请选择一个文件夹一保存驱动程序,,0x81000,%WndProc1Adr%
MESS. [%RetBrow%]


//选择文件和目录  注意带引号 0x80000
BROW RetBrow;RetBrow.flg,"%WinDir%\*.*",请选择一个文件夹或文件,,0x81000,%WndProc1Adr%
MESS. [%RetBrow%]

mdyblog

527104427 发表于 2022-4-23 18:45
调整了下布局，默认弹出到屏幕中间，你看看这样满意吗

挺好的！！！！

527104427

mdyblog 发表于 2022-4-23 20:24
挺好的！！！！

哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！






//authored by mdyblog@163.com
@IFEX %&CurFile%.LOG, LOGS * %&CurFile%.LOG
@TEAM ENVI^ EnviMode=1| ENVI^ ForceLocal=1
//SET &RetBrow=0
//SET< RetBrow=\XXX
//MESS. RetBrow[%RetBrow%]

SET$ &NL=0d 0a
SET$ &NLd=0d
SET$ &NLa=0a
SET$ TAB=09

IFEX #%&bX64%=3, SET &PTR_LEN=8!  SET &PTR_LEN=4
IFEX #%&bX64%=3, SET &SetWindowLongPtrW=SetWindowLongPtrW! SET &SetWindowLongPtrW=SetWindowLongW
SET &cmb1=1136
SET &cmb13=1148
SET &stc2=1089
SET &stc3=1090
SET &chx1=1040
SET &IDOK=1
SET &IDCANCEL=2
CALC -base=16 #&&CDN_INITDONE=0 - 601 - 0x0000
CALC -base=16 #&&CDM_GETFOLDERPATH=0x0400 + 100 + 0x0002

SET &SW_HIDE=0x0
CALC #&&WM_NOTIFY=0x004E
CALC #&&WM_COMMAND=0x0111
SET &WM_INITDIALOG=0x0110
CALC -base=16 #&&GWLP_WNDPROC=-4

SET &BorwOriWndProc=0
SET &RetBrow.flg=0
SET &RetBrow=

ENVI^ WndProc1,&&WndProc1Adr
ENVI^ WndProc2,&&WndProc2Adr


_SUB OnWndProc1  //hdlg uiMsg wParm lParam
    @TEAM SET &hdlg=%~1| SET &uiMsg=%~2| SET &wParam=%~3| SET &lParam=%~4
        IFEX #[ %uiMsg%=%WM_INITDIALOG% & %hdlg%<>0 & %RetBrow.flg%=0 ],
        {        SET$ &wcsClassName1=*2048 0
                SET$ &wcsClassName2=*2048 0
        CALL $--ret:&&hParent user32.dll,GetParent,#%hdlg%
        CALL $--ret:&&n1 --qd user32.dll,GetClassNameW,#%hParent%,*wcsClassName1,#2047
        CALL $--ret:&&n2 --qd user32.dll,GetClassNameW,#%hdlg%,*wcsClassName2,#2047
                FIND $%wcsClassName1% = %wcsClassName2%,
        {        SET RetBrow.flg=0x1
            ^CALL $--ret:&BorwOriWndProc --qd user32.dll,%SetWindowLongPtrW%,#%hParent%,#%GWLP_WNDPROC%,#%WndProc2Adr%
                }
        }
    //HWND hwndFrom;UINT_PTR idFrom;UINT code;
        IFEX #%uiMsg%=%WM_NOTIFY%,
    {        ENVI?ints %lParam%=&&pnmh_code:(%PTR_LEN% * 2)    //LPNMHDR-->code
                IFEX #%CDN_INITDONE%=%pnmh_code%,
                {        CALL $--ret:&hParent user32.dll,GetParent,#%hdlg%
            //CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%cmb1%
            //CALL $--ret:&&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //cmb1=1136 文件类型
            //CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%cmb13%
            //CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //cmb13=1148 文件名
            //CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%stc3%
            //CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //stc3=1090 文件名标签
            //CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%stc2%
            //CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  //stc2=1089 文件类型标签
            CALL $--ret:&w user32.dll,GetDlgItem,#%hParent%,#%chx1%
            CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  ///chx1=1040 以只读方式打开(&R)

           //以下重新布局

            CALL $--ret:&&w1 user32.dll,GetDlgItem,#%hParent%,#%IDCANCEL%
            ENVI @@POS=?%&&w1%:@:&&top1::&&high1

            SCRN -win &&wide2,&&high2
            ENVI @@POS=?%hParent%:::&&wide3:&&high3
            ENVI @@POS=%hParent%:((%&&wide2%-%&&wide3%)/2):((%&&high2%-%&&high3%)/2):@:(%&&top1%+%&&high1%+15)   //调整主窗口高度、坐标

            CALL $--ret:&&w4 user32.dll,GetDlgItem,#%hParent%,#1091   //“查找范围”标签
            ENVI @@POS=?%&&w4%:&&left4:&&top4:&&wide4:&&high4
            ENVI @@POS=%&&w4%:(%&&left4%+14)::(%&&wide4%-14):(%&&high4%-2)   //调整“查找范围”标签宽、高、坐标

            CALL $--ret:&&w5 user32.dll,GetDlgItem,#%hParent%,#%stc2%   //“文件类型”标签
            ENVI @@POS=?%&&w5%:&&left5:&&top5:&&wide5:&&high5
            ENVI @@POS=%&&w5%:(%&&left5%+15)::(%&&wide5%-15):(%&&high5%-2)   //调整“文件类型”标签宽、高、坐标

            CALL $--ret:&&w6 user32.dll,GetDlgItem,#%hParent%,#%stc3%   //“文件名”标签
            ENVI @@POS=?%&&w6%:&&left6:&&top6:&&wide6:&&high6
            ENVI @@POS=%&&w6%:(%&&left6%+27)::(%&&wide6%-27):(%&&high6%-2)   //调整“文件名”标签宽、高、坐标

           //以上重新布局

                }
        }
        EXIT= 0
_END

_SUB OnWndProc2  //hWnd uiMsg wParm lParam
    @TEAM SET &hWnd=%~1| SET &uiMsg=%~2| SET &wParam=%~3| SET &lParam=%~4
        IFEX #[ %uiMsg%=%WM_COMMAND% & %wParam%=%IDOK% ],
    {
        SET RetBrow.flg=0x00
        SET$ RetBrow=*8192 0 0
        CALL $--ret:&&w user32.dll,GetDlgItem,#%hwnd%,#%cmb13%
        SET$ &&V=*8192 0
        CALL $--qd --ret:&&ok user32.dll,GetWindowTextW,#%w%,*&V,#8191
        ENVI @@SENDMSG=%hwnd%:%CDM_GETFOLDERPATH%;8191;@RetBrow
        SED -ex &&i=?1,[\*\?],,&V
        IFEX [ '%RetBrow%'<>'' && '%V%'<>'' & #%i%<1 &  %RetBrow%\%&&V% ], SET RetBrow=%RetBrow%\%&&V%
        CALL $--qd --ret:&&ret user32.dll,%SetWindowLongPtrW%,#%hwnd%,#%GWLP_WNDPROC%,#%BorwOriWndProc%
        ENVI @@SENDMSG=%hwnd%:%uiMsg%;%IDCANCEL%;%lParam%
        EXIT= 0
        EXIT _SUB
    }
        IFEX #[ %uiMsg%=%WM_COMMAND% & %wParam%=%IDCANCEL% ],
    {
        SET RetBrow.flg=0x00
        CALL $--qd --ret:&&ret user32.dll,%SetWindowLongPtrW%,#%hwnd%,#%GWLP_WNDPROC%,#%BorwOriWndProc%
        ENVI @@SENDMSG=%hwnd%:%uiMsg%;%IDCANCEL%;%lParam%
        //EXIT= %IDCANCEL%
        EXIT _SUB
    }
    CALL $#,%BorwOriWndProc%,#%1,#%2,#%3,#%4
        EXIT= 0
_END

//带上 ;RetBrow.flg， 自动初始化标志RetBrow.flg
//只选择目录 注意带引号  注意 *..*   0x80000
BROW RetBrow;RetBrow.flg,"%WinDir%\*..*",请选择一个文件夹一保存驱动程序,,0x81000,%WndProc1Adr%
MESS. [%RetBrow%]


//选择文件和目录  注意带引号 0x80000
BROW RetBrow;RetBrow.flg,"%WinDir%\*.*",请选择一个文件夹或文件,,0x81000,%WndProc1Adr%
MESS. [%RetBrow%]

红毛樱木

527104427 发表于 2022-4-23 22:02
哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！

哦吼，看的我一脸懵逼，这是干啥呢，这是赤裸裸的装B呀，先点赞再学习。

Anson4

527104427 发表于 2022-4-23 22:02
哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！

我正想着怎么获取那个 listbox 的参数，将它的高度宽度增大，真是想什么来什么，感谢5大！
在英文系统环境下，那个白框还是存在：

Anson4

mdyblog 发表于 2022-4-23 14:00
CALL $--ret:&ret user32.dll,ShowWindow,#%w%,#%SW_HIDE%  ///chx1=1040 以只读方式打开(&R)
下面
CAL ...

实际测试中，我发现还有一个隐藏的问题：界面和字体没有跟随系统DPI（在环境150%DPI的情况下，字体比系统字体小）。
同时，我想到了另一个问题：在选择文件夹和文件的模式下，本增强的BROW命令与旧版的BROW命令，能不能允许指定文件类型？

mdyblog

Anson4 发表于 2022-4-24 01:00
实际测试中，我发现还有一个隐藏的问题：界面和字体没有跟随系统DPI（在环境150%DPI的情况下，字体比系统 ...

文件类型选择 和原来一样
如 *.EXE和*.DLL
//选择文件和目录  注意带引号 0x80000
BROW RetBrow;RetBrow.flg,"%WinDir%\*.EXE;*.DLL",请选择一个文件夹或文件,,0x81000,%WndProc1Adr%
MESS. [%RetBrow%]

mdyblog

527104427 发表于 2022-4-23 22:02
哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！

好！！！！！！

Anson4

mdyblog 发表于 2022-4-24 01:56
文件类型选择 和原来一样
如 *.EXE和*.DLL
//选择文件和目录  注意带引号 0x80000

明白了，谢谢！同时看帮助发现了 0x881000 就是窗口可调大小^_^

原来的用法指定文件类型无效，是不是我写错了呢？
BROW &FF,*"%WinDir%\*.reg",请选择一个文件夹或文件,,0x4000

Anson4

527104427 发表于 2022-4-23 22:02
哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！

可是，此时 文件名编辑框 和 文件类型选择框 好像不起作用。

mdyblog

泮安宁 发表于 2022-4-21 21:58
https://software.download.prss.microsoft.com/sg/Win11_Chinese(Simplified)_x64v1.iso?t=38d25d99-56bc- ...

这个ISO安装了后，（未激活）
什么配置都没改。就默认的设置。没手动安装驱动。
效果：

mdyblog

泮安宁 发表于 2022-4-21 10:48
我这里是dpi的原因，自定义dpi就不模糊了

Win7X64 正常系统， 手动 改 配置， DPI缩放改为 125%。
效果：

mdyblog

826773297 发表于 2022-4-21 10:51
就是说系统dpi是125，pecmd也要设置成125就不模糊吗

WIn7X64 手动设为DPI缩放 125%
记事本显示也一样。不同字体，效果不一样。
9#字体效果 （PECMD为9#）


改为  7#效果： （五号也好， 小四号就非常漂亮）




小四号非常漂亮:

Anson4

527104427 发表于 2022-4-23 18:45
调整了下布局，默认弹出到屏幕中间，你看看这样满意吗

5大，我发现用 0x881000，就可以调整窗口大小，而且下次打开会在上次的位置以上次的大小显示。

826773297

mdyblog 发表于 2022-4-24 03:03
这个ISO安装了后，（未激活）
什么配置都没改。就默认的设置。没手动安装驱动。
效果：

pecmd建一个任务栏图标右键菜单，对比一下其他右键的字体比较明显

826773297

mdyblog 发表于 2022-4-24 03:57
WIn7X64 手动设为DPI缩放 125%
记事本显示也一样。不同字体，效果不一样。
9#字体效果 （PECMD为9#）

pecmd的字好像不自然加粗了一样，粗得有点模糊

826773297

mdyblog 发表于 2022-4-24 03:57
WIn7X64 手动设为DPI缩放 125%
记事本显示也一样。不同字体，效果不一样。
9#字体效果 （PECMD为9#）

win7的字体是宋体，现在的10或11都是雅黑了，可能没有做字体这方面的优化，而且dpi设置后pecmd字体的缩放有点不正常

mdyblog

Anson4 发表于 2022-4-24 07:14
5大，我发现用 0x881000，就可以调整窗口大小，而且下次打开会在上次的位置以上次的大小显示。

好！！！！

mdyblog

527104427 发表于 2022-4-23 22:02
哈哈，原来是这么玩的，终于把文件名编辑框搞出来了！

第二个函数最后，返回真是的动态结果，改为
    CALL $--ret:&&r #,%BorwOriWndProc%,#%1,#%2,#%3,#%4
    EXIT= %&r%

加了  类型控制变量RetBrow.tp，
0：仅目录
1：支持文件
3：支持文件和类型选择
BrowDirX.wcs.zip (2.05 KB, 下载次数: 11)

2022-4-24 09:52 上传

点击文件名下载附件

效果：

826773297

mdyblog 发表于 2022-4-24 09:52
第二个函数最后，返回真是的动态结果，改为
    CALL $--ret:&&r #,%BorwOriWndProc%,#%1,#%2,#%3,#%4
...

对了，透明标签设置成雅黑字体，_sub加入：类型的透明窗体，标签字体明明是黑色的，但是字体左侧会发白，不知道为什么，我在11系统下测试的

泮安宁

mdyblog 发表于 2022-4-24 03:03
这个ISO安装了后，（未激活）
什么配置都没改。就默认的设置。没手动安装驱动。
效果：

对比一下就感觉不清楚了

泮安宁

mdyblog 发表于 2022-4-24 03:57
WIn7X64 手动设为DPI缩放 125%
记事本显示也一样。不同字体，效果不一样。
9#字体效果 （PECMD为9#）

小四号确实非常漂亮，这个字体字号怎么改的

826773297

泮安宁 发表于 2022-4-24 11:04
小四号确实非常漂亮，这个字体字号怎么改的

那个是记事本，不是pecmd

826773297

泮安宁 发表于 2022-4-24 11:04
小四号确实非常漂亮，这个字体字号怎么改的

其他软件正常，pecmd字体比较糊

泮安宁

826773297 发表于 2022-4-24 11:09
那个是记事本，不是pecmd

额...我以为改的PECMD的字体

mdyblog

826773297 发表于 2022-4-24 09:43
pecmd建一个任务栏图标右键菜单，对比一下其他右键的字体比较明显

这个完全有选择的字体完全决定的。
选择 什么 字体， 就是什么效果。
WIn11 右键 明显和PECMD-HELP的字体不同。如果选择的 字体一样， 效果一样。 PECMD-HELP用的宋体，字号 也小写， 看起来比较刚，比较实。
PECMD-HELP 界面 也不只一种字体， 帮助文本一种字体，比较实， 外面又是另一种字体。
帮助文本 字体 特选的， 这样默认情况下， 表格 比较 齐整。 其它地方，要求么那么 严格。

826773297

mdyblog 发表于 2022-4-24 11:15
这个完全有选择的字体完全决定的。
选择 什么 字体， 就是什么效果。
WIn11 右键 明显和PECMD-HELP的字 ...

我是说任务栏托盘右键菜单字体，和其他软件托盘右键菜单字体对比，使用的应该都是系统字体吧

mdyblog

826773297 发表于 2022-4-24 11:17
我是说任务栏托盘右键菜单字体，和其他软件托盘右键菜单字体对比，使用的应该都是系统字体吧

什么 “说任务栏托盘右键菜单字体”？  上图吧。  不说清楚，太浪费精力。

简单来说， 效果有字体完全决定。
反之， 效果不同， 字体一定选的不同。

826773297

mdyblog 发表于 2022-4-24 11:19
什么 “说任务栏托盘右键菜单字体”？  上图吧。  不说清楚，太浪费精力。

简单来说， 效果有字体完全 ...

就是MENU命令产生的托盘菜单字体，和别的软件托盘右键字体模糊感区别比较明显，窗体内字体也模糊，回去后截图上来看下