怎样写autoexec.bat文件为引导后默认为光盘根目录？？

iJOE

有1可引导win98.img文件，默认引导带cdrom,可是引导后直接显示盘符为a:\
如何写autoexec.bat文件为引导后默认为X盘（光驱根目录？）
即，通过CD引导后,直接还原光盘根目录下的win98.gho文件。
GHOST -clone,mode=pload,src=win98.gho:1,dst=1:1 -sure -rb
注：ghost2003文件在根目录下。
谢谢

iJOE

知道，可是应该怎么写？ 我这么写不灵的。

iJOE

@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
set temp=c:\
set tmp=c:\
path=a:\
IF "%config%"=="NOCD" GOTO QUIT
LH MSCDEX.EXE /D:oemcd001 /L:D
echo.
IF "%config%"=="SETUP_CD" goto AUTOSETUP
GOTO QUIT
:AUTOSETUP
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\
%CDROM%
cd \WIN98
echo.
OEMSETUP.EXE /K "/IE /NF"
goto QUIT
:NOCDROM
echo.
echo The Windows 98 Setup files were not found.
echo.
:QUIT
%CDROM%

不成，还是A:\
!!!!

iJOE

谢谢，我再试验 ：）

iJOE

Bad command or file name
A:\_
....................

Climbing

把你的autoexec.bat修改成这样子：
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
set temp=c:\
set tmp=c:\
path=a:\
IF "%config%"=="NOCD" GOTO QUIT
LH MSCDEX.EXE /D:oemcd001 /L:D
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\

echo.
IF "%config%"=="SETUP_CD" goto AUTOSETUP
GOTO QUIT
:AUTOSETUP
%CDROM%
cd \WIN98
echo.
OEMSETUP.EXE /K "/IE /NF"
goto QUIT
:NOCDROM
echo.
echo There is no CDROM.
echo.
:QUIT
%CDROM%

iJOE

echo There is no CDROM.
Bad command or file name
A:\_

还是不可以哦.....
我用的就是标准98安装磁盘的img.

iJOE

发过去了。

Climbing

从autoexec.bat上就可以看出你用的不是原版的98启动盘。
有两个解决办法：
1、简单的，直接将光驱的盘符指定为R，即将盘符固定下来，方法如下：
LH MSCDEX.EXE /D:oemcd001 /L:R
这样你可以使用set CDROM=R:
然后在你的批处理最后面直接用R:或者%cdrom%来转到光驱。在你上面给出的批处理中直接指定光驱盘符为D，有点儿太靠前了，有可能被硬盘占掉了这个盘符。
2、复杂的，还是要用findcd来查找光驱到底是哪个盘符，但没有你上面的批处理中给出的那么简单，下面是供你参考用的批处理文件：
@echo off
set cdrom=
findcd -e
if errorlevel 255 goto _err
if errorlevel 0 set cdrom=A
if errorlevel 1 set cdrom=B
if errorlevel 2 set cdrom=C
if errorlevel 3 set cdrom=D
if errorlevel 4 set cdrom=E
if errorlevel 5 set cdrom=F
if errorlevel 6 set cdrom=G
if errorlevel 7 set cdrom=H
if errorlevel 8 set cdrom=I
if errorlevel 9 set cdrom=J
if errorlevel 10 set cdrom=K
if errorlevel 11 set cdrom=L
if errorlevel 12 set cdrom=M
if errorlevel 13 set cdrom=N
if errorlevel 14 set cdrom=O
if errorlevel 15 set cdrom=P
if errorlevel 16 set cdrom=Q
if errorlevel 17 set cdrom=R
if errorlevel 18 set cdrom=S
if errorlevel 19 set cdrom=T
if errorlevel 20 set cdrom=U
if errorlevel 21 set cdrom=V
if errorlevel 22 set cdrom=W
if errorlevel 23 set cdrom=X
if errorlevel 24 set cdrom=Y
if errorlevel 25 set cdrom=Z
if "%cdrom%"=="" goto _nocd
set cddrv=%cdrom%:
echo.
echo Found CDROM Drive at %cddrv%...
if not exist %cddrv%\bootstar\bsdos.exe goto _nopath
echo Setting PATH to CDROM...
path=%cddrv%\ghost;%cddrv%\pm8;%cddrv%\bootstar;%cddrv%\mcafee;%cddrv%\dostools;%cddrv%\;%cddrv%\ucdos;%cddrv%\boot;%path%
goto _end
:_err
echo.
echo There was an error with finding CD-ROM Drive Letter.
echo.
goto _end
:_nocd
echo.
echo Cannot find a CDROM drive.
echo.
goto _end
:_nopath
echo.
echo Cannot find useful tools on CDROM drive %cddrv%, PATH not be set.
echo.
:_end

heimuya

"set CDROM=FOO23"是什么的东东？？？

Climbing

再试试把批处理改成这样：
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
set temp=c:\
set tmp=c:\
path=a:\
IF "%config%"=="NOCD" GOTO QUIT
LH MSCDEX.EXE /D:oemcd001 /L:R
set CDROM=R:
IF "%config%"=="SETUP_CD" goto AUTOSETUP
GOTO QUIT
:AUTOSETUP
%CDROM%
cd \WIN98
echo.
OEMSETUP.EXE /K "/IE /NF"
goto QUIT
:NOCDROM
echo.
echo There is no CDROM.
echo.
:QUIT
%CDROM%

iJOE

运行结果如下：
Found CD-ROM Drive at A:...
Canont find useful tool on CDROM drive A:,PATH not be set.
A:\_

iJOE

OK
R:\_
谢谢