发布4个pe均支持VSS卷影1秒备份离线系统盘和1秒输入数字键自动还原离线系统盘卷影副本

sairen139

发布4个pe均支持VSS卷影1秒备份离线系统盘和1秒输入数字键自动还原离线系统盘卷影副本

四个pe如下：
第1个：
22000.1pe网络版加DWM加bitlocker解锁加ISO装载外置工具包+CHFStool增加第三方文件管理器最新oMegaCommander桌面快捷AutoShortcut完美ftp支持VSS备份还原卷影BOOT.WiM
大小体积151mb

第2个：
内置浏览器22000.1pe网络版加DWM加bitlocker解锁加ISO装载外置工具包+CHFStool增加第三方文件管理器最新oMegaCommander桌面快捷AutoShortcut完美ftp支持VSS备份还原卷影BOOT.WiM
大小体积218mb

第3个：
支持wifi7的28000.1骨头网络版再添加CHFSTool支持QQ完整vssadmin批处理自动还原卷影完美BOOT.WiM
大小体积166mb

第 4个：
支持wifi7的28000.1骨头网络版再添加CHFSTool支持QQ完整vssadmin批处理自动生成还原且自动刷新卷影列表内置Palemoon浏览器完美BOOT.WiM
大小体积212mb

另外说明一下基于winre精简的骨头pe里使用vssadmin命令创建和还原VSS卷影副本备份所依赖的最少8个文件如下（22000.1到28000pe都测试过了全部创建和还原卷影成功的依赖文件）：

\Windows\System32\swprv.dll
\Windows\System32\vss_ps.dll
\Windows\System32\vssadmin.exe
\Windows\System32\vssapi.dll
\Windows\System32\vsstrace.dll
\Windows\System32\VSSVC.exe
\Windows\System32\zh-CN\vssadmin.exe.mui
\Windows\System32\zh-CN\vsstrace.dll.mui

需要注意的普通WinPE 环境中, 在运行此 vssadmin命令之前, 可以将注册表项 HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\ProductOptions 的值 ProductType 的数据更改为 ServerNT, 瞒天过海即可命令生成VSS卷影副本。服务器pe本身注册表里该值就是ServerNT无需这般修改操作。vssadmin命令还原时不要cmd访问C盘或者文件管理器访问C盘的文件或者文件夹，会导致无法执行成功。

具体1秒备份离线系统盘为VSS卷影副本和1秒恢复C盘所有文件和注册表到备份前方法：

就是利用vssadmin的备份命令和还原命令

1秒VSS备份离线系统盘C盘的命令（如果在正常系统里可以win+r组合键输入SystemPropertiesProtection就能点击创建还原点效果也是一样的）
vssadmin create shadow /for=c:

1秒VSS还原离线系统盘的命令
vssadmin revert shadow /shadow={卷影副本ID}

查看VSS卷影副本ID的命令
vssadmin list shadows




通过百度网盘分享的文件：支持vssadmin一秒备份离线系统盘和1秒自动还原VSS卷影副本的几个pe
链接：https://pan.baidu.com/s/1-XCfZNIWEDjF7uvuZa7FlQ?pwd=8864

除了WiM格式的几个pe外，网盘里还有一个64petools.ISO是外置的几十个工具集合包可以下载放到任意盘的根目录，双击pe桌面上的【加载外置】即可加载到pe的B盘。

sairen139

用完即走的还原卷影副本的批处理如下：

@echo off
setlocal enabledelayedexpansion

:: WinPE兼容性处理：确保reg命令可用
set "RegCmd=reg.exe"
if not exist "%SystemRoot%\System32\reg.exe" (
    echo.
    echo 警告: 未找到reg.exe
    echo.
    pause
    exit /b 1
)

:: 查询当前的ProductType值
set "OriginalProductType="
for /f "skip=2 tokens=3" %%a in ('%RegCmd% query "HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions" /v ProductType 2^>nul') do (
    set "OriginalProductType=%%a"
)

:: 如果查询失败（键值不存在），设置默认值
if not defined OriginalProductType (
    set "OriginalProductType=WinNT"
)

:: 如果不是ServerNT，则修改为ServerNT
if /i not "!OriginalProductType!"=="ServerNT" (
    %RegCmd% add "HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions" /v ProductType /d ServerNT /f >nul 2>&1
)

:Menu
cls
echo.
echo. 卷影副本列表如下请输入行号数字还原系统【或者直接按一个盘符英文字母键创建对应盘的卷影备份】
echo.
echo. 由大到小按需输入
echo.

set /a id_cnt=0, vol_cnt=0, time_cnt=0
for /f "delims=" %%a in ('vssadmin list shadows 2^>nul') do (
    set "line=%%a"
    if "!line:卷影副本 ID:=!" neq "!line!" (
        set /a id_cnt+=1
        for /f "tokens=3" %%b in ("!line!") do set "shadowid_!id_cnt!=%%b"
    )
    if "!line:原始卷:=!" neq "!line!" (
        set /a vol_cnt+=1
        for /f "tokens=2 delims=()" %%c in ("!line!") do set "vol_!vol_cnt!=%%c"
    )
    if "!line:在创建时间:=!" neq "!line!" (
        set /a time_cnt+=1
        for /f "tokens=2,3" %%d in ("!line!") do set "time_!time_cnt!=%%d %%e"
    )
)

