PE下批处理显示并保存硬盘系统盘的IP设置

tanchenglong · 发表于 2024-3-11 14:36:12

本帖最后由 tanchenglong 于 2024-3-11 14:37 编辑

PE下批处理显示并保存硬盘系统盘的IP设置，适合需固定IP电脑重装
1、自动寻找WINDOWS系统的盘符（会自动过滤掉PE的盘符）
2、显示系统盘WINDOWS的IP设置
3、保存IP设置到运行盘的\Tmp-IP.txt文件，用于重装系统后恢复。

@echo off
REM @echo off 2>nul 3>nul
setlocal enabledelayedexpansion
::判断当前已使用盘符及系统WINDOWS盘符
set a=C D E F G H I J K L M N O P Q R S T U V W X Y Z
set dr=
echo 当前已使用盘符有：
for %%i in (%a%) do if exist %%i: echo %%i:
echo. ===============================================================
echo.
echo 当前WINDOWS系统盘符为：
for %%t in (software) do (
for %%j in (%a%) do if exist "%%j:\Windows\System32\config\%%t" (
if %%j: neq %SystemDrive% echo %%j: & set dr=%%j
))
set input=%dr%
echo.
echo. ===============================================================
::PE系统中显示原WINDOWS系统IP信息
set /p Input=↑↑↑根据上面列出的WINDOWS系统盘符输入要查询的系统安装盘符【如：%dr%】：
if %Input%=="" set Input="C"
echo 当前输入的盘符是：%Input%
echo.
echo. 将在当前文件夹下创建：Tmp-IP.txt，以备查。
echo.
Pause
if /i "%Input%:" neq "%systemDrive%" (
for %%a in (software system) do (
if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
)
reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
call :GetIPInfo Temp_HIV1 Temp_HIV2
reg unload HKLM\Temp_HIV1 >nul
reg unload HKLM\Temp_HIV2 >nul
) else call :GetIPInfo SOFTWARE SYSTEM
start "" "%TEMP%\IPInfo.txt" & exit/b
:GetIPInfo
for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
if /i "%%a" == "Default" set /a x=%%c
)
set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
set "v2=ControlSet00%x%\Control\Network"
set "v3=ControlSet00%x%\services\Tcpip\Parameters"
set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
set "v=%%a"
if "!v:%v1%\=!" neq "!v!" (
set /a n+=1
for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
if /i "%%b" == "ServiceName" (
set "Guid!n!=%%d"
) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
)
)
)
if not defined n echo,找不到网卡&pause & exit
(for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
if /i "%%a" == "Domain" (
if "%%c" neq "" (echo,域名名称：%%c)else echo,域名名称：^<nul^>
) else if /i "%%a" == "HostName" echo,主机名称：%%c
))>"%TEMP%\IPInfo.txt"
for %%a in (%s%) do set "_%%a=1"
(for /l %%a in (1 1 %n%) do (
echo,&echo,网卡名称：!NetCard%%a!
for %%b in (%s%) do set "%%b="
for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
if defined flag (
for /f "tokens=1,2*" %%c in ("%%b") do (
if /i "%%c" == "Name" echo,连接名称：%%e& set "flag="
)
) else (
set "v=%%b"
for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" set flag=1
)
)
for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
)
if /i "!EnableDHCP!" == "0x1" (
echo,IP 地址：!DHCPIPAddress!
echo,子网掩码：!DHCPSubnetMask!
echo,默认网关：!DHCPDefaultGateway!
echo,DNS 地址：!DHCPNameServer!
) else (
echo,IP 地址：!IPAddress!
echo,子网掩码：!SubnetMask!
echo,默认网关：!DefaultGateway!
echo,DNS 地址：!NameServer!
)
)
echo.
echo. MAC信息
echo. ==============================================================================
rem getmac /v
rem ipconfig /all|find /i "物理地址"
rem for /f "tokens=12 delims= " %%i in ('ipconfig /all^|find /i "物理地址"') DO (echo. 物理地址：%%i)
for /f "tokens=2 delims=:" %%i in ('ipconfig /all ^| findstr /i /c:"物理地址"') do echo. 物理地址：%%i
echo. ==============================================================================
echo. 所有网络连接
echo. ==============================================================================
ipconfig /all
echo.
echo. ==============================================================================
)>>"%TEMP%\IPInfo.txt"
@echo F | xcopy "%TEMP%\IPInfo.txt" .\Tmp-IP.txt /Y /Q >nul

复制代码

yuguotqing · 发表于 2024-3-11 14:59:34

沙发感谢分享

wang1126 · 发表于 2024-3-11 15:11:51

感谢分享

nathan6498 · 发表于 2024-3-11 15:23:22

谢谢分享

zqfeng01 · 发表于 2024-3-11 16:15:32

感谢分享

yyz2191958 · 发表于 2024-3-11 16:52:56

谢谢分享

yc2428 · 发表于 2024-3-11 17:41:48

谢谢分享！

kings · 发表于 2024-3-11 19:52:57

谢谢分享

2267981144 · 发表于 2024-3-11 21:28:58

感谢提供分享！

namsoo · 发表于 2024-3-12 05:05:21

谢谢分享

namsoo · 发表于 2024-3-12 07:00:30

谢谢分享！

hehuiying · 发表于 2024-3-12 18:10:53

老铁厉害

ningzhonghui · 发表于 2024-3-13 19:58:52

装机觉得实用

gyalp · 发表于 2024-3-13 20:29:24

感谢分享

as8686886 · 发表于 2024-3-15 12:15:00

我的PE里一直有这个，我是移植别人PE里的，好像是一根葱的PE里的

tanchenglong · 发表于 2024-3-15 17:29:34

楼主加油~~，向楼主学习@~~~

tanchenglong · 发表于 2024-3-18 08:39:11

这个也是在别人的批处理上进一步优化的，比如排除PE的系统盘，然后自动判断系统盘符

紧急追踪 · 发表于 2024-3-20 21:39:02

感谢分享

mumu015 · 发表于 2024-4-3 17:22:10

大神能写个wcs版本的吗。

2012飘水 · 发表于 2024-4-5 11:04:02

学习了，感谢分享

hehuiying · 发表于 2024-4-8 09:56:22

谢谢分享

无犹启动 · 发表于前天 17:35

谢谢分享

softwarezheng · 发表于前天 17:58

谢谢

		自动登录	找回密码
密码			注册

[分享] PE下批处理显示并保存硬盘系统盘的IP设置

点评

评分