就是说系统进不了，可是想知道本地IP及网关、DNS

pznpt

P处理 获取网卡名称及IP信息.bat
考虑到在WinPE中运行，但PE精简程度不一样，除reg.exe外，未使用其它外部命令
也可以在正常系统中运行，查看其它系统安装分区的IP信息，或本系统IP信息
2014-9-1
改正按F8进入“最后一次正确配置”后，注册表项HKLM\SYSTEM\ControlSet001不存在而无法运行的问题；
增加获取Domain名称和HostName名称；
将结果保存到脚本所在目录下IPInfo.txt文本中，而不是打印到屏幕

2014-6-4
修正了在xp上获取的DNS地址可能出现多余的\0字符

1. @echo off 2>nul 3>nul
   
2. setlocal enabledelayedexpansion
   
3. set /p Input=输入要查询的系统安装盘符[例如D]：
   
4. if /i "%Input%:" neq "%systemDrive%" (
   
5.     for %%a in (software system) do (
   
6.         if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
   
7.     )
   
8.     reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
   
9.     reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
   
10.     call :GetIPInfo Temp_HIV1 Temp_HIV2
    
11.     reg unload HKLM\Temp_HIV1 >nul
    
12.     reg unload HKLM\Temp_HIV2 >nul
    
13. ) else call :GetIPInfo SOFTWARE SYSTEM
    
14. start "" "%~dp0IPInfo.txt" & exit/b
    
15. 
    
16. :GetIPInfo
    
17. for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
    
18.     if /i "%%a" == "Default" set /a x=%%c
    
19. )
    
20. set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
    
21. set "v2=ControlSet00%x%\Control\Network"
    
22. set "v3=ControlSet00%x%\services\Tcpip\Parameters"
    
23. set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
    
24. set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
    
25. 
    
26. for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
    
27.     set "v=%%a"
    
28.     if "!v:%v1%\=!" neq "!v!" (
    
29.         set /a n+=1
    
30.         for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
    
31.             if /i "%%b" == "ServiceName" (
    
32.                 set "Guid!n!=%%d"
    
33.             ) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
    
34.         )
    
35.     )
    
36. )
    
37. if not defined n echo,找不到网卡&pause & exit
    
38. 
    
39. (for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
    
40.     if /i "%%a" == "Domain" (
    
41.         if "%%c" neq "" (echo,域名名称：%%c)else echo,域名名称：^<nul^>
    
42.     ) else if /i "%%a" == "HostName" echo,主机名称：%%c
    
43. ))>"%~dp0IPInfo.txt"
    
44. 
    
45. for %%a in (%s%) do set "_%%a=1"
    
46. (for /l %%a in (1 1 %n%) do (
    
47.     echo,&echo,网卡名称：!NetCard%%a!
    
48.     for %%b in (%s%) do set "%%b="
    
49.     for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
    
50.         if defined flag (
    
51.             for /f "tokens=1,2*" %%c in ("%%b") do (
    
52.                 if /i "%%c" == "Name" echo,连接名称：%%e& set "flag="
    
53.             )
    
54.         ) else (
    
55.             set "v=%%b"
    
56.             for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" set flag=1
    
57.         )
    
58.     )
    
59.     for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
    
60.         if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
    
61.     )
    
62.     if /i "!EnableDHCP!" == "0x1" (
    
63.         echo,IP 地 址：!DHCPIPAddress!
    
64.         echo,子网掩码：!DHCPSubnetMask!
    
65.         echo,默认网关：!DHCPDefaultGateway!
    
66.         echo,DNS 地址：!DHCPNameServer!
    
67.     ) else (
    
68.         echo,IP 地 址：!IPAddress!
    
69.         echo,子网掩码：!SubnetMask!
    
70.         echo,默认网关：!DefaultGateway!
    
71.         echo,DNS 地址：!NameServer!
    
72.     )
    
73. ))>>"%~dp0IPInfo.txt"

复制代码

pznpt

saiz 发表于 2014-8-30 22:31
TO pznpt大大
十分感謝 用途很大!
但希望能多加點功能

2楼请测试