批处理系列6：查找剩余空间最大的磁盘盘符（终稿）

dos时代菜鸟 · 发表于 2021-7-11 11:01:27

本帖最后由 dos时代菜鸟于 2021-7-11 11:37 编辑

@echo off
setlocal ENABLEDELAYEDEXPANSION
set bit=0
set free1=0
set free2=0
set n=0
echo 找出剩余空间最大的那个分区对应的盘符
echo --------------------------------------
for /f "skip=1 delims=" %%c in (' wmic volume get DriveLetter^,freespace^,Label') do (
for /f "tokens=1,2,3* delims= " %%i in ("%%c") do (
if not "%%k"=="" (
rem 计算当前 Freespace 数值位数
call:x_bit %%j
set free=%%j
rem 因为 cmd 只能计算10位数且小于 2147483647 ，所以先截取数值后9位，存入Free22
rem 再截取前面剩下的，如果当前位数不足9，设置0
set free22=!free:~-9!
if !bit1! gtr 9 (set free11=!free:~0,-9!) else (set free11=0)
rem 如果当前 Freespace 数值位数比之前的大，就进一步比较
if !bit1! geq !bit! (
set bit=!bit1!
rem 分两段比较 Free1 free2 确定当前是否为最大。
if !free11! geq !free1! (
if !free11! gtr !free1! set free2=!free22!
set free1=!free11!
if !free22! geq !free2! (
set free2=!free22!
set drv=%%i
set /a n=n+1
)
)
)
if "!drv!"=="%%i" (echo %%i !free11!,!free22! *!n! %%k) else (echo %%i !free11!,!free22! %%k)
)
)
)
echo -----------------------------------
if not "!drv!"=="" ( echo MAX_FREE_DRV=!drv! !free1!!free2! ) ELSE (echo 没有可用分区!)
pause
goto :eof
:x_bit
rem 用于计算传递过来的字符串参数的字符个数。返回变量 bit1
set "str1=%1"
for /l %%r in (0,1,18) do (
if not "!str1:~%%r,1!"=="" (
set bit1=%%r
)
)
exit /b

复制代码

引入一个计算数值位数的办法。用 wimc 获取分区剩余大小，然后比较出来。
预设数值最大 18位，而 cmd 只能计算10位数且要小于 2147483647，那就截取下呗。
仅做技术交流，运行效率不是最好的，但算法是最传统的。

dos时代菜鸟 · 发表于 2021-7-13 12:17:19

本帖最后由 dos时代菜鸟于 2021-7-13 12:21 编辑

