20240109自娱自乐【wmic硬件检测-gfd5.3】cmd版简单获取电脑信息并保存，慢慢完善...

享β亻寸木东 · 发表于 2024-1-6 14:36:50

本帖最后由享β亻寸木东于 2024-3-3 10:18 编辑

自己用的代码，不定时更新中。
主要用途：获取电脑的序列号、配置信息，然后保存到文件中。我是卖电脑的，收集这些信息可以记录电脑序列，销售日期，方便后期的保修查询等。
代码都是东拼西凑弄来的，大神有更好的建议欢迎提出，谢谢。
5.4加qq群吧：58902001还有cmd获取显示器信息：

@echo off
setlocal enabledelayedexpansion
echo 正在获取硬件基础信息（需要几分钟时间）
set "FileDX=%temp%\dxdiag.txt"
dxdiag /whql:off /t "%FileDX%"
echo 正在计算
for /f "tokens=2 delims=" %%i in ('wmic DesktopMonitor Get PNPDeviceID 2^>nul ^| findstr "DISPLAY"') do (
set "MonitorPNP=%%i"
)
for /f "tokens=2*" %%i in ('findstr /c:"Monitor Name:" "%FileDX%"') do (
set "MonitorName=%%j"
)
for /f "tokens=2*" %%i in ('findstr /c:"Monitor Model:" "%FileDX%"') do (
set "MonitorModel=%%j"
)
if /i "!MonitorModel!" equ "Unknown" (
for /f "tokens=2*" %%i in ('findstr /c:"Monitor Id:" "%FileDX%"') do (
set "MonitorModel=%%j"
)
) else if "!MonitorModel!" equ "" (
set "MonitorModel=!MonitorPNP!"
)
for /f "tokens=3" %%i in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\DISPLAY\!MonitorPNP!" /s ^| findstr "EDID"') do (
set "MonitorEDID=%%i"
)
set "YearNum=!MonitorEDID:~34,2!"
set "WeekNum=!MonitorEDID:~32,2!"
set "HeightNum=!MonitorEDID:~42,2!"
set "WidthNum=!MonitorEDID:~44,2!"
set /a WeekNum=0x!WeekNum!*1
set /a YearNum=0x!YearNum!*1+1990
set /a HeightNum=0x!HeightNum!*1
set /a WidthNum=0x!WidthNum!*1
for /f %%i in ('powershell "[Math]::Round([Math]::Sqrt([Math]::Pow(!HeightNum!,2)+[Math]::Pow(!WidthNum!,2))*0.3937,1)"') do (
set "MonitorSizeInch=%%i"
)
for /f "tokens=4" %%i in ('findstr /c:"User DPI Setting:" "%FileDX%"') do (
set "MonitorDPI=%%i"
)
for /f "tokens=2*" %%i in ('findstr /c:"Native Mode:" "%FileDX%"') do (
set "MonitorNative=%%j"
)
cls
echo 名称 : !MonitorName!
echo 型号 : !MonitorModel!
echo 屏幕尺寸 : !HeightNum! X !WidthNum! 厘米 (!MonitorSizeInch! 英寸)
echo 生产日期 : !YearNum!年第!WeekNum!周
echo 像素密度 : !MonitorDPI! DPI
echo 当前模式 : !MonitorNative!
pause >nul

复制代码

5.3地址：https://www.123pan.com/s/8JFRVv-Ichtv.html提取码:1234

这电脑板载8颗内存

5.2代码

