全盘搜索install.wim文件的命令 求简化

wchongy

全盘搜索 install.wim文件！！如果仅有一个文件自动拷贝到R:\OKRBackup\Factory 路径下！如果有一个以上文件，选择以后拷贝。如果没有发现该文件，自动关闭搜索退出！！

title 搜索 Install.Wim 并拷贝
setlocal enabledelayedexpansion & cd /d %~dp0

::设置Wim文件保存目录
set WimDir=R:\OKRBackup\Factory

if not exist "!WimDir!" md "!WimDir!"
del /f /q WimList_*.Log 2>nul
for %%a in (D E F G H I J K L M N P) do (
    if exist "%%~a:\" (
        pushd %%~a:\
        echo 正在搜索 %%~a  Install.Wim，此过程可能很耗时间，请耐心等待。。。 & echo,
        for /r %%i in (*install.wim) do (
            if /i "%%~nxi"=="install.wim" (
                if /i not "%%~dpi"=="!WimDir!\" (
                    set /a Num+=1
                    set "Wim=%%~i"
                    >>"%~dp0WimList_CP.Log" echo ^|!Num!^|"%%~i"
                    >>"%~dp0WimList_XZ.Log" echo !Num!、Install.Wim 位于 "!Wim:\install.wim=!"，文件大小: %%~zi 字节
                )
            )
        )
        popd
    )
)
cls
if defined Num (
    if !Num! equ 1 (
        echo 正在从 "!Wim:\install.wim=!" 中拷贝 Install.Wim，请耐心等待。。。& echo,
        copy "!Wim!" "!WimDir!\" 2>nul && (
            echo 拷贝成功！
        ) || (
            echo 系统镜像拷贝失败！请手动复制Install.Wim到打开的R:\OKRBackup\Factory文件夹下
            start R:\OKRBackup\Factory
        )
    ) else (
        type WimList_XZ.Log | more
        echo, & set /p xz=请选择要拷贝的 Install.Wim 编号并回车，不选择请直接回车:
        if defined xz for /f "tokens=2 delims=|" %%f in ('findstr "^|!xz!|" WimList_CP.Log') do (
            echo, & echo 正在从 "%%~dpf" 中拷贝 Install.Wim，请耐心等待。。。& echo,
            copy "%%~f" "!WimDir!\" 2>nul && (
                echo 拷贝成功！
            ) || (
                echo 系统镜像拷贝失败！请手动复制Install.Wim到打开的R:\OKRBackup\Factory文件夹下
                start R:\OKRBackup\Factory
            )
        )
    )
) else (
    echo 未发现 Install.Wim 文件。
)
del /f /q WimList_*.Log


echo