plusv 发表于 2021-7-12 14:56
>而 cmd 只能计算10位数且要小于 2147483647
准确的说是 32 位有号整数
Int= -2147483648(8000000 ...

if !bit1! gtr 9 (set free11=!free:~0,-9!) else (set free11=0)

改成
if !bit1! geq 9 (set free11=!free:~0,-9!) else (set free11=0)

@echo off
setlocal ENABLEDELAYEDEXPANSION
set bit=0
set free1=0
set free2=0
set n=0
echo 找出剩余空间最大的那个分区对应的盘符
echo --------------------------------------
for /f "skip=1 delims=" %%c in (' wmic volume get DriveLetter^,freespace^,Label') do (
for /f "tokens=1,2,3* delims= " %%i in ("%%c") do (
if not "%%k"=="" (
rem 计算当前 Freespace 数值位数
call:x_bit %%j
set free=%%j
rem 因为 cmd 只能计算10位数且小于 2147483647 ，所以先截取数值后9位，存入Free22
rem 再截取前面剩下的，如果当前位数不足9，设置0
set free22=!free:~-9!
if !bit1! geq 9 (set free11=!free:~0,-9!) else (set free11=0)
rem 如果当前 Freespace 数值位数比之前的大，就进一步比较
if !bit1! geq !bit! (
set bit=!bit1!
rem 分两段比较 Free1 free2 确定当前是否为最大。
if !free11! geq !free1! (
if !free11! gtr !free1! set free2=!free22!
set free1=!free11!
if !free22! geq !free2! (
set free2=!free22!
set drv=%%i
set /a n=n+1
)
)
)
if "!drv!"=="%%i" (echo %%i !free11!,!free22! *!n! %%k) else (echo %%i !free11!,!free22! %%k)
)
)
)
echo -----------------------------------
if not "!drv!"=="" ( echo MAX_FREE_DRV=!drv! !free1!!free2! ) ELSE (echo 没有可用分区!)
pause
goto :eof
:x_bit
rem 用于计算传递过来的字符串参数的字符个数。返回变量 bit1
set "str1=%1"
for /l %%r in (0,1,18) do (
if not "!str1:~%%r,1!"=="" (
set bit1=%%r
)
)
exit /b

复制代码

dos时代菜鸟 · 发表于 2021-7-16 09:47:55

再来个 fsutil 的

@echo off
setlocal ENABLEDELAYEDEXPANSION
for /f "delims=" %%c in ('fsutil fsinfo drives') do (call :x_drv %%c)
pause
goto :eof
:x_bit
rem 用于计算传递过来的字符串参数的字符个数。返回变量 bit1
set "str1=%1"
for /l %%r in (0,1,18) do (
if not "!str1:~%%r,1!"=="" (
set bit1=%%r
)
)
exit /b
:x_drv
set bit=0
set free1=0
set free2=0
:loop1
shift
if exist %1 (
set /a n=0
for /f "tokens=2 delims=#:^(" %%j in ('fsutil volume diskfree %1') do (
set /a n=!n!+1
if !n! equ 1 (
call:x_bit %%j
set free=%%j
set free=!free: =!
set free22=!free:~-9!
if !bit1! geq 9 (set free11=!free:~0,-9!) else (set free11=0)
if !bit1! geq !bit! (
set bit=!bit1!
if !free11! geq !free1! (
if !free11! gtr !free1! set free2=!free22!
set free1=!free11!
if !free22! geq !free2! (
set free2=!free22!
set drv=%1
)
)
)
if "!drv!"=="%1" ( echo %1 !free11!,!free22! *) else (echo %1 !free11!,!free22!)
)
)
)
if not "%2"=="" goto loop1
echo.
echo !drv! !free1!!free2!
exit /b

复制代码

dos时代菜鸟 · 发表于 2021-7-16 10:43:06

本帖最后由 dos时代菜鸟于 2021-7-16 10:45 编辑

free.7z (816 Bytes, 下载次数: 7)

用 fsutil 获取盘符列表，分区格式卷标分区类型，如果找不出分区格式就认为不是本地盘可能是网盘或者光盘，不在统计之列。

dos时代菜鸟 · 发表于 2021-7-16 13:35:22

嗯嗯 fsutil 也有不足，不过，
找最大剩余，估计 fat 分区里面是不够的。

dos时代菜鸟 · 发表于 2021-7-16 20:33:35

free-1.7z (872 Bytes, 下载次数: 6)
用 fsutil 肯定不支持 fat ，另外为了获取卷标，分区格式，介质类型等信息，必然要多次运行 fsutil ,效率会慢一些，
有的系统下有逗号分割尺寸大小，还需要对文本流进行格式统一，效率也会慢一些。

遗憾的是，目前看，这个功能不管怎样最终都需要用外部命令来完成 wmic /fsutil 都属于外部命令，如果用内部命令，也就 dir 了，但是有有中英文的问题，不够通用。

dos时代菜鸟 · 发表于 2021-7-16 21:13:27

本帖最后由 dos时代菜鸟于 2021-7-16 21:24 编辑

这是用 dir 获取磁盘剩余空间用的。不需要外部程序，不需要 find

free-2.7z (613 Bytes, 下载次数: 14)

		自动登录	找回密码
密码			注册

批处理系列6：查找剩余空间最大的磁盘盘符（终稿）

点评

点评

点评

点评