@echo off&color e&title gfd硬件检测_5.2
mode con cols=110 lines=70
setlocal enabledelayedexpansion
echo 信息提取时间：%date% 时间 %Time%
for /f "tokens=1* delims=:=" %%a in ('"wmic os get Caption,InstallDate,OSArchitecture,Version /Format:List"') do (
IF /I "%%a"=="Caption" set Caption=%%b
IF /I "%%a"=="InstallDate" set InstallDate=%%b
IF /I "%%a"=="OSArchitecture" set OSArchitecture=%%b
IF /I "%%a"=="Version" set Version=%%b
)
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒
echo.
echo 主版:
for /f "tokens=1* delims==" %%a in ('"wmic csproduct get IdentifyingNumber,Name,Vendor,Version /value|more +2"') do (
IF /I "%%a"=="IdentifyingNumber" set IdentifyingNumber=%%b
IF /I "%%a"=="Name" set Name=%%b
IF /I "%%a"=="Vendor" set Vendor=%%b
IF /I "%%a"=="Version" set VersionZ=%%b
)
echo 供应商：%Vendor%
echo 系列：%Name%
echo 型号：%VersionZ%
echo 序列号：%IdentifyingNumber%&echo.&echo.
REM 处理器
for /f "tokens=2 delims==" %%a in ('"wmic cpu Get DeviceID /value"') do set /a CPUQuantity+=1
echo CPU ：【%CPUQuantity% 颗】
for /f "tokens=1* delims==" %%a in ('"wmic cpu get MaxClockSpeed,Name,NumberOfCores,NumberOfLogicalProcessors /value"') do (
IF /I "%%a"=="MaxClockSpeed" set MaxClockSpeed=%%b
IF /I "%%a"=="Name" set NameC=%%b
IF /I "%%a"=="NumberOfCores" set NumberOfCores=%%b
IF /I "%%a"=="NumberOfLogicalProcessors" set NumberOfLogicalProcessors=%%b
)
echo 名称：%NameC%【%NumberOfCores%核%NumberOfLogicalProcessors%线程】
echo 主频：%MaxClockSpeed%&echo.&echo.
REM 内存
for /f "tokens=2 delims==" %%a in ('"wmic memorychip Get Tag /value"') do set /a MemoryQuantity+=1
echo 内存：【%MemoryQuantity% 条】
for /f "tokens=2 delims==" %%a in ('"wmic memorychip get Capacity /value"') do (
set "Capacity=%%a"
for /f "tokens=1 delims=." %%b in ("!Capacity:~,-7!/1073") do set /a m+=%%b
)
call echo 总容量：%%m%% GB
for /f "tokens=1* delims==" %%a in ('"wmic memorychip get ConfiguredClockSpeed /value"') do (
IF /I "%%a" == "ConfiguredClockSpeed" set ConfiguredClockSpeed=%%b
)
echo 频率：%ConfiguredClockSpeed%&echo.&echo.
REM 硬盘
for /f "tokens=2 delims==" %%a in ('"wmic DiskDrive where MediaType='Fixed hard disk media' get Caption /value"') do set /a DiskQuantity+=1
echo 硬盘：【%DiskQuantity% 块】
set "Model= 型号："&set "SerialNumber= 序列号："&set "size= 容量："
for /f "tokens=1* delims==" %%a in ('"wmic DiskDrive where MediaType='Fixed hard disk media' get Model,SerialNumber,Size /value|more +2"') do echo. !%%a!%%b
echo 显示:
for /f "tokens=1* delims==" %%a in ('"wmic path Win32_VideoController get CurrentRefreshRate,DeviceID,MaxRefreshRate,MinRefreshRate,Name,VideoModeDescription /value"') do (
IF /I "%%a"=="CurrentRefreshRate" (
echo. 当前刷新率： %%b)
IF /I "%%a"=="DeviceID" (
echo. 设备 ID： %%b)
IF /I "%%a"=="MaxRefreshRate" (
echo. 最高刷新率： %%b)
IF /I "%%a"=="MinRefreshRate" (
echo. 最低刷新率： %%b)
IF /I "%%a"=="Name" (
echo. 显卡名称： %%b)
IF /I "%%a"=="VideoModeDescription" (
echo. 当前分辨率： %%b
echo ----------------------------)
)
echo.&echo.
echo BIOS：
for /f "tokens=1* delims=:=" %%a in ('"wmic bios get BIOSVersion,Manufacturer,Name,ReleaseDate,SerialNumber,SMBIOSBIOSVersion,Version /Format:List"') do (
IF /I "%%a"=="ReleaseDate" set ReleaseDate=%%b
IF /I "%%a"=="SerialNumber" set SerialNumberB=%%b
IF /I "%%a"=="Manufacturer" set Manufacturer=%%b
IF /I "%%a"=="Name" set NameB=%%b
IF /I "%%a"=="Version" set VersionB=%%b
IF /I "%%a"=="BIOSVersion" set BIOSVersion=%%b
IF /I "%%a"=="SMBIOSBIOSVersion" set SMBIOSBIOSVersion=%%b
)
echo 制造商：%Manufacturer%
echo 名称：%NameB%
echo 版本：%VersionB%
echo BIOS 版本：%BIOSVersion%
echo SMBIOS版本：%SMBIOSBIOSVersion%
echo 固件日期：%ReleaseDate:~0,4%年%ReleaseDate:~4,2%月%ReleaseDate:~6,2%日
echo 序列号：%SerialNumberB%
echo.
echo 信息提取完成，按任意键保存到文本中。
pause>nul
REM ==========保存信息到文件中，如果不需要，删除下面所有==========
echo 信息提取时间：%date% 时间 %Time%>>wmic硬件信息gfd.txt
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒>>wmic硬件信息gfd.txt
echo.>>wmic硬件信息gfd.txt
echo 主版:>>wmic硬件信息gfd.txt
echo 供应商：%Vendor%>>wmic硬件信息gfd.txt
echo 系列：%Name%>>wmic硬件信息gfd.txt
echo 型号：%VersionZ%>>wmic硬件信息gfd.txt
echo 序列号：%IdentifyingNumber%>>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
REM 处理器
echo CPU ：【%CPUQuantity% 颗】>>wmic硬件信息gfd.txt
echo 名称：%NameC%【%NumberOfCores%核%NumberOfLogicalProcessors%线程】>>wmic硬件信息gfd.txt
echo 主频：%MaxClockSpeed%>>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
REM 内存
echo 内存：【%MemoryQuantity% 条】>>wmic硬件信息gfd.txt
echo 总容量：%m% GB>>wmic硬件信息gfd.txt
echo 频率：%ConfiguredClockSpeed%>>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
REM 硬盘
echo 硬盘：【%DiskQuantity% 块】>>wmic硬件信息gfd.txt
set "Model= 型号："&set "SerialNumber= 序列号："&set "size= 容量："
for /f "tokens=1* delims==" %%a in ('"wmic DiskDrive where MediaType='Fixed hard disk media' get Model,SerialNumber,Size /value|more +2"') do echo. !%%a!%%b>>wmic硬件信息gfd.txt
echo 显示:>>wmic硬件信息gfd.txt
for /f "tokens=1* delims==" %%a in ('"wmic path Win32_VideoController get CurrentRefreshRate,DeviceID,MaxRefreshRate,MinRefreshRate,Name,VideoModeDescription /value"') do (
IF /I "%%a"=="CurrentRefreshRate" (
echo. 当前刷新率： %%b>>wmic硬件信息gfd.txt)
IF /I "%%a"=="DeviceID" (
echo. 设备 ID： %%b>>wmic硬件信息gfd.txt)
IF /I "%%a"=="MaxRefreshRate" (
echo. 最高刷新率： %%b>>wmic硬件信息gfd.txt)
IF /I "%%a"=="MinRefreshRate" (
echo. 最低刷新率： %%b>>wmic硬件信息gfd.txt)
IF /I "%%a"=="Name" (
echo. 显卡名称： %%b>>wmic硬件信息gfd.txt)
IF /I "%%a"=="VideoModeDescription" (
echo. 当前分辨率： %%b>>wmic硬件信息gfd.txt
echo ---------------------------->>wmic硬件信息gfd.txt)
)
echo. >>wmic硬件信息gfd.txt
echo. >>wmic硬件信息gfd.txt
echo BIOS：>>wmic硬件信息gfd.txt
echo 制造商：%Manufacturer%>>wmic硬件信息gfd.txt
echo 名称：%NameB%>>wmic硬件信息gfd.txt
echo 版本：%VersionB%>>wmic硬件信息gfd.txt
echo BIOS 版本：%BIOSVersion%>>wmic硬件信息gfd.txt
echo SMBIOS版本：%SMBIOSBIOSVersion%>>wmic硬件信息gfd.txt
echo 固件日期：%ReleaseDate:~0,4%年%ReleaseDate:~4,2%月%ReleaseDate:~6,2%日>>wmic硬件信息gfd.txt
echo 序列号：%SerialNumberB%>>wmic硬件信息gfd.txt
echo ****************************************页尾****************************************>>wmic硬件信息gfd.txt

