批处理bat如何判断字符串长度

crtrccrtt

请教热心网友，如何使用批处理bat判断字符串长度，
特别是字符串带有【空格】、【“】、【““】（即两个“字符连在一起）等特殊情况时。

a66

批处理本身处理复杂字符串比较麻烦，推荐调用 PowerShell 来获取字符串长度，可以轻松处理特殊字符。使用 powershell 判断字符串长度（推荐）

1. echo off
   
2. setlocal
   
3. 
   
4. :: 示例字符串，可以包含空格、引号、连续引号等
   
5. set "input=Hello "World""
   
6. 
   
7. :: 调用 PowerShell 获取字符串长度
   
8. for /f "usebackq" %%a in (`powershell -command "$env:input.Length"`) do set "len=%%a"
   
9. 
   
10. echo 字符串长度为: %len%
    
11. 
    
12. endlocal

复制代码

说明：

• set "input=Hello "World""：即使包含特殊字符，用 set "变量=..." 格式是安全的。
• powershell -command "$env:input.Length"：读取环境变量 input 的内容，并返回其长度。
• for /f 用来捕获 PowerShell 的输出。
  

---

如果坚持使用纯批处理虽然可以实现，但处理引号、空格会变得非常复杂，容易出错，不推荐用于实际项目。

jieny

感谢分享

hlowld

2楼说得很全面了

如果一定要用纯批处理，可以试下这个函数，对于包含空格和双引号的字符串，结果是正确的
来源于互联网，相当精巧

@echo off
set "input=Hello "World""
call :getstrlen input len
if defined len echo -%len%-
pause
exit

REM 获取变量中字符串长度，存入变量
REM call :getstrlen str len
:getstrlen
if "%~1" equ "" goto :eof
if "%~2" equ "" goto :eof
setlocal enabledelayedexpansion
set "$=!%1!#"
set "len="&for %%a in (4096 2048 1024 256 128 64 32 16 8 4 2 1) do (if "!$:~%%a,1!" NEQ "" set/a len+=%%a&set "$=!$:~%%a!" &if "!$:~1!"=="" goto getstrlenok)
set "s=!s!fedcba9876543210" &set/a "len+=0x!s:~16,1!"
:getstrlenok
endlocal&set/a "%2=%len%"&goto:eof

fengge2018

这东西用AI编写一个可以试试

juiceV5

jieny 发表于 2026-3-16 09:47
感谢分享

感谢分享，快乐分享，分享快乐。

juiceV5

感谢论坛速度提升

view520

感谢分享

l987142018

学习学习

矩子

2楼威武！

nttwqz

对于用于长度对其的长度计算，批处理有先天劣势，特别是中英文半角全角混排情况，dpinfo中采用的办法是写入临时文件，根据文件大小计算。或者省事点用tab键对齐。

wn168cn@163.com

支持2#4#热心坛友

guong

学习下了

ppll2030

如果只是单纯的要长度，那就直接计算就好了。

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. rem 示例字符串，可以包含空格、引号、连续引号等
   
4. set "str=Hello "World""""
   
5. 
   
6. :count
   
7. if not "!str:~%n%,1!"=="" set /a n+=1&goto :count
   
8. echo;%n%
   
9. pause&exit

复制代码

l3429900

学习学习

redyear2026

这是批处的一个经典话题了。以下代码供没有预装 powershell 但可在批处理脚本中运行 vbs/jscript/mshta 代码的场合（据说 winPE 的 pecmd 内置了计算字符串长度的函数 strl，另当别论吧）。
先设定要获取其长度（字符量和字节量，字符量把中文字符视为一个字符计算，字节量把中文字符视为两个字节计算）的字符串变量 set "s=!"【"文"】"" %%"，其中字符%在字面量中须予加倍写成%%。以下示例代码尽量采用环境变量向 vbs/jscript/mshta 代码传值以避免处理复杂字面量（如 %s% 变量值）的麻烦。

一。直接调用 jscript 代码（不用临时文件）获取字符串的字符量，但该法因采用 mshta 引擎会产生闪屏

1. @echo off & set "s=!"【"文"】"" %%"
   
2. for /f %%v in ('mshta "javascript:v=new ActiveXObject('wscript.shell').environment('process')('s');new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).write(v.length);close()" ') do echo,%%v
   
3. pause
   

复制代码

二。创建临时文件 *.vbs 获取字符串的字符量，没有方法一导致的闪屏

1. @echo off & set "s=!"【"文"】"" %%"
   
2. echo,x=createobject("wscript.shell").environment("process")("s"):wsh.echo(len(x))>#.vbs&for /f %%v in ('cscript /nologo #.vbs') do echo,%%v
   
3. pause
   

复制代码

三。创建临时文件获取字符串的字节量，为避免 cmd 的预处理后果，须用延迟变量逃逸的方法，计算结果-4是要删除包裹 !s! 值的双引号和末尾换行符的数量

1. @echo off & set "s=!"【"文"】"" %%"
   
2. setlocal enabledelayedexpansion &echo,"!s!">#.$&endlocal
   
3. for %%F in (#.$) do set/a "v=%%~zF-4"
   
4. echo,%v%
   
5. pause
   

复制代码

四。回顾批处理有史以来最经典的精品之一，即用纯批处理代码获取字符串长度（来自外网 dostips 2008年发布的老帖），其经典之义是其高效率。以下代码是其简化版 strLen 的示例

1. @echo off &set "s=!"【"文"】"" %%"
   
2. setlocal enabledelayedexpansion &call :strLen s v
   
3. echo,!v!
   
4. pause&exit/b
   
5. :strLen
   
6.    set "_str=!%~1!" &set "_len=1"
   
7.    for %%p in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
   
8.    if "!_str:~%%p,1!" neq "" (set/a "_len+=%%p" &set "_str=!_str:~%%p!") )
   
9.    set "%~2=!_len!" &exit/b

复制代码

RoyRay

@echo off &set "s=!"【"文"】"" %%"
setlocal enabledelayedexpansion &call :strLen s v
echo,!v!
pause&exit/b
:strLen
   set "_str=!%~1!" &set "_len=1"
   for %%p in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
   if "!_str:~%%p,1!" neq "" (set/a "_len+=%%p" &set "_str=!_str:~%%p!") )
   set "%~2=!_len!" &exit/b

handsome_xiang

感谢分享！

ebaqiang

纯支持～帮顶