:: 如果没有卷影副本，跳转到直接创建模式
if %id_cnt% equ 0 (
    echo 检索不到卷影，将直接进入创建卷影模式。
    goto :CreateOnly
)

set /a total=%id_cnt%
for /l %%i in (1,1,%total%) do echo [%%i] 卷影副本 ID: !shadowid_%%i! 原始卷（!vol_%%i!） !time_%%i!

set /p V=请输入行号数字进行卷影还原【或按英文键创建对应盘卷影备份，如 C 或D 或E】：

:: ====== 按一个英文盘符字母创建对应盘的卷影备份 ======
:: 去除输入中的空格
set "V=!V: =!"
:: 检查是否为单个字母
if not "!V!"=="" if "!V:~1!"=="" (
    set "alphabet=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    if /i not "!alphabet:%V%=!"=="!alphabet!" (
        echo.
        echo 正在创建 !V!: 盘卷影副本，请稍候...
        vssadmin create shadow /for=!V!:

        goto Menu
    )
)
:: =================================================

if /i "%V%"=="0" goto Done

set "valid=0"
for /l %%i in (1,1,%total%) do if "%V%"=="%%i" set "valid=1"
if "!valid!"=="0" (echo 请输列表里的行号数字&goto Menu)

echo.
echo. 按 Y 键还原目标分区所有文件和注册表，按 N 键不进行
echo.

vssadmin revert shadow /shadow=!shadowid_%V%!

echo.
echo 系统将在 9 秒后自动重启，按 Y 键取消，按 N 键立即重启...
choice /c YN /t 9 /d N /m "按 Y 取消重启，超时或按 N 则自动重启"
if errorlevel 2 (
    echo 即将自动重启...
    Wpeutil Reboot
) else (
    echo 自动重启已取消，返回卷影列表...
    goto Menu
)

:Done
reg.exe add "HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions" /v ProductType /d !OriginalProductType! /f >nul 2>&1
endlocal
pause
exit /b

:: ====== 无卷影时直接创建卷影的处理段（排除 X 盘） ======
:CreateOnly
echo.
set /p DriveLetter=请直接输入要创建卷影的盘符英文字母（如 C 或 D 或 E）：
set "DriveLetter=!DriveLetter: =!"
if "!DriveLetter!"=="" goto CreateOnly
if not "!DriveLetter:~1!"=="" (
    echo 只能输入单个英文字母
    goto CreateOnly
)
:: 排除 X 盘（WinPE 的 RAM 盘）
if /i "!DriveLetter!"=="X" (
    echo.
    echo X 系统盘通常为 WinPE 临时内存盘，不支持创建卷影备份，请换一个盘符。
    goto CreateOnly
)
set "alphabet=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
if /i "!alphabet:%DriveLetter%=!"=="!alphabet!" (
    echo 无效的盘符，请输入 A-Z 之间的英文字母。
    goto CreateOnly
)
echo 正在创建 !DriveLetter!: 盘卷影副本，请稍候...
vssadmin create shadow /for=!DriveLetter!:

goto Menu

martin313

我发布的原生explorer壳启动的PE，都支持的呗！

630

VSS，即"Volume Shadow Copy Service"的缩写，中文直译为“卷影复制服务”。它是一种在计算机系统中广泛使用的功能，用于在数据备份期间创建一个与原始数据一致的临时副本，从而避免对正在运行的应用程序造成影响。这个缩写词在技术领域，尤其是驱动程序相关应用中具有较高的知名度，其流行度达到了3341。VSS主要应用于数据库备份、系统恢复等场景，例如，安装卷影复制服务更新包时，它能确保备份操作的高效执行，而不会中断数据库服务。在没有VSS的情况下，备份可能需要在系统维护期间进行，增加了复杂性和停机时间。而VSS的独特之处在于它能在系统运行时创建数据的实时点对点副本，极大地提高了数据保护的效率和便利性。
一项关于基于虚拟磁盘服务(VDS)和卷影复制服务(VSS)备份方法的研究也表明，VSS的结合使用在现代数据管理中具有显著优势。总的来说，VSS作为一项重要的技术工具，对于维护数据安全和备份策略至关重要。

yyz219195888

了解一下，谢谢

it323

看看怎样，感谢分享!

a66

纯支持

ebaqiang

多谢老板，收藏一份

ntsxyv51729

那个大神能搞一个123的下载，就好了

laybmusic

了解看看。

2012andyle113

感谢分享，没有真正用过这个

martin313

了解一下就行，没啥实际应用价值。如今系统备份啊系统恢复啊，都没啥用！做好个人数据的备份才是必须的。

lyrgcy

感谢楼主分享！楼上说的系统备份恢复没啥用，这仅是你个人思维，不代表所有人

sunandy

感谢分享

紧急追踪

感谢分享