复制代码

shanghui6666 · 发表于前天 20:58

谢谢分享，支持原创，楼主不易，了表赞赏。

hnol · 发表于前天 13:28

脚本获取的硬盘序列号，与标签上显示序列号不一致

2012飘水 · 发表于 2024-5-7 14:05:31

感谢分享，长姿势了

shanghui6666 · 发表于 2024-5-7 12:58:08

谢谢分享，支持原创，楼主不易，了表赞赏。

mtv01 · 发表于 2024-5-7 11:17:29

wmic path Win32_PnPSignedDriver where "DeviceClass='Monitor'" get DeviceName,Manufacturer,DriverVersion /format:list

mtv01 · 发表于 2024-5-7 11:14:46

zlq_hysy 发表于 2024-1-6 15:10
感谢分享。显示器信息能搜集到吗？

wmic path Win32_DesktopMonitor get /format:list

softwarezheng · 发表于 2024-5-4 18:00:18

谢谢

zzq1392281 · 发表于 2024-5-1 18:16:23

这个脚本很棒，收藏了

Ukyo · 发表于 2024-4-30 16:57:00

还不错的，读取了本机的配置的信息，基本可以替换掉鲁大师了

2012飘水 · 发表于 2024-4-5 11:05:16

学习了，感谢分享

2012飘水 · 发表于 2024-4-3 13:57:44

感谢楼主分享，学习了

zqfeng01 · 发表于 2024-4-3 12:28:03

