文件,文件夹自打包解包工具

kingshui · 发表于 2021-12-29 11:12:38

本帖最后由 kingshui 于 2021-12-31 11:36 编辑

如标题，就是一个使用windows自带工具（内外置命令）写的一个方便打包文件的小工具

将文件或者文件夹拖放到批处理上会自动生成另一个自解压的批处理,生成的批处理自带父文件的打包功能，可重复利用。

@echo off
set "_n=%~0"
if "%~1" NEQ "" goto packagemod
for /f "usebackq delims==" %%a in ("%_n%") do set "name=%%a"
certutil -decode "%_n%" "%~n0.cab"
md "%~n0"
expand -r "%~n0.cab" ".\%~n0" |find "-F" && expand "%~n0.cab" -F:* ".\%~n0" >nul
del "%~n0.cab" & explorer "%~n0"
exit
:packagemod
set cmdstr=MAKECAB /v3 /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=CDROM /D Cabinet=On /D Compress=On /D FolderSizeThreshold=5000000 /D DiskDirectoryTemplate="%~dp1." /D CabinetNameTemplate="tmp.cab"
if exist "%~1" (
for /f "delims=" %%a in ('dir "%~1" /a-d /s /b') do (
setlocal enabledelayedexpansion
set x=%%a
set x=!x:%~dp1=!
echo "%%a" "!x!">>cabstr
endlocal
)) else (
echo "%~1" "%~nx1" >>cabstr
)
if "%~2" neq "" shift&goto packagemod
%cmdstr% /F cabstr >nul
del /f/q patch cab cabstr SETUP.INF SETUP.RPT >nul
powershell -C "& {$outpath = (Join-Path (pwd) '%~n1.base64'); $inpath = (Join-Path (pwd) 'tmp.cab'); [IO.File]::WriteAllText($outpath, ([convert]::ToBase64String(([IO.File]::ReadAllBytes($inpath)))))}"
for /f "delims=" %%i in (%_n%) do (
if "%%i" EQU ":encoding" goto :next
echo,%%i>>"%~n1.cmd"
)
:next
set "certb=BEGIN CERTIFICATE"
set "certe=END CERTIFICATE"
set "dash=-----"
echo :encoding>>"%~n1.cmd"
echo,%dash%%certb%%dash%>>"%~n1.cmd"
type "%~n1.base64" >>"%~n1.cmd"
echo,>>"%~n1.cmd"
echo,%dash%%certe%%dash%>>"%~n1.cmd"
echo %~nx1>>"%~n1.cmd"
del tmp.cab "%~n1.base64"
exit

复制代码

lr · 发表于 2021-12-29 13:42:12

学习一下。。。

juyz · 发表于 2021-12-29 13:42:45

这个打包的格式是CAB么?

a123456789z · 发表于 2021-12-29 14:39:15

谢谢分享。

旁观者清 · 发表于 2021-12-29 18:33:58

打开这个帖子，浏览器居然提示是否翻译。

holley2008 · 发表于 2021-12-29 20:21:51

本帖最后由 holley2008 于 2021-12-29 20:23 编辑

随后拖了个txt试了一下，，还原不了了- -~~~别的类型源文件都会在
txt会直接不在掉

kingshui · 发表于 2021-12-30 14:50:55

holley2008 发表于 2021-12-29 20:21
随后拖了个txt试了一下，，还原不了了- -~~~别的类型源文件都会在
txt会直接不在掉

多谢反馈，我来检查一下。

ellx98 · 发表于 2021-12-31 09:02:26

解压出来后能不能改为不生成文件夹？在当前目录下直接还原
另外不要系统的压缩，改为Winrar怎么以设？我试了一个WINRAR的包，打包完成后还变大了。

kingshui · 发表于 2021-12-31 11:40:45

holley2008 发表于 2021-12-29 20:21
随后拖了个txt试了一下，，还原不了了- -~~~别的类型源文件都会在
txt会直接不在掉

代码已经更新。

kingshui · 发表于 2021-12-31 11:45:02

ellx98 发表于 2021-12-31 09:02
解压出来后能不能改为不生成文件夹？在当前目录下直接还原
另外不要系统的压缩，改为Winrar怎么以设？我试 ...

改Winrar的话首先你要安装有Winrar，但是安装路径要查.我这个可以直接在新电脑上放出来了

最主要是现在系统加固得比较厉害，不能复制粘贴文件了，我才搞的这个，直接粘贴文本内容不受限

要在当前目录释放的话改第7行的".\%~n0" 为.\ 和第8行的&后面的内容要删掉

@echo off
set "_n=%~0"
if "%~1" NEQ "" goto packagemod
for /f "usebackq delims==" %%a in ("%_n%") do set "name=%%a"
certutil -decode "%_n%" "%~n0.cab"
REM md "%~n0"
expand -r "%~n0.cab" .\ |find "-F" && expand "%~n0.cab" -F:* .\ >nul
del "%~n0.cab" & explorer "%~n0"
exit
:packagemod
set cmdstr=MAKECAB /v3 /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=CDROM /D Cabinet=On /D Compress=On /D FolderSizeThreshold=5000000 /D DiskDirectoryTemplate="%~dp1." /D CabinetNameTemplate="tmp.cab"
if exist "%~1" (
for /f "delims=" %%a in ('dir "%~1" /a-d /s /b') do (
setlocal enabledelayedexpansion
set x=%%a
set x=!x:%~dp1=!
echo "%%a" "!x!">>cabstr
endlocal
)) else (
echo "%~1" "%~nx1" >>cabstr
)
if "%~2" neq "" shift&goto packagemod
%cmdstr% /F cabstr >nul
del /f/q patch cab cabstr SETUP.INF SETUP.RPT >nul
powershell -C "& {$outpath = (Join-Path (pwd) '%~n1.base64'); $inpath = (Join-Path (pwd) 'tmp.cab'); [IO.File]::WriteAllText($outpath, ([convert]::ToBase64String(([IO.File]::ReadAllBytes($inpath)))))}"
for /f "delims=" %%i in (%_n%) do (
if "%%i" EQU ":encoding" goto :next
echo,%%i>>"%~n1.cmd"
)
:next
set "certb=BEGIN CERTIFICATE"
set "certe=END CERTIFICATE"
set "dash=-----"
echo :encoding>>"%~n1.cmd"
echo,%dash%%certb%%dash%>>"%~n1.cmd"
type "%~n1.base64" >>"%~n1.cmd"
echo,>>"%~n1.cmd"
echo,%dash%%certe%%dash%>>"%~n1.cmd"
echo %~nx1>>"%~n1.cmd"
del tmp.cab "%~n1.base64"
exit

复制代码

chibuzhu · 发表于 2021-12-31 14:11:55

没有.cab文件生成，源文件也还在，就生成了一个和源文件名一样的.cmd文件

kingshui · 发表于 2022-1-4 09:52:02

chibuzhu 发表于 2021-12-31 14:11
没有.cab文件生成，源文件也还在，就生成了一个和源文件名一样的.cmd文件

这是正确的，运行这个CMD就能还原出来源文件了，同时这个cmd也附带了父文件的功能

loka · 发表于 2022-1-4 18:03:55

感谢分享

		自动登录	找回密码
密码			注册

[原创] 文件,文件夹自打包解包工具