谢谢分享

tilltotell007 · 发表于 2024-3-4 21:44:01

感谢分享

享β亻寸木东 · 发表于 2024-3-3 18:18:35

pda8888 发表于 2024-3-3 16:12
这是用了wintoflash大师的nwinfo
和windows版的jq综合出来的，jq语法在批处理环境超级复杂，不晓得吓 ...

谢谢分享！！！谢谢分享！！！

pda8888 · 发表于 2024-3-3 16:12:11

本帖最后由 pda8888 于 2024-3-3 16:14 编辑

@echo off
echo.
nwinfo_x64.exe --cpu --smbios --disk --pci=03 --format=json|jq -r -c "[ "^
MB:\t\(.SMBIOS[]^|select(."Table Type" == 1 ) ^|^
."Manufacturer") \(.SMBIOS[]^|select(."Table Type" == 2 ) ^| ^
."Product Name")\(.SMBIOS[]^|select(."Table Type" == 0 ) ^| ^
" (BIOS Ver=\(."Version"))|\(."Release Date" | split("/") | "\(.[2])-\(.[0])-\(.[1])" )")\t\(.SMBIOS[] ^| select(."Table Type" == 2 ) ^| ."Serial Number")", "^
CPU:\t\(.CPUID.CPU0.Brand)", "^
Mem:\t\(.SMBIOS[] ^| select(."Table Type" == 17 ) ^| ^
select(."Manufacturer" != null) ^|^
"\(.Manufacturer)|\(.["Part Number"] | sub(" +$"; ""))|\(.["Device Type"]) \(.["Speed (MT/s)"]) \((."Device Size" / 1024 / 1024 /1024))GB@\(.["Device Locator"])\t\(.["Serial Number"])")", "^
VGA:\t\(.PCI[]^|"\(.Vendor) \(.Device)")", "^
Disk:\t$.Disks[]^|"\(."HW Name") (\(.["Health Status"] | capture("\\((?^<percentage^>\\d+%%)\$"; "g").percentage))@\(."Type") \(."Size" /1000000000 | round)GB\t\(."Serial Number")")" ] | join("\n")"

复制代码

这是用了wintoflash大师的nwinfo
和windows版的jq综合出来的，jq语法在批处理环境超级复杂，不晓得吓到了一些小宝宝没有。
jq 1.7.1 executables for AMD64 or i386.

效果是这样的：

好处是不依赖于wmic，PE下可用。

享β亻寸木东 · 发表于 2024-3-1 08:51:41

Qidulan 发表于 2024-2-28 09:53
某些电脑读取到的硬盘序列号不对！

再就是现在很多固态硬盘鱼龙混杂，厂家不一定把序列号写入硬盘固件

享β亻寸木东 · 发表于 2024-3-1 08:50:10

Qidulan 发表于 2024-2-28 09:53
某些电脑读取到的硬盘序列号不对！

wmic命令获取的不一定准，仅供参考。

Qidulan · 发表于 2024-2-28 09:53:59

某些电脑读取到的硬盘序列号不对！

yuguotqing · 发表于 2024-2-21 17:04:25

谢谢楼主的分享

zhupai168 · 发表于 2024-2-21 16:59:35

感谢分享

iceAngle · 发表于 2024-2-4 10:56:50

这个可以了，谢谢！

leitian72853 · 发表于 2024-2-4 08:30:04

感谢分享

jyt · 发表于 2024-1-30 21:30:28

娱乐性很强，谢了！

wjsk10 · 发表于 2024-1-28 11:29:46

谢谢分享

dyc086 · 发表于 2024-1-28 11:24:48

感谢分享

无犹启动 · 发表于 2024-1-26 09:12:37

谢谢分享

无犹启动 · 发表于 2024-1-25 18:10:38

谢谢分享

享β亻寸木东 · 发表于 2024-1-15 15:57:36

3416510931 发表于 2024-1-15 11:21
保存的文本用Notepad2打开时提示换行符不一致

能用吗？能用就行

3416510931 · 发表于 2024-1-15 11:21:40

保存的文本用Notepad2打开时提示换行符不一致

zw12834377 · 发表于 2024-1-15 10:58:59

感谢分享

		自动登录	找回密码
密码			注册

[发布] 20240109自娱自乐【wmic硬件检测-gfd5.3】cmd版简单获取电脑信息并保存，慢慢完善...

点评

评分

点评

点评

点评

[发布] 20240109自娱自乐【wmic硬件检测-gfd5.3】cmd版 简单获取电脑信息并保存，慢慢完善...

点评

评分

点评

点评

点评

[发布] 20240109自娱自乐【wmic硬件检测-gfd5.3】cmd版简单获取电脑信息并保存，慢